[FuZ!on]

Hi,

It's been way too long and I'm looking to get back into the AlliedModders community. Always did some stuff with AMXx and never SourceMod so this is all new to me.

I started off with a small plugin by following a tutorial I found online that will trigger a message when a user connects to the server that displays the client's name and steam ID. The tutorial is a bit outdated and uses the GetClientAuthString method.

Here is the original code:

PHP Code:

#include <sourcemod>

public Plugin:myinfo = {
    name = "Tutorial",
    author = "FuZ!oN",
    description = "Display connect message",
    url = ""
};

public OnClientPutInServer(client)
{
    new String:name[32], String:authid[32];
    
    GetClientName(client, name, sizeof(name));
    GetClientAuthString(client, authid, sizeof(authid));
    
    PrintToChatAll("\x01[SM] \x04%s\x01 (\x05%s\x01) has joined.", name, authid);
} 


Compiles with a warning about the GetClientAuthString which is understandable but still works. Only thing is, it doesn't appear to display a message for myself when I join the server, only bots: https://i.imgur.com/I7D8PhM.png

I did some research and changed my code around to this:

PHP Code:

#include <sourcemod>

public Plugin:myinfo = {
    name = "Tutorial",
    author = "Tim",
    description = "This is a simple tutorial",
    url = ""
};

public OnClientPutInServer(client)
{
    char authid[32], name[64];
    
    GetClientName(client, name, sizeof(name));
    GetClientAuthId(client, AuthId_Steam2, authid, sizeof(authid));
    
    PrintToChatAll("\x01[SM] \x04%s\x01 (\x05%s\x01) has joined.", name, authid);
} 


Compiles without warnings or errors but still have the same result as above.

Any help would be greatly appreciated so I can continue on my way

EDIT:

I just thought that maybe I'm too late to see the message because it's displayed before I spawn? I haven't been able to test it yet with another friend.

[Ilusion9]

PHP Code:


#include <sourcemod>

public void OnClientPostAdminCheck(int client)
{
    if (!IsFakeClient(client)) // skip bots
    {
        CreateTimer(5.0, Timer_ConnectMessage, GetClientUserId(client), TIMER_FLAG_NO_MAPCHANGE);
    }
}

public Action Timer_ConnectMessage(Handle timer, any data)
{
    int client = GetClientOfUserId(view_as<int>(data));

    if (client)
    {
        char authid[65];
        if (GetClientAuthId(client, AuthId_Steam2, authid, sizeof(authid))) // if has valid steam id
        {
            PrintToChatAll("\x01[SM] \x04%N\x01 (\x05%s\x01) has joined.", client, authid);
        }
        else
        {
            // maybe show the message wihout his steamid ???
        }
    }
} 


[SpirT]

Hello!

I've done here a try, see if it works.

PHP Code:

#include <sourcemod>

public Plugin myinfo = {
    name = "Tutorial",
    author = "Tim",
    version = "1.0"
    description = "This is a simple tutorial",
    url = ""
};

public void OnClientPutInServer(int client)
{
    if(!IsFakeClient(client) && client == 1)
    {
           char steam[32];
           GetClientAuthId(client, AuthId_Steam2, steam, sizeof(steam));
           
           PrintToChatAll("[SM] \x04%N \x01(\05 %s \x01) has joined", client, steam);
       }
} 


If you need any help click down bellow and contact me on steam, It apears that I am offline, but it's just to avoid spamming!

Here is some stuff that can help u

All the colors suported! with X code:

default (white): \x01
darkred: \x02
purple: \x03
green: \x04
lightgreen: \x05
lime: \x06
red: \x07
grey: \x08
yellow: \x09
gold: \x10

Best regards and hope I could help,

SpirT.

[Ilusion9]

Originally Posted by SpirT PHP Code: public void OnClientPutInServer(int client) {     if(!IsFakeClient(client) && client == 1)     {            char steam[32];            GetClientAuthId(client, AuthId_Steam2, steam, sizeof(steam));                        PrintToChatAll("[SM] \x04%N \x01(\05 %s \x01) has joined", client, steam);        } }

You should check why OnClientPutInServer is bad for what he's asking (clients might not have steamids in this event and it's triggered too early).
Why are you checking if the client is 1?
You should check if the steamid is valid (if getclientauthid returns true)

[FuZ!on]

Thank you both. SpirT, your code does not compile however Ilusion's compiles and works.

What I'm getting out of this is that I'm following an outdated tutorial that I should stop and find a new one.

[SpirT]

Originally Posted by FuZ!on Thank you both. SpirT, your code does not compile however Ilusion's compiles and works. What I'm getting out of this is that I'm following an outdated tutorial that I should stop and find a new one.

Weird, I compiled it with SPEdit compiler, and it worked with no problem. Btw, if Illusion works, nice! Any help you need just ask us. Add me and then if a problem appears, just call me ;)

Best Regards and good luck on your SourcePawn plugins,

SpirT.