[Prajch]

Is there a circumstance under which removing an entity could cause a server to freeze? I have a plugin that's freezing my server a small fraction of the time and I can't pin down the problem.

(I'm using EF_RemoveEntity from fakemeta_stocks.inc)

[ConnorMcLeod]

It would help with your code.

You can try :

PHP Code:

set_pev(entity, pev_flags, FL_KILLME)
dllfunc(DLLFunc_Think, entity) 


[Prajch]

Well it's a fairly big section of code... I'll try what you suggested and see if it helps, thanks.

[SchlumPF*]

usually removing should not freeze the server. removing entitys can just fuck up the map if you remove every single spawn withotu creating enw ones or bombzones etc if your server is a ordinary shooting server.

[Prajch]

I'm starting to think that RemoveEntity isn't the problem... Here's a section of the code that I think contains what is causing the freeze.

PHP Code:

     if(elapsedTime >= fuseTime && bombExists[ownerID])
     {
          static Float:damage, Float:radius
          damage = get_pcvar_float(cvar_damage)
          radius = get_pcvar_float(cvar_radius)
 
          new i = 0
 
          while(i < 32)
          {
               i = EF_FindEntityInSphere(i, bombOrigin, radius)
 
               static Float:origin[3], Float:distance
               pev(i, pev_origin, origin)
               distance = get_distance_f(bombOrigin, origin)
 
               if(is_user_alive(i) && distance <= radius)
               {
                    static Float:health
                    pev(i, pev_health, health)
                    health = health - damage * (1.0 - distance / radius)      //distance-dependent damage
 
                    if(health >= 1.0)
                    {
                         set_pev(i, pev_health, health)
                    }
                    else
                    {
                         //create a cherry bomb death message
                         message_begin(MSG_ALL, deathMsgid)
                         write_byte(ownerID)
                         write_byte(i)
                         write_byte(0)
                         write_string("cherry bomb")
                         message_end()
 
                         user_silentkill(i)
                         ////////////////////////////////////////////////////////////////
                         //Update the victim's scoreboard to cancel the loss of a frag.//
                         //user_silentkill() doesn't update it immediately.            //
                         //If it isn't delayed, the message gets overridden.           //
                         ////////////////////////////////////////////////////////////////
                         static frags, deaths, team
                         frags = get_user_frags(i)
                         deaths = get_pdata_int(i, OFFSET_CSDEATHS)
                         team = get_pdata_int(i, OFFSET_TEAM)
 
                         set_pev(i, pev_frags, float(frags)) //update frags
 
                         static arg[3]
                         arg[0] = frags
                         arg[1] = deaths
                         arg[2] = team
                         set_task(0.1, "scoreUpdate", i, arg, 3)
                         ////////////////////////////////////////////////////////
                         //Give the killer a frag, unless it was self-inflicted//
                         ////////////////////////////////////////////////////////
                         if(i != ownerID)
                         {
                              frags = get_user_frags(ownerID) + 1
                              deaths = get_pdata_int(ownerID, OFFSET_CSDEATHS)
                              team = get_pdata_int(ownerID, OFFSET_TEAM)
 
                              set_pev(ownerID, pev_frags, float(frags)) //update frags
 
                              arg[0] = frags
                              arg[1] = deaths
                              arg[2] = team
                              set_task(0.1, "scoreUpdate", ownerID, arg, 3)
                         }
                    }
               }
          }
          //create the explosion visuals and sounds
          EF_MessageBegin(MSG_PVS, SVC_TEMPENTITY, bombOrigin, 0)
          write_byte(TE_EXPLOSION)
          EF_WriteCoord(bombOrigin[0] + 10.0)
          EF_WriteCoord(bombOrigin[1])
          EF_WriteCoord(bombOrigin[2] + 5.0)
          write_short(explosionIndex)
          write_byte(10)               //scale in 0.1's
          write_byte(45)               //framerate
          write_byte(TE_EXPLFLAG_NOSOUND)     //flags
          message_end()
 
          emit_sound(bomb, CHAN_BODY, explosionSound, 0.7, ATTN_NORM, 0, 200)
          emit_sound(bomb, CHAN_WEAPON, explosionSound2, 0.6, ATTN_NORM, 0, 175)
 
          EF_RemoveEntity(bomb)
          bombExists[ownerID] = false //owner no longer has a bomb deployed
     } 


[Alka]

If that code from above is called on a forward try to return SUPERCEDE, to handle the nextthink of ent. But i think that while(i < 32) is creating an infinite loop.

[Prajch]

Hmm you know, you're probably right! I never thought about the case where it wouldn't be able to find enough entities around it to go beyond 32. I'll try that tonight.

By the way it is called on a forward. Why do you say it should return FMRES_SUPERCEDE?

[edit] Also does FindEntityInSphere return 0 on failure only, or is it possible that it could return 0 when hitting worldspawn?

[Styles]

[edit] Also does FindEntityInSphere return 0 on failure only, or is it possible that it could return 0 when hitting worldspawn?

while(ent = FindEnitityInSphear

;) I'm not tying it out you seem smart enough ... but as far as Iknow, it loops for ever and while true (while there is an entity) blah..

[Prajch]

Originally Posted by styles [edit] Also does FindEntityInSphere return 0 on failure only, or is it possible that it could return 0 when hitting worldspawn? while(ent = FindEnitityInSphear ;) I'm not tying it out you seem smart enough ... but as far as Iknow, it loops for ever and while true (while there is an entity) blah..

[edit] Nevermind, misunderstood your code. That's a pretty good idea.