Raised This Month: $51 Target: $400
 12% 

Solved Need Help!


Post New Thread Reply   
AlliedModders Forum Index > SourceMod > Scripting
 
Thread Tools Display Modes
Author Message
beastedout
Member
Join Date: Aug 2018
Old 09-09-2018 , 06:57   Need Help!
Reply With Quote #1
PHP Code:
public Action CMD_Team(int client, int args)
{
    if(!IsClientValid(client) || !IsClientInGame(client))
    {
        return Plugin_Handled;
    }
    
    if((args != 2) && (args != 3))
    {
        ReplyToCommand(client, "%t", "CMD_Team_Usage");
        return Plugin_Handled;
    }
    
    char target_name[MAX_TARGET_LENGTH];
    char buffer[64];
    int    target_list[MAXPLAYERS], target_count;
    bool tn_is_ml;
        
    
    GetCmdArg(1, buffer, sizeof(buffer));
    if((target_count = ProcessTargetString(buffer, client, target_list, MAXPLAYERS, COMMAND_FILTER_CONNECTED, target_name, sizeof(target_name), tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }
    
    char team[64];
    GetCmdArg(2, buffer, sizeof(buffer));
    if(StrEqual(buffer, "spectator", false) || StrEqual(buffer, "spec", false) || StrEqual(buffer, "1", false))
    {
        team = CS_TEAM_SPECTATOR;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_Spec", target_name);
            LogActionEx(client, "%t", "CMD_Team_Spec", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_Spec", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_Spec", "_s", target_name);
        }
    }
    else if(StrEqual(buffer, "t", false) || StrEqual(buffer, "2", false))
    {
        team = CS_TEAM_T;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_T", target_name);
            LogActionEx(client, "%t", "CMD_Team_T", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_T", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_T", "_s", target_name);
        }
    }
    else if(StrEqual(buffer, "ct", false) || StrEqual(buffer, "3", false))
    {
        team = CS_TEAM_CT;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_CT", target_name);
            LogActionEx(client, "%t", "CMD_Team_CT", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_CT", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_CT", "_s", target_name);
        }
    }
    else
    {
        ReplyToCommand(client, "%t", "CMD_Invalid_Team");
        return Plugin_Handled;
    }
    
    GetCmdArg(3, buffer, sizeof(buffer));
    int value = StringToInt(buffer);
    
    for(int i = 0; i < target_count; i++)
    {
        if(IsClientInGame(target_list[i]))
        {
            if(!value)
            {
                if(team != 1)
                {
                    CS_SwitchTeam(target_list[i], team);
                    if(IsPlayerAlive(target_list[i]))
                    {
                        CS_RespawnPlayer(target_list[i]);
                    }
                }
                else
                {
                    ChangeClientTeam(target_list[i], team);
                }
            }
            else
            {
                SetEntProp(target_list[i], Prop_Data, "m_iPendingTeamNum", team);
            }
        }
    }
    return Plugin_Handled;
} 
Errors: http://prntscr.com/ksb0qg
Can someone help please?(I'm still learning, don't be harsh )
Last edited by beastedout; 09-09-2018 at 07:31.
beastedout is offline
Fyren
FyrenFyrenFyrenFyrenFyren FyrenFyrenFyrenFyrenFyren FyrenFyrenFyrenFyrenFyren FyrenFyrenFyrenFyrenFyren
Join Date: Feb 2106
Old 09-09-2018 , 07:11   Re: Need Help!
Reply With Quote #2
You defined team as a 64-character string, which is an array, but you're using it as an integer.
Fyren is offline
Neuro Toxin
Veteran Member
Neuro Toxin's Avatar
Join Date: Oct 2013
Location: { closing the void; }
Old 09-09-2018 , 17:21   Re: Need Help!
Reply With Quote #3
Please share how you solved your problem for future readers.
__________________
Neuro Toxin is offline
beastedout
Member
Join Date: Aug 2018
Old 09-10-2018 , 03:16   Re: Need Help!
Reply With Quote #4
PHP Code:
public Action CMD_Team(int client, int args)
{
    if(!IsClientValid(client) || !IsClientInGame(client))
    {
        return Plugin_Handled;
    }
    
    if((args != 2) && (args != 3))
    {
        ReplyToCommand(client, "%t", "CMD_Team_Usage");
        return Plugin_Handled;
    }
    
    char target_name[MAX_TARGET_LENGTH], buffer[512];
    int target_list[MAXPLAYERS], target_count;
    bool tn_is_ml;
    
    GetCmdArg(1, buffer, sizeof(buffer));
    if((target_count = ProcessTargetString(buffer, client, target_list, MAXPLAYERS, COMMAND_FILTER_CONNECTED, target_name, sizeof(target_name), tn_is_ml)) <= 0)
    {
        ReplyToTargetError(client, target_count);
        return Plugin_Handled;
    }
    
    int team;
    GetCmdArg(2, buffer, sizeof(buffer));
    if(StrEqual(buffer, "spectator", false) || StrEqual(buffer, "spec", false) || StrEqual(buffer, "1", false))
    {
        team = CS_TEAM_SPECTATOR;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_Spec", target_name);
            LogActionEx(client, "%t", "CMD_Team_Spec", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_Spec", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_Spec", "_s", target_name);
        }
    }
    else if(StrEqual(buffer, "t", false) || StrEqual(buffer, "2", false))
    {
        team = CS_TEAM_T;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_T", target_name);
            LogActionEx(client, "%t", "CMD_Team_T", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_T", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_T", "_s", target_name);
        }
    }
    else if(StrEqual(buffer, "ct", false) || StrEqual(buffer, "3", false))
    {
        team = CS_TEAM_CT;
        if(tn_is_ml)
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_CT", target_name);
            LogActionEx(client, "%t", "CMD_Team_CT", target_name);
        }
        else
        {
            ShowActivity2(client, CMD_PREFIX, "%t", "CMD_Team_CT", "_s", target_name);
            LogActionEx(client, "%t", "CMD_Team_CT", "_s", target_name);
        }
    }
    else
    {
        ReplyToCommand(client, "%t", "CMD_Invalid_Team");
        return Plugin_Handled;
    }
    
    GetCmdArg(3, buffer, sizeof(buffer));
    int value = StringToInt(buffer);
    
    for(int i = 0; i < target_count; i++)
    {
        if(IsClientInGame(target_list[i]))
        {
            if(value == 1)
            {
                if(team != 1)
                {
                    CS_SwitchTeam(target_list[i], team);
                    if(IsPlayerAlive(target_list[i]))
                    {
                        CS_RespawnPlayer(target_list[i]);
                    }
                }
                else
                {
                    ChangeClientTeam(target_list[i], team);
                }
            }
            else
            {
                SetEntProp(target_list[i], Prop_Data, "m_iPendingTeamNum", team);
            }
        }
    }
    return Plugin_Handled;
} 
Here we go! Thanks Fyren!
Last edited by beastedout; 09-10-2018 at 03:20.
beastedout is offline
Reply
AlliedModders Forum Index > SourceMod > Scripting

« Previous Thread | Next Thread »


Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts
BB code is On
Smilies are On
[IMG] code is On
HTML code is Off
Forum Jump


All times are GMT -4. The time now is 01:39.

DMCA - Archive - Top

Powered by vBulletin®
Copyright ©2000 - 2024, vBulletin Solutions, Inc.
Theme made by Freecode