This code will save a users frags between connections (disconnect\map-change) and allow them to purchase a reward using frags as the currency. Use the /buyreward chat command to purchase the reward.
PHP Code:
#include <amxmodx>
#include <amxmisc>
#include <fun>
#include <nvault>
new g_szAuthID[33][33];
new g_iBot[33];
new g_iFrags[33];
new g_pEnabled;
new g_pRewardPrice;
new g_iVault;
new g_iMsgScoreInfo;
new const g_szVaultFile[] = "frag_save";
public plugin_init()
{
register_plugin( "Frag_Save" , "2.0" , "-Acid-" );
register_clcmd( "say /buyreward" , "cmdBuyReward" );
register_clcmd( "say_team /buyreward" , "cmdBuyReward" );
register_event( "ScoreInfo" , "fwEvScoreInfo" , "a" );
g_pEnabled = register_cvar( "fs_enabled" , "1" );
g_pRewardPrice = register_cvar( "fs_rewardprice" , "2" );
g_iMsgScoreInfo = get_user_msgid( "ScoreInfo" );
register_dictionary( "Frag_Save.txt" );
}
public plugin_cfg()
{
g_iVault = nvault_open( g_szVaultFile );
if ( g_iVault == INVALID_HANDLE )
set_fail_state( "Error opening nVault" );
}
public plugin_end()
{
nvault_close( g_iVault );
}
public client_putinserver( id )
{
if ( !get_pcvar_num( g_pEnabled ) )
return PLUGIN_CONTINUE;
g_iBot[ id ] = is_user_bot( id );
if ( !g_iBot[ id ] )
{
get_user_authid( id , g_szAuthID[ id ] , 32 );
new iFrags = nvault_get( g_iVault , g_szAuthID[ id ] );
if ( iFrags )
{
g_iFrags[ id ] = iFrags;
set_user_frags( id , iFrags );
}
}
return PLUGIN_CONTINUE;
}
public client_disconnect( id )
{
if ( !get_pcvar_num( g_pEnabled ) )
return PLUGIN_CONTINUE;
if ( !g_iBot[ id ] && g_iFrags[ id ] )
{
new szFrags[ 6 ];
num_to_str( g_iFrags[id] , szFrags , 5 );
nvault_set( g_iVault , g_szAuthID[ id ] , szFrags );
}
g_iFrags[ id ] = 0;
g_iBot[ id ] = 0;
return PLUGIN_CONTINUE;
}
public fwEvScoreInfo()
{
if ( !get_pcvar_num( g_pEnabled ) )
return PLUGIN_CONTINUE;
new id = read_data( 1 );
new iFrags = read_data( 2 );
//The server resets scores at mapchange so this will set the players score [if g_iFrags[] > 0].
if ( !iFrags && g_iFrags[ id ] )
{
set_user_frags( id , g_iFrags[ id ] );
return PLUGIN_CONTINUE;
}
g_iFrags[ id ] = iFrags;
return PLUGIN_CONTINUE;
}
public cmdBuyReward( id )
{
if ( !get_pcvar_num( g_pEnabled ) )
return PLUGIN_HANDLED;
new iRewardPrice = get_pcvar_num( g_pRewardPrice );
if ( g_iFrags[ id ] >= iRewardPrice )
{
//
//Put your reward code here
//
g_iFrags[ id ] -= iRewardPrice;
set_user_frags( id , g_iFrags[ id ] );
cmdUpdateScoreBoard( id );
client_print( id , print_chat , "* You have purchased the reward (-%d frags)" , iRewardPrice );
}
else
{
client_print( id , print_chat , "* You do not have enough frags to buy reward" );
}
return PLUGIN_HANDLED;
}
public cmdUpdateScoreBoard(id)
{
message_begin( MSG_ALL , g_iMsgScoreInfo );
write_byte( id );
write_short( get_user_frags( id ) );
write_short( get_user_deaths( id ) );
write_short( 0 );
write_short( get_user_team( id ) );
message_end( );
}
Linear Mode
