[ambn]

Can you just edit my code and tell me how? i just got so confused testing different methods and still nothing.

[ambn]

This is how i did it:

Spoiler

PHP Code:

char PlayerItem[MAXPLAYERS+1][4];
stock void GetClientWeapons()
{
    for(int client; client <= MaxClients; client++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            for(int slot; slot <= 4; slot++)
            {
                if(slot == 1)
                {
                    int wep = GetPlayerWeaponSlot(client, slot);
                    GetEntityClassname(wep, PlayerItem[client][0], sizeof(PlayerItem[]));
                }
                else if(slot == 2)
                {
                    int wep = GetPlayerWeaponSlot(client, slot);
                    GetEntityClassname(wep, PlayerItem[client][1], sizeof(PlayerItem[]));
                }
                else if(slot == 3)
                {
                    int wep = GetPlayerWeaponSlot(client, slot);
                    GetEntityClassname(wep, PlayerItem[client][2], sizeof(PlayerItem[]));
                }
                else if(slot == 4)
                {
                    int wep = GetPlayerWeaponSlot(client, slot);
                    GetEntityClassname(wep, PlayerItem[client][3], sizeof(PlayerItem[]));
                }
            }
        }
    }
}
stock void GiveClientWeapons()
{
    for(int client; client <= MaxClients; client++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            for(int slot; slot <= 4; slot++)
            {
                if(slot == 1)
                {
                    if(!StrEqual(PlayerItem[client][0], ""))
                    {
                        GivePlayerItem(client, PlayerItem[client][0]);
                    }
                }
                else if(slot == 2)
                {
                    if(!StrEqual(PlayerItem[client][1], ""))
                    {
                        GivePlayerItem(client, PlayerItem[client][1]);
                    }
                }
                else if(slot == 3)
                {
                    if(!StrEqual(PlayerItem[client][2], ""))
                    {
            
                        GivePlayerItem(client, PlayerItem[client][2]);
                    }
                }
                else if(slot == 4)
                {
                    if(!StrEqual(PlayerItem[client][3], ""))
                    {
                        GivePlayerItem(client, PlayerItem[client][3]);
                    }
                }
            }
        }
    }
} 


[c00lio]

Originally Posted by OSWO Slot 0 = Primary, why do you exactly not want to check the Primary Slot?

In his code, doesn't use slot = 0 at all but starts from 0

[sdz]

Here's what I PERSONALLY would've done, just note I am not the top diggity dog around here.
To me, it's more readable and edit friendly if you loop through clients and pass each client index individually whenever you are to call GetClientWeapons() and GiveClientWeapons().

My Rendition of the Stocks:

PHP Code:

int playerWeapons[MAXPLAYERS + 1][5];

stock void GetClientWeapons(int client)
{
    for(int slot = 0; slot <= 4; slot++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            playerWeapons[client][slot] = GetPlayerWeaponSlot(client, slot);
        }
    }
}

stock void GiveClientWeapons(int client)
{
    for(int slot = 0; slot <= 4; slot++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            if(IsValidEntity(playerWeapons[client][slot]))
            {
                char Weapon_ClassName[32];
                GetEdictClassname(playerWeapons[client][slot], Weapon_ClassName, sizeof(Weapon_ClassName));
                GivePlayerItem(client, Weapon_ClassName);
            }
        }
    }
} 


so instead of

My Examples in play

PHP Code:

{
    GiveClientWeapons();
    return Plugin_Handled;
} 


You'll want to do something like this...

PHP Code:

{
     for(int i = 1; i <= MaxClients; i++)
     {
          GivePlayerWeapons(client);
     }
} 


[ambn]

well thank you for your replay it seems very clean , so i'm gonna test this now.

[ambn]

I used GetClientWeapons(client) on cs_pre_restart event then fired GiveClientWeapons(client) with a timer after 0.5 seconds on round start but nothing happens ...

[sdz]

Run some debugging, check values every step of the way. Make sure your cs_pre_restart event is even firing. Lots you can do. Perhaps increase that timer to 1.0-1.5 to compensate for player lag?
Also, it looks like you wanted to give weapons, so this is what I would personally do..

PHP Code:


int playerWeapons[MAXPLAYERS + 1][5];
char weaponClass[MAXPLAYERS + 1][5][32];

stock void GetClientWeapons(int client)
{
    for(int slot = 0; slot <= 4; slot++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            if(playerWeapons[client][slot] = GetPlayerWeaponSlot(client, slot) > -1)
            {
                GetEdictClassname(playerWeapons[client][slot], weaponClass[client][slot], 32);
            }
            else weaponClass[client][slot] = "";
        }
    }
}

stock void GiveClientWeapons(int client)
{
    for(int slot = 0; slot <= 4; slot++)
    {
        if(IsClientInGame(client) && IsPlayerAlive(client))
        {
            if(playerWeapons[client][slot] > -1)
            {
                GivePlayerItem(client, weaponClass[client][slot]);
            }
        }
    }
} 


[ambn]

I'll test it tomorrow and thank you for helping me getting this work , it would be awesome if we can talk on steam if possible, add me if possible and again thank you.

[TnTSCS]

In the Zeus Round plugin, there is a section where I get and store the player's weapons and then give them back to them later. You can take a look at that and see if that code helps get you to where you want to go.

Here's a snippet of that plugin pertaining to weapons

Spoiler

PHP Code:

GetClientWeapons(client)
{
    new prim, sec;
    
    PrimarySlot[client][0] = '\0';
    SecondarySlot[client][0] = '\0';
    
    ClientHasWeapons[client] = true;
    
    prim = GetPlayerWeaponSlot(client, CS_SLOT_PRIMARY);
    
    if (prim > MaxClients)
    {
        GetEntityClassname(prim, PrimarySlot[client], sizeof(PrimarySlot[]));
    }
    else
    {
        Format(PrimarySlot[client], sizeof(PrimarySlot), "NONE");
    }
    
    sec = GetPlayerWeaponSlot(client, CS_SLOT_SECONDARY);
    
    if (sec > MaxClients)
    {
        GetEntityClassname(sec, SecondarySlot[client], sizeof(SecondarySlot[]));
    }
    else
    {
        Format(SecondarySlot[client], sizeof(SecondarySlot), "NONE");
    }
    
    HEGrenades[client] = GetClientHEGrenades(client);
    FlashBangs[client] = GetClientFlashbangs(client);
    SmokeGrenades[client] = GetClientSmokeGrenades(client);
    DecoyGrenades[client] = GetClientDecoyGrenades(client);
    INCGrenades[client] = GetClientIncendaryGrenades(client);
}

GiveClientWeapons(client)
{
    GivePlayerItem(client, "weapon_knife");
    
    if (HEGrenades[client] > 0)
    {
        for (new g = 0; g < HEGrenades[client]; g++)
        {
            GivePlayerItem(client, "weapon_hegrenade");
        }
        
        HEGrenades[client] = 0;
    }
    
    if (FlashBangs[client] > 0)
    {
        for (new fb = 0; fb < FlashBangs[client]; fb++)
        {
            GivePlayerItem(client, "weapon_flashbang");
        }
        
        FlashBangs[client] = 0;
    }
    
    if (SmokeGrenades[client] > 0)
    {
        for (new sg = 0; sg < SmokeGrenades[client]; sg++)
        {
            GivePlayerItem(client, "weapon_smokegrenade");
        }
        
        SmokeGrenades[client] = 0;
    }
    
    if (DecoyGrenades[client] > 0)
    {
        for (new dg = 0; dg < DecoyGrenades[client]; dg++)
        {
            GivePlayerItem(client, "weapon_decoy");
        }
        
        DecoyGrenades[client] = 0;
    }
    
    if (INCGrenades[client] > 0)
    {
        for (new ig = 0; ig < INCGrenades[client]; ig++)
        {
            if (GetClientTeam(client) == CS_TEAM_CT)
            {
                GivePlayerItem(client, "weapon_incgrenade");
            }
            else
            {
                GivePlayerItem(client, "weapon_molotov");
            }
        }
        
        INCGrenades[client] = 0;
    }
    
    if (!StrEqual(SecondarySlot[client], "NONE", false))
    {
        GivePlayerItem(client, SecondarySlot[client]);
        
        SecondarySlot[client][0] = '\0';
    }
    
    if (!StrEqual(PrimarySlot[client], "NONE", false))
    {
        GivePlayerItem(client, PrimarySlot[client]);
        
        PrimarySlot[client][0] = '\0';
    }
} 


[sdz]

Already solved this with the OP, sorry if anyone wasted massive time writing snippets