[ThatOneGuy]

I'm slowly releasing (which takes a good bit of time) a bunch of my older/smaller plugins that have just been sitting around and others might want them. By now, some of these may have similar plugins released by others - I don't intend on checking them all. This one was made upon request (on here? I cant find where...) and I didn't see a similar plugin in the first page or two of a search.

TOG Bot Damage Immunity

Makes bot/replay clients immune to damage.

Installation:
* Put togbotdmgimmunity.smx in the following folder: /addons/sourcemod/plugins/

[B3none]

Perhaps:

PHP Code:

#include <sourcemod>
#include <sdkhooks>

#pragma semicolon 1
#pragma newdecls required

#define PLUGIN_VERSION "1.0.1"

public Plugin myinfo =
{
    name = "TOG Bot Damage Immunity",
    author = "That One Guy",
    description = "Makes bot/replay clients immune to damage",
    version = PLUGIN_VERSION,
    url = "https://www.togcoding.com/togcoding/"
}

public void OnPluginStart()
{
    CreateConVar("tbdi_version", PLUGIN_VERSION, "TOG Bot Damage Immunity - version number.", FCVAR_NOTIFY|FCVAR_DONTRECORD);
}

public void OnClientPutInServer(int client)
{
    SDKHook(client, SDKHook_OnTakeDamage, Event_OnTakeDamage);
}

public void OnClientDisconnect(int client)
{
    SDKUnhook(client, SDKHook_OnTakeDamage, Event_OnTakeDamage);
}

public Action Event_OnTakeDamage(int victim, int &attacker, int &inflictor, float &fDamage, int &damagetype, int &weapon, float a_fDmgForce[3], float a_fDmgPosition[3])
{
    if (IsValidClient(victim) && IsFakeClient(victim) || IsClientReplay(victim))
    {
        fDamage = 0.0;
        return Plugin_Changed;
    }
    
    return Plugin_Continue;
}

bool IsValidClient(int client)
{
    if(!(1 <= client <= MaxClients) || !IsClientInGame(client))
    {
        return false;
    }
    
    return true;
}

stock void Log(char[] sPath, const char[] sMsg, any ...) //TOG logging function - path is relative to logs folder.
{
    char sLogFilePath[PLATFORM_MAX_PATH], sFormattedMsg[1500];
    
    BuildPath(Path_SM, sLogFilePath, sizeof(sLogFilePath), "logs/%s", sPath);
    VFormat(sFormattedMsg, sizeof(sFormattedMsg), sMsg, 3);
    LogToFileEx(sLogFilePath, "%s", sFormattedMsg);
}

/////////////////////////////////////////////////////////////////////////////////////////
/////////////////////////////////////// CHANGE LOG //////////////////////////////////////
/////////////////////////////////////////////////////////////////////////////////////////
/*
    1.0.1
        * Tiny re-factor courtesy of B3none.
    
    1.0.0
        * Initial creation.
        
*/ 


[ttasdasda]

m_takedamage 0

[Mitchell]

remove all those checks but mainly IsValidClient lol how insane is that function within a sdkhooks callback. A callback that wouldn't fire for some one not actually hooked... And guess what, you're hooking the client when they are put in the server... Something like this should work, and be immune.

PHP Code:

#pragma semicolon 1
#define PLUGIN_VERSION "1.1.0"
#include <sdkhooks>

#pragma newdecls required

public Plugin myinfo =
{
    name = "TOG Bot Damage Immunity",
    author = "That One Guy",
    description = "Makes bot/replay clients immune to damage",
    version = PLUGIN_VERSION,
    url = "https://www.togcoding.com/togcoding/"
}

public void OnPluginStart()
{
    CreateConVar("tbdi_version", PLUGIN_VERSION, "TOG Bot Damage Immunity - version number.", FCVAR_NOTIFY|FCVAR_DONTRECORD);
}

public void OnClientPutInServer(int client)
{
    if (IsFakeClient(client) || IsClientReplay(client))
    {
        SDKHook(client, SDKHook_OnTakeDamage, Event_OnTakeDamage);
    }
}

public void OnClientDisconnect(int client)
{
    SDKUnhook(client, SDKHook_OnTakeDamage, Event_OnTakeDamage);
}

public Action Event_OnTakeDamage(int victim, int &attacker, int &inflictor, float &fDamage, int &damagetype, int &weapon, float a_fDmgForce[3], float a_fDmgPosition[3]/*, int damagecustom*/)
{
    return Plugin_Stop;
} 


m_takedamage 0 is a terrible solution since there are several plugins that modify that property.

[ThatOneGuy]

Originally Posted by b3none Perhaps: PHP Code: if (IsValidClient(victim) && IsFakeClient(victim) || IsClientReplay(victim))

IsFakeClient and IsClientReplay were nested under IsValidClient because I couldnt remember if it causes an error if those functions are passed an invalid client index.

Originally Posted by ttasdasda m_takedamage 0

That would indeed be a better solution provided it isnt later modified by another plugin, e.g., a super admin plugin with God Mode commands. If the server operator is sure no other plugins modify that property, that could work well.

Originally Posted by Mitchell ...you're hooking the client when they are put in the server

Good point. That would indeed be a better solution as no checks are necessary after the initial check. Even though this was intended to just be an old plugin dump, I'll make that edit real quick and update the OP. Just a note though, returning Plugin_Stop could prevent other plugins that may need to hook that event (e.g. stats plugins counting the damage).

OP version updated to 1.1.0.