[amirwolf]

Hello, I have a question
If I add a flag to menu_additem
How do I add a message of no access to it?

[bigdaddy424]

Using paccess param from menu_additem will disable item from being pressed if you don't have specified access.

PHP Code:

#include <amxmodx>
#include <amxmisc>

#define VIP_FLAG "t"
#define _VIP_FLAG ADMIN_LEVEL_H

public plugin_init()
    register_clcmd("say test", "run_test")

public run_test(id){
    new menu = menu_create("My menu", "menu_handler")
    menu_additem(menu, "Item 1", .paccess=_VIP_FLAG)
    menu_additem(menu, fmt("%sItem 2", has_flag(id, VIP_FLAG) ? "" : "\d"))
    menu_display(id, menu)
}

public menu_handler(id, menu, item){
    switch (item) {
        case 0: client_print(id, print_chat, "Item 1")
        case 1: client_print(id, print_chat, "%s", has_flag(id, VIP_FLAG) ? "Item 2" : "You don't have permission")
    }

    menu_destroy(menu)
} 


[fysiks]

If you add a flag in the "paccess" argument of menu_additem(), the item is automatically greyed out and disabled in the menu if the player does not have that access flag. Nothing else is needed.

EDIT: Looks like someone posted since I first opened the thread (had to leave for a while).

[amirwolf]

For example, I have this
No access message?

PHP Code:

#include <amxmodx>
#include <cstrike>

enum _:Models
{
    Name[20],
    NameModel[20],
    RUTA[126],
    FlagAdmin
}

new const g_eModels[][Models] =
{
    { "hutao", "hutao", "models/player/hutao/hutao.mdl" , ADMIN_ALL},
    { "spiderman", "admin_spiderman", "models/player/donald/admin_spiderman.mdl", ADMIN_SLAY},
    { "woailuo", "flash_woailuo", "models/player/donald/flash_woailuo.mdl", ADMIN_LEVEL_B}
}

public plugin_init()
{
    register_clcmd("say /test", "ModelMenu")
}

public plugin_precache()
{
    for(new i; i < sizeof(g_eModels); i++)
        precache_generic(g_eModels[i][RUTA])
}

public ModelMenu(id)
{
    new iMenu = menu_create("Models Menu", "ModelsHandler")
    
    for(new i; i < sizeof(g_eModels); i++)
        menu_additem(iMenu, g_eModels[i][Name], "", g_eModels[i][FlagAdmin])
    menu_display(id, iMenu, 0)
    
    return PLUGIN_HANDLED
}

public ModelsHandler(id, iMenu, iItem){
    if(iItem == MENU_EXIT)
    {
        menu_destroy(iMenu);
        return PLUGIN_HANDLED;
    }
    cs_set_user_model(id, g_eModels[iItem][NameModel])
    client_print(id, print_chat, "Selected Model: %s", g_eModels[iItem][Name])
    return PLUGIN_HANDLED
} 


[lexzor]

if you want a chat message you can pass the flag as a string and check in menu callback if the user has the specified flag or flags

PHP Code:

#include <amxmodx>
#include <cstrike>

enum _:Models
{
    Name[20],
    NameModel[20],
    RUTA[126],
    FlagAdmin[6]
}

new const g_eModels[][Models] =
{
    //changed the flag as a string (you must use read_flags to transform it in bytes and use get_user_flags)
    { "hutao", "hutao", "models/player/hutao/hutao.mdl" , "a" },
    { "spiderman", "admin_spiderman", "models/player/donald/admin_spiderman.mdl", "b"},
    { "woailuo", "flash_woailuo", "models/player/donald/flash_woailuo.mdl", "c"}
}

public plugin_init()
{
    register_clcmd("say /test", "ModelMenu")
}

public plugin_precache()
{
    for(new i; i < sizeof(g_eModels); i++)
    {
        //better check if the model exists so the server won't crash
        //doesn't make any sense here but it s a good practice
        if(file_exists(g_eModels[i][RUTA]))
        {
            precache_generic(g_eModels[i][RUTA])
        }
        else 
        {
            log_amx("Model ^"%s^" does not exists", g_eModels[i][RUTA])
        }
    }
}

public ModelMenu(id)
{
    new iMenu = menu_create("Models Menu", "ModelsHandler")
    
    for(new i; i < sizeof(g_eModels); i++)
    {
        // i'm just passing the flag from the global var as string data
        menu_additem(iMenu, g_eModels[i][Name], g_eModels[i][FlagAdmin])
    }

    menu_display(id, iMenu, 0)
    
    return PLUGIN_HANDLED
}

public ModelsHandler(id, iMenu, iItem){
    if(iItem == MENU_EXIT)
    {
        menu_destroy(iMenu);
        return PLUGIN_HANDLED;
    }

    new szModelName[64], szFlag[6]
    menu_item_getinfo(iMenu, iItem, _, szFlag, charsmax(szFlag), szModelName, charsmax(szModelName))

    if(!(get_user_flags(id) & read_flags(szFlag)))
    {
        client_print(id, print_chat, "You don't have the access to use ^"%s^" model", szModelName)
        ModelMenu(id)
        return PLUGIN_HANDLED
    }

    cs_set_user_model(id, g_eModels[iItem][NameModel])
    client_print(id, print_chat, "Selected Model: %s", g_eModels[iItem][Name])
    
    return PLUGIN_HANDLED
} 


[amirwolf]

I already tried using menu_item_getinfo
But it didn't work, I think the reason was the incorrect use of flags
Thanks, now I understand the problem
Edit
But still not what I was looking for

[lexzor]

what are you looking for? don't understand

[bigdaddy424]

you need something like this but keep in mind that the folder name must match player model name.
for eg. elastigirl/elastigirl.mdl and not extra/elastigirl.mdl

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>
#include <hamsandwich>

enum _:Models
{
    Name[20],
    NameModel[20],
    RUTA[126],
    FlagAdmin
}

new const g_eModels[][Models] =
{
    { "hutao", "hutao", "models/player/hutao/hutao.mdl" , ADMIN_ALL},
    { "spiderman", "admin_spiderman", "models/player/donald/admin_spiderman.mdl", ADMIN_SLAY},
    { "woailuo", "flash_woailuo", "models/player/donald/flash_woailuo.mdl", ADMIN_LEVEL_B} 
}

new my_model[MAX_PLAYERS + 1]

public plugin_init()
{
    register_clcmd("say /test", "ModelMenu")
    RegisterHam(Ham_Spawn, "player", "HookSpawn", 1)
}

public plugin_precache()
{
    for(new i; i < sizeof(g_eModels); i++)
        precache_generic(g_eModels[i][RUTA])
}

public client_putinserver(id)
    my_model[id] = 0

public HookSpawn(id)
    cs_set_user_model(id, g_eModels[my_model[id]][NameModel])

public ModelMenu(id)
{
    new iMenu = menu_create("Models Menu", "ModelsHandler")
    
    for(new i; i < sizeof(g_eModels); i++)
        menu_additem(iMenu, g_eModels[i][Name])
    menu_display(id, iMenu, 0)
    
    return PLUGIN_HANDLED
}

public ModelsHandler(id, iMenu, iItem){
    if (iItem > MENU_MORE){
        if (access(id, g_eModels[iItem][FlagAdmin])){
            my_model[id] = iItem
            cs_set_user_model(id, g_eModels[my_model[id]][NameModel])
            client_print(id, print_chat, "Selected Model: %s", g_eModels[my_model[id]][Name])
            
        }
        
        else
            client_print(id, print_chat, "You don't have permission")
    }

    menu_destroy(iMenu)
} 


[amirwolf]

Thanks to both of you
Another question, if I want the model to be reloaded after each Spawn
How to connect the selected model?
If a person has not chosen a model, I will choose a specific model for him

[bigdaddy424]

i edited my prev post, i think it should work just fine