[Kensai]

What's the error?

Also,make sure you installed the fakemeta_util.inc file.

[Yerallo]

it's not compiling how else can I dl it?

[lucius]

I have the same problem: I can't download the .amxx file.

[lucius]

I was able to compile it, after downloading the original sma-file and installing the inc-file locally and then compile it myself.
However, I am having the following problems:
- The first round of the game, only 1 person gets a bomb instead of every T's.
- Only 1 person has the bomb in the "Score-screen", but actually all T's have a bomb. That's confusing.
- I find it a great plugin, but as stated: it is not really fair for the CT's. I think you should make it that when the first bomb is planted, the other bombs can't be used anymore.

Sorry if one or more of my problems where already covered.

[Yerallo]

can anyone compile the amxx for me? I don't know how.

[Yerallo]

can someone comile it for me please or fix this plugin?

[vontrolle]

I have amxmodx 1.8 but i dont have the module cstrike or csx
U know where i can get it?

[Fry!]

Errors :

L 05/29/2008 - 237:07: [AMXX] Run time error 10 (plugin "all_bombs.amxx") (native "get_user_weapon") - debug not enabled!
L 05/29/2008 - 237:07: [AMXX] To enable debug mode, add "debug" after the plugin name in plugins.ini (without quotes).
L 05/29/2008 - 2375: Invalid player id 0

[ConnorMcLeod]

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>
#include <hamsandwich>

#define OFFSET_DEFUSE_PLANT            193
#define CAN_PLANT_BOMB                (1<<8)
#define DEFUSER_COLOUR_R                0
#define DEFUSER_COLOUR_G                160
#define DEFUSER_COLOUR_B                0

#define OFFSET_TEAM    114
#define fm_cs_get_user_team(%1)    get_pdata_int(%1,OFFSET_TEAM)

new bombs
new amx_max_bombs
new gmsgStatusIcon

public plugin_init()
{
    register_plugin("All Ts have Bomb", "1.0", "Kensai")

    if( engfunc(EngFunc_FindEntityByString, 0, "classname", "func_bomb_target") || 
        engfunc(EngFunc_FindEntityByString, 0, "classname", "info_bomb_target") )
    {
        RegisterHam(Ham_Spawn, "player", "Ham_Spawn_player_Post", 1)
        register_logevent("_bomb_planted", 3, "2=Planted_The_Bomb")
        gmsgStatusIcon = get_user_msgid("StatusIcon")
        amx_max_bombs = register_cvar("amx_max_bombs", "2")
    }
    else
    {
        pause("ad")
    }
}

public _bomb_planted()
{
    bombs += 1
    if(bombs >= get_pcvar_num(amx_max_bombs))
    {
        new players[32], pnum, player
        get_players(players, pnum ,"ae", "TERRORIST")
        for(new i=0; i<pnum; i++)
        {
            player = players[i]
            if(user_has_weapon(player, CSW_C4))
                ham_strip_weapon(player, "weapon_c4")
            client_print(player, print_chat, "*Max bombs reached!*")
        }
    }
}    

public Ham_Spawn_player_Post(id)
{
    if( is_user_alive(id) )
    {
        set_task(0.1, "Post_PlayerSpawn", id)
    }
}

public Post_PlayerSpawn(id)
{
    if( fm_cs_get_user_team(id) == 1 )
    {
        ham_give_weapon(id, "weapon_c4")
        fm_cs_set_user_plant(id)
    }
}

fm_cs_set_user_plant(id, plant = 1, showbombicon = 1)
{
    new plantskill = get_pdata_int(id, OFFSET_DEFUSE_PLANT)
    if( plant )
    {
        plantskill |= CAN_PLANT_BOMB
        if( showbombicon )
        {
            message_begin(MSG_ONE_UNRELIABLE, gmsgStatusIcon, _, id)
            write_byte(1)
            write_string("c4")
            write_byte(DEFUSER_COLOUR_R)
            write_byte(DEFUSER_COLOUR_G)
            write_byte(DEFUSER_COLOUR_B)
            message_end()
        }
        set_pev(id, pev_body, 1)
    }
    else
    {
        plantskill &= ~CAN_PLANT_BOMB
        message_begin(MSG_ONE_UNRELIABLE, gmsgStatusIcon, _, id)
        write_byte(0)
        write_string("c4")
        message_end()
    }
    set_pdata_int(id, OFFSET_DEFUSE_PLANT, plantskill)
}

ham_give_weapon(id,weapon[])
{    
    if(!equal(weapon,"weapon_",7)) return 0;
    
    new wEnt = engfunc(EngFunc_CreateNamedEntity,engfunc(EngFunc_AllocString,weapon));
    if(!pev_valid(wEnt)) return 0;
    
    set_pev(wEnt,pev_spawnflags,SF_NORESPAWN);
    dllfunc(DLLFunc_Spawn,wEnt);
    
    if(!ExecuteHamB(Ham_AddPlayerItem,id,wEnt) || !ExecuteHamB(Ham_Item_AttachToPlayer,wEnt,id))
    {
        if(pev_valid(wEnt)) set_pev(wEnt,pev_flags,pev(wEnt,pev_flags) & FL_KILLME);
        return 0;
    }

    return 1;
}

ham_strip_weapon(id,weapon[])
{
    if(!equal(weapon,"weapon_",7)) return 0;

    new wId = get_weaponid(weapon);
    if(!wId) return 0;

    new wEnt;
    while((wEnt = engfunc(EngFunc_FindEntityByString,wEnt,"classname",weapon)) && pev(wEnt,pev_owner) != id) {}
    if(!wEnt) return 0;

    if(get_user_weapon(id) == wId) ExecuteHamB(Ham_Weapon_RetireWeapon,wEnt);

    if(!ExecuteHamB(Ham_RemovePlayerItem,id,wEnt)) return 0;
    ExecuteHamB(Ham_Item_Kill,wEnt);

    set_pev(id,pev_weapons,pev(id,pev_weapons) & ~(1<<wId));
    return 1;
} 


[Fry!]

okey , Thanks connorr !