[AuricYoutube]

I have a really small tiny problem with this plugin, whenever the last player alive joins spectator and comes back to ct/t, it causes the plugin not to recognize that all players are dead and not end the round.

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <cstrike>

public OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public Action:Event_PlayerDeath(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if (!IsFakeClient(client) && AllHumansDead())
    {
        EndRound();
    }
}

bool:AllHumansDead()
{
    new bool:result = true;
    
    for (new i = 1; i <= MaxClients; i++)
    {
        if (IsClientInGame(i) && !IsFakeClient(i) && IsPlayerAlive(i)) // Thanks Black-Rabbit
        {
            result = false;
        }
    }
    
    return result;
}

EndRound()
{
	CS_TerminateRound(GetConVarFloat(FindConVar("mp_round_restart_delay")), CSRoundEnd_CTWin);
}

If you know how to add such a function please help me.

[adma]

I've had issues with counting dead players when someones dies. The way I got it to work was using RequestFrame to delay the check by a frame.

[Ilusion9]

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <cstrike>

public void OnPluginStart()
{
    HookEvent("player_death", Event_PlayerDeath);
}

public void Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast)
{
    int client = GetClientOfUserId(GetEventInt(event, "userid"));
    
    if (IsFakeClient(client)) return;

    if (AllHumansDead(client))
    {
        EndRound();
    }
}

bool AllHumansDead(int client)
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (i == client) continue;

        if (IsClientInGame(i))
        {
                if (IsFakeClient(i)) continue;

                if (IsPlayerAlive(i))
                {
                        return false;
                }
        }
    }
    
    return true;
}

void EndRound()
{
	CS_TerminateRound(GetConVarFloat(FindConVar("mp_round_restart_delay")), CSRoundEnd_CTWin);
}

[AuricYoutube]

Originally Posted by Ilusion9 #pragma semicolon 1 #include <sourcemod> #include <sdktools> #include <cstrike> public void OnPluginStart() { HookEvent("player_death", Event_PlayerDeath); } public void Event_PlayerDeath(Event event, const char[] name, bool dontBroadcast) { int client = GetClientOfUserId(GetEventInt(event, "userid")); if (IsFakeClient(client)) return; if (AllHumansDead(client)) { EndRound(); } } bool AllHumansDead(int client) { for (int i = 1; i <= MaxClients; i++) { if (i == client) continue; if (IsClientInGame(i)) { if (IsFakeClient(i)) continue; if (IsPlayerAlive(i)) { return false; } } } return true; } void EndRound() { CS_TerminateRound(GetConVarFloat(FindConVar("mp_round_restart_delay")), CSRoundEnd_CTWin); }

problem still occuring

[Ilusion9]

If you have a custom command to join spec, you should check that.

[impossible_cc]

Try this

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <cstrike>

public void OnPluginStart()
{
    HookEvent("player_death", Event_CheckCond, EventHookMode_PostNoCopy);
    HookEvent("player_team", Event_CheckCond, EventHookMode_PostNoCopy);
}

public void Event_CheckCond(Event event, const char[] name, bool dontBroadcast)
{
    RequestFrame(view_as<RequestFrameCallback>(DoRoundcheck));
}

public void DoRoundcheck()
{
    if (AllHumansDead())
    {
        EndRound();
    }
}

bool AllHumansDead()
{
    for (int i = 1; i <= MaxClients; i++)
    {
        if (IsClientConnected(i) && IsClientInGame(i) && !IsFakeClient(i) && IsPlayerAlive(i))
        {
            return false;
        }
    }
    return true;
}

void EndRound()
{
    CS_TerminateRound(GetConVarFloat(FindConVar("mp_round_restart_delay")), CSRoundEnd_CTWin);
}