[Yusochan]

Hello !

I need a plugin for the last (ct) gets the xm1014 and a deagle and $3000 / 25hp / 25ap. The (tt) gets a knife that I will add the model and the script by myself and 3000 $ / 25hp / ap

Thx for the help and please i need it !

sorry for my impatience.

[Bugsy]

Not tested

PHP Code:

#include <amxmodx>
#include <fun>
#include <cstrike>
#include <hamsandwich>

new const Version[] = "0.1";

enum LastStuff
{
    LastWeapon[ 16 ],
    LastMoney,
    LastHP,
    LastAP
}

new lsStuff[ CsTeams ][ LastStuff ] = 
{
    { "" , 0 , 0 , 0 },
    { "weapon_knife" , 3000 , 25 , 25 },  //T
    { "weapon_xm1014" , 3000 , 25 , 25 },  //CT
    { "" , 0 , 0 , 0 }
};

public plugin_init() 
{
    register_plugin( "Last Player Stuff" , Version , "bugsy" );
    
    RegisterHam( Ham_Killed , "player" , "PlayerKilled" );
}

public PlayerKilled( iVictim , iKiller , iShouldGib )
{
    new iPlayers[ CsTeams ][ 32 ] , iTeamCounts[ CsTeams ] , iPlayer;

    for ( new CsTeams:csTeam = CS_TEAM_T ; csTeam <= CS_TEAM_CT ; csTeam++ )
    {
        get_players( iPlayers[ csTeam ] , iTeamCounts[ csTeam ] , "ae" , ( csTeam == CS_TEAM_T ) ? "TERRORIST" : "CT" );
        
        if ( iTeamCounts[ csTeam ] == 1 )
        {
            iPlayer = iPlayers[ csTeam ][ 0 ];
            
            strip_user_weapons( iPlayer );
            give_item( iPlayer , lsStuff[ csTeam ][ LastWeapon ] );
            cs_set_user_money( iPlayer , cs_get_user_money( iPlayer ) + lsStuff[ csTeam ][ LastMoney ] );
            set_user_health( iPlayer , get_user_health( iPlayer ) + lsStuff[ csTeam ][ LastHP ] );
            cs_set_user_armor( iPlayer , cs_get_user_armor( iPlayer ) + lsStuff[ csTeam ][ LastAP ] , CS_ARMOR_VESTHELM );

            client_print( iPlayer , print_chat , "* [Last Player] Given %s, %d money, %d hp, %d armor" , lsStuff[ csTeam ][ LastWeapon ][ 7 ] , lsStuff[ csTeam ][ LastMoney ] , lsStuff[ csTeam ][ LastHP ] , lsStuff[ csTeam ][ LastAP ] );
        }
    }    
} 


[Yusochan]

Thank you so much ! It's perfect