[SaBBa]

Hey, I don't have a code yet ...
I want to make player invulnerable for 30 sec, uppon item purchase, light up his screen during that time and make him glow.
I need some resources or some base code to start with, thank you

[OciXCrom]

1. set_user_godmode(id, 1) + set_user_rendering() + ScreenFade message
2. set_task() for 30 seconds.
3. In the task set_user_godmode(id, 0) + remove set rendering

[lexzor]

i hope this will give you a boost

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "godmodemenu"
#define VERSION "1.0"
#define AUTHOR "none"

#define GodModeTask 4321

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_clcmd("say /menu", "godmodemenu")
    register_clcmd("say_team /menu", "godmodemenu")
}

public godmodemenu(id){
    new iMenu = menu_create("Awesome Menu", "godmodemenu_handler")
    
    menu_additem(menu, "1. Godmode")
    
    menu_setprop ( iMenu, MPROP_EXIT, MEXIT_ALL );
    menu_display ( id, iMenu, 0 );
}

public godmodemenu_handler(id, menu, item){
    switch(item){
        
        case 0:{
            //set_user_godmode
            //rendering
            //whatever you want
            set_task(30.0, "disable_godmode", id + GodModeTask)
        }
        
        case MENU_EXIT:{
            menu_destroy(iMenu)
            return PLUGIN_HANDLED
        }
}}

public disable_godmode(id){
    id -= GodModeTask
    //disable godmode
    //disable rendering
} 


[SaBBa]

Thanks for suggestions, why are you adding random it to task id, tasks can get overwritten if I set few of them under same id ?

[OciXCrom]

Originally Posted by SaBBa Thanks for suggestions, why are you adding random it to task id, tasks can get overwritten if I set few of them under same id ?

Because other plugins can remove them.

[SaBBa]

Everything works, expect screenfade, how to set it's duration correctly (from input value) ?
or just, set high value and then reset screenfade with make_mortal func ?

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fun>

#define PLUGIN "godmode"
#define VERSION "1.0"
#define AUTHOR "Nevermind23"

#define GodModeTask 4321
#define InfoTask 2341

new timer[33], bool:isGodmode[33], g_msgScreenFade

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_clcmd("amx_godmode", "cmdGodmode", ADMIN_LEVEL_B, "<name> <time>")
    g_msgScreenFade = get_user_msgid( "ScreenFade" )
}

public client_putinserver(id)
{
    isGodmode[id] = false
}

public client_disconnected(id)
{
    make_mortal(id)
}

public cmdGodmode(id, iLevel, iCid)
{
    if(!cmd_access(id, iLevel, iCid, 3))
        return PLUGIN_HANDLED

    new target[33]
    read_argv(1, target, charsmax(target))
    new pId = cmd_target(id, target, CMDTARGET_ALLOW_SELF)

    new sTime[3]
    read_argv(2, sTime, charsmax(sTime))
    new time = str_to_num(sTime)

    make_immortal(pId, time)
    return PLUGIN_HANDLED
}

public immortal_info(id)
{
    id -= InfoTask
    set_hudmessage(216, 100, 174, -1.0, 0.450, 1, 0.2, 1.0, 0.0, 1.0)
    show_hudmessage(id, "You are immortal for %d second", timer[id])
    timer[id]--

    if(timer[id] >= 0)
        set_task(1.0, "immortal_info", id + InfoTask)
}

public make_immortal(id, time)
{
    if(isGodmode[id])
        return PLUGIN_HANDLED

    timer[id] = time
    set_user_godmode(id, 1)
    set_user_rendering(id, kRenderFxGlowShell, 0, 102, 204, kRenderNormal, 0)
    screen_fade(id, time<<0, time<<0, 1, 0, 102, 204, 40)
    immortal_info(id + InfoTask)

    set_task(float(time), "make_mortal", id + GodModeTask)

    new pName[64]
    get_user_name(id, pName, charsmax(pName))
    client_print(0, print_chat, "[CSO] Player %s will be immortal for %d second", pName, time)

    return PLUGIN_HANDLED
}

public make_mortal(id)
{
    id -= GodModeTask
    set_user_godmode(id, 0)
    set_user_rendering(id, kRenderFxGlowShell, 0, 0, 0, kRenderNormal, 0)
}

stock screen_fade(id, iDuration, iHold, FadeMode, iRed, iGreen, iBlue, iAlpha)
{
    message_begin( MSG_ONE_UNRELIABLE, g_msgScreenFade,{ 0, 0, 0 }, id );
    write_short(iDuration);
    write_short(iHold);
    write_short(FadeMode);
    write_byte(iRed);
    write_byte(iGreen);
    write_byte(iBlue);
    write_byte(iAlpha);
    message_end();
} 


[OciXCrom]

time<<12