Correct safety remove entity - Page 2

DeMNiX · 10-13-2023 , 04:53 Re: Correct safety remove entity

Quote:

Originally Posted by MrPickles

error will throw, u are starting the think to an invalid entity, u removed it before with FL_KILLME

setting KILL ME or with remove_entity( ent ) its more than enough.

Nope. FL_KILLME will remove object on next server tick.
On current server tick we just forcing to call Think function by DLLFunc_Think

lexzor · 10-13-2023 , 04:54 Re: Correct safety remove entity

not the next server tick, next entity tick

Jhob94 · 10-13-2023 , 05:24 Re: Correct safety remove entity

Quote:

Originally Posted by mlibre

OR

PHP Code:


			
stock kill_entity(ent)

{

    entity_set_int(ent, EV_INT_flags, FL_KILLME)

}

Why do you make a stock for 1 single line?

Anyway lexzor and natesh are right. Depending on what entity you are managing you may or may not need to call the entity think.
If you know that the entity think won't be called in a very short period of time you must call it yourself.

lexzor · 10-13-2023 , 05:29 Re: Correct safety remove entity

you guys are just turning a simple situation into a complex one

to delete an entity, on it's next think must have flag FL_KILLME

is not important how do you call next think

DeMNiX · 10-13-2023 , 05:42 Re: Correct safety remove entity

unexpected result

Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>

new g_iFrame;

public plugin_init()
{
	RegisterHookChain(RH_ED_Free, "fw_OnFreeEdictPre");
	register_forward(FM_StartFrame, "fw_OnStartFrame")
	RegisterHam(Ham_Think, "info_target", "fw_NextThink");	
	RegisterHam(Ham_Think, "info_target", "fw_NextThink", true);	
}

public plugin_cfg()
{
	set_task(5.0, "test_func");
}

public fw_OnStartFrame()
{
	g_iFrame++;
}

public test_func()
{
	new iEnt = rg_create_entity("info_target");

	if (iEnt > 0) {

		set_entvar(iEnt, var_classname, "test_kill");

		new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
		server_print("~~~ OnSpawn [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);

		dllfunc(DLLFunc_Think, iEnt);
		set_entvar(iEnt, var_nextthink, get_gametime());
		set_entvar(iEnt, var_flags, FL_KILLME);
		dllfunc(DLLFunc_Think, iEnt);
                dllfunc(DLLFunc_Think, iEnt);
	}
}

public fw_NextThink(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntThink [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

public fw_OnFreeEdictPre(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntRemove [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

Code:

~~~ OnSpawn [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntThink [test_kill][6.074496][4047]
~~~ OnEntRemove [test_kill][6.074496][4047]

seems like not on think? but on end of the server's frame tick?

or OnStartFrame call after check all ents on flkillme flag?

DeMNiX · *Last edited by DeMNiX; 10-13-2023 at 05:56.*

>is not important how do you call next think
its true, but interesting

seems like on the end of the server frame ent removes

Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>

new g_iFrame;
new g_bShouldPrintNewFrame;

public plugin_init()
{
	RegisterHookChain(RH_ED_Free, "fw_OnFreeEdictPre");
	RegisterHookChain(RH_ED_Free, "fw_OnFreeEdictPost", true);
	register_forward(FM_StartFrame, "fw_OnStartFrame")
	RegisterHam(Ham_Think, "info_target", "fw_NextThink");	
	RegisterHam(Ham_Think, "info_target", "fw_NextThink", true);	
}

public plugin_cfg()
{
	set_task(5.0, "test_func");
}

public fw_OnStartFrame()
{
	g_iFrame++;

	if (g_bShouldPrintNewFrame) {
		server_print("~~~ OnStartFrame [%f][%d]", get_gametime(), g_iFrame);
		g_bShouldPrintNewFrame = false;
	}
}

public test_func()
{
	new iEnt = rg_create_entity("info_target");

	if (iEnt > 0) {

		set_entvar(iEnt, var_classname, "test_kill");

		new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
		server_print("~~~ OnSpawn [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);

		dllfunc(DLLFunc_Think, iEnt);
		set_entvar(iEnt, var_nextthink, get_gametime());
		set_entvar(iEnt, var_flags, FL_KILLME);
		dllfunc(DLLFunc_Think, iEnt);
		dllfunc(DLLFunc_Think, iEnt);

		g_bShouldPrintNewFrame = true;
	}
}

public fw_NextThink(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntThink [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

public fw_OnFreeEdictPre(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntRemove [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

public fw_OnFreeEdictPost(iEnt)
{
	server_print("~~~ OnEntRemovePost [%f][%d]", get_gametime(), g_iFrame);
	RequestFrame("fw_OnNextFrame");
}

public fw_OnNextFrame()
{
	server_print("~~~ 	OnNextFrame [%f][%d]", get_gametime(), g_iFrame);
}

Code:

~~~ OnSpawn [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntRemove [test_kill][6.081494][4052]
~~~ OnEntRemovePost [6.081494][4052]
~~~ OnStartFrame [6.081494][4053]
~~~     OnNextFrame [6.081494][4053]

so, with fl_killme none requires to checks on valid ents with dllfunc_think

mlibre · 10-13-2023 , 10:12 Re: Correct safety remove entity

Quote:

Originally Posted by Jhob94

Why do you make a stock for 1 single line?

It is a simplified example to use in more functions. I always prefer to use the engine instead of fakemeta

Jhob94 · 10-13-2023 , 11:42 Re: Correct safety remove entity

Quote:

Originally Posted by DeMNiX

>is not important how do you call next think
its true, but interesting

seems like on the end of the server frame ent removes

Code:

#include <amxmodx>
#include <fakemeta>
#include <hamsandwich>
#include <reapi>

new g_iFrame;
new g_bShouldPrintNewFrame;

public plugin_init()
{
	RegisterHookChain(RH_ED_Free, "fw_OnFreeEdictPre");
	RegisterHookChain(RH_ED_Free, "fw_OnFreeEdictPost", true);
	register_forward(FM_StartFrame, "fw_OnStartFrame")
	RegisterHam(Ham_Think, "info_target", "fw_NextThink");	
	RegisterHam(Ham_Think, "info_target", "fw_NextThink", true);	
}

public plugin_cfg()
{
	set_task(5.0, "test_func");
}

public fw_OnStartFrame()
{
	g_iFrame++;

	if (g_bShouldPrintNewFrame) {
		server_print("~~~ OnStartFrame [%f][%d]", get_gametime(), g_iFrame);
		g_bShouldPrintNewFrame = false;
	}
}

public test_func()
{
	new iEnt = rg_create_entity("info_target");

	if (iEnt > 0) {

		set_entvar(iEnt, var_classname, "test_kill");

		new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
		server_print("~~~ OnSpawn [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);

		dllfunc(DLLFunc_Think, iEnt);
		set_entvar(iEnt, var_nextthink, get_gametime());
		set_entvar(iEnt, var_flags, FL_KILLME);
		dllfunc(DLLFunc_Think, iEnt);
		dllfunc(DLLFunc_Think, iEnt);

		g_bShouldPrintNewFrame = true;
	}
}

public fw_NextThink(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntThink [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

public fw_OnFreeEdictPre(iEnt)
{
	new szClassname[32]; get_entvar(iEnt, var_classname, szClassname, charsmax(szClassname));
	server_print("~~~ OnEntRemove [%s][%f][%d]", szClassname, get_gametime(), g_iFrame);
}

public fw_OnFreeEdictPost(iEnt)
{
	server_print("~~~ OnEntRemovePost [%f][%d]", get_gametime(), g_iFrame);
	RequestFrame("fw_OnNextFrame");
}

public fw_OnNextFrame()
{
	server_print("~~~ 	OnNextFrame [%f][%d]", get_gametime(), g_iFrame);
}

Code:

~~~ OnSpawn [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntThink [test_kill][6.081494][4052]
~~~ OnEntRemove [test_kill][6.081494][4052]
~~~ OnEntRemovePost [6.081494][4052]
~~~ OnStartFrame [6.081494][4053]
~~~     OnNextFrame [6.081494][4053]

so, with fl_killme none requires to checks on valid ents with dllfunc_think

As you can see it removes the Ent after think is called and before start frame.
So it is called on think. Anyway, this is irrelevant on most of cases.

metal_upa · 10-14-2023 , 05:45 Re: Correct safety remove entity

If you are using ReAPI then you can explore my code.
This is a template that i use on my custom entity.

Spoiler

PHP Code:


			
#include <amxmodx>
#include <fakemeta>
#include <reapi>

#pragma semicolon 1

new const szEntityName[] = "remove_me";
new const szModelRemove[] = "models/w_usp.mdl";
new const szSoundRemove[] = "weapons/c4_explode1.wav";
new const szSoundThink[] = "weapons/he_bounce-1.wav";

public plugin_precache()
{
    precache_model(szModelRemove);
    precache_sound(szSoundRemove);
    precache_sound(szSoundThink);
}

public plugin_init()
{
    register_plugin("Remove Me", "0.0.1", "metal_upa");

    register_clcmd("say /tt", "CmdCreateMe");
}

public CmdCreateMe(id)
{
    if(!is_user_alive(id)) return;

    new ent = rg_create_entity("info_target");
    if(ent <= MaxClients) return;

    new Float:vecSrc[3];
    get_entvar(id, var_origin, vecSrc);

    set_entvar(ent, var_classname, szEntityName);
    set_entvar(ent, var_movetype, MOVETYPE_TOSS);
    set_entvar(ent, var_solid, SOLID_TRIGGER);
    set_entvar(ent, var_owner, id);

    engfunc(EngFunc_SetOrigin, ent, vecSrc);
    engfunc(EngFunc_SetModel, ent, szModelRemove);
    engfunc(EngFunc_SetSize, ent, Float:{0.0,0.0,0.0}, Float:{0.0,0.0,0.0});
    
    SetThink(ent, "OnThinkRemove");
    SetTouch(ent, "OnTouchRemove");

    new Float:flTime = get_gametime();
    set_entvar(ent, var_fuser1, flTime + 10.0); //auto remove time
    set_entvar(ent, var_nextthink, flTime + 0.4);
}

public OnThinkRemove(const ent)
{
    if(!is_entity(ent)) return;

    //owner not connected? remove the entity
    new id = get_entvar(ent, var_owner);
    if(!is_user_connected(id))
    {
        emit_sound(ent, CHAN_WEAPON, szSoundRemove, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
        RemoveEntitySafe(ent);
        return;
    }

    //entity time has expired? remove the entity
    new Float:flTime = get_gametime();
    if(get_entvar(ent, var_fuser1) < flTime)
    {
        client_print(id, print_chat, "[DEBUG] Entity:%i time expired!", ent);
        emit_sound(ent, CHAN_WEAPON, szSoundRemove, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
        RemoveEntitySafe(ent);
        return;
    }

    //entity time is active? loop the think if you want.
    //set the nextthink to any value you want.
    client_print(id, print_chat, "[DEBUG] OnThinkRemove(%i) Think!", ent);
    emit_sound(ent, CHAN_WEAPON, szSoundThink, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
    set_entvar(ent, var_nextthink, flTime + 1.0);
}

public OnTouchRemove(const ent, const id)
{
    if(!is_entity(ent) || !is_user_alive(id)) return HC_CONTINUE;
    
    //owner not connected anymore
    new atk = get_entvar(ent, var_owner);
    if(!is_user_connected(atk))
    {
        emit_sound(ent, CHAN_WEAPON, szSoundRemove, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
        RemoveEntitySafe(ent);
        return HC_CONTINUE;
    }

    //owner touch their entity? block the touch
    if(id == atk) return HC_SUPERCEDE;

    //someone touch owner's entity? delete the entity
    client_print(id, print_chat, "[DEBUG] OnTouchRemove(%i, %i) -- BAMM entity remove!", ent, id);
    emit_sound(ent, CHAN_WEAPON, szSoundRemove, VOL_NORM, ATTN_NORM, 0, PITCH_NORM);
    RemoveEntitySafe(ent);

    return HC_CONTINUE;
}

RemoveEntitySafe(ent)
{
    SetThink(ent, "");
    SetTouch(ent, "");
    set_entvar(ent, var_flags, FL_KILLME);
    dllfunc(DLLFunc_Think, ent);
}

Arje · 10-15-2023 , 12:04 Re: Correct safety remove entity

Quote:

Originally Posted by Natsheh

This is the proper way to remove entities with specific classname by owner...

PHP Code:


			
new ent = MAX_PLAYERS + 1;



while( (ent = find_ent_by_owner(ent, gBlackHole_EntName, id)) > 0)

{

    set_pev(ent, pev_flags, FL_KILLME);

    dllfunc(DLLFunc_Think, ent);

}

Thanks lexzor and Natsheh for the help, both codes worked, although I stick with what you said that it is the best way to eliminate entities so I will use it,

On the other hand, I have a question regarding eliminating by owner, that is, it will only eliminate the entities that were created by that owner, or it will eliminate all entities independently of the owner, that is, I do not have to create a array for each entity created to correspond to each player,and then eliminate the entities that player is the owner?