[Darkimmortal]

Originally Posted by CrimsonGT I am considering writing a small MMS plugin that changes the stun to a daze effect if theres enough interest in it.

It would be even better if you were able to provide an option to simply prevent the effect entirely

[teddyruxpin]

I would take a look at these 2 as a hold over until a way to remove them is found. You can also wack the entry from the /scripts/items/items.ctx file but that is a dirty hack.

sm_cvar tf_player_movement_stun_time 0
sm_cvar tf_scout_stunball_ball_regen_rate 300

This should make the stun time 0 and regen rate for the ball 5 mins.

-Teddy

[HL-SDK]

I've heard tf_player_movement_stun_time has a MIN of 4 elsewhere on this forum.

[CrimsonGT]

You can change convar bounds with code.

SetConVarBounds(Handle:convar, ConVarBounds:type, bool:set, Float:value=0.0);

[HL-SDK]

That is pretty cool, I may try doing that instead of what I typed up last night. I haven't been able to test it yet - was updating the ded server.

/*  */
#include <sourcemod>
#include <tf2_stocks>
new Handle:cvarSandmanEnable = INVALID_HANDLE;
new Handle:cvarClass = INVALID_HANDLE;
 
public Plugin:myinfo = 
{
 name = "Strip Sandman",
 author = "HL-SDK",
 description = "<- Description ->",
 version = "0.1",
 url = "<- URL ->"
}
public OnPluginStart()
{
 HookEvent("player_spawn", event_PlayerSpawn);
 cvarSandmanEnable = CreateConVar("sm_sandman_enable", "1", "Enable/Disable the sandman", FCVAR_PLUGIN, true, 0.0, true, 1.0);
}
 
public Action:event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
 if (GetConVarInt(cvarSandmanEnable) == 0)
  return Plugin_Continue;
 new client = GetClientOfUserId(GetEventInt(event, "userid"));
 decl String:classString[32];
 GetConVarString(cvarClass, classString, sizeof(classString));
 new TFClassType:class = TF2_GetClass(classString);
 if (class == TFClass_Scout)
 {
  CreateTimer(0.1, timer_RemoveWeap, client);
 }
 return Plugin_Continue;
}
 
public Action:timer_RemoveWeap(Handle:timer, any:client)
{
 TF2_RemoveWeaponSlot(client, 2);
}

It is supposed to strip the scout's melee bucket, then I will re-equip it later. I'll also try changing the counds of that cvar.

On similar lines: I don't have the scout unlockables. Is there a command to unlock them all temporarily with sv_cheats 1?

[Hfuhruhurr]

This sounds very promising thanks for your effort HL-SDK it's very much appreciated.

[HL-SDK]

I tried changing bounds of tf_movement_player_Stun_time and verified that it was set to 0. I was still knocked to 3rd person and could not move.

Now I'm modding what I've posted so far to actually give a weapon for melee instead of depriving him of his oh-so-beloved bat.

Well with my ineperience, and bl4nk's pure awesome, I was able to mangle his givenameditem plugin so that whenever a player spawns, the plugin executes a servercommand.

I do it this way because I couldn't get the call_startfunction to pass the arguments correctly :'(

Feel free to look over what is 98% bl4nk's code in attachment. My addition was:

public Action:event_PlayerSpawn(Handle:event, const String:name[], bool:dontBroadcast)
{
 if (GetConVarInt(cvarSandmanEnable) == 1)
  return Plugin_Continue;
 new client = GetClientOfUserId(GetEventInt(event, "userid"));
 new userid = GetClientUserId(client);
 new String:weapString[32];
 GetConVarString(cvarWeap, weapString, sizeof(weapString));
 
 decl String:classString[32];
 GetConVarString(cvarClass, classString, sizeof(classString));
 
 new TFClassType:class = TF2_GetClass(classString);
 if (TF2_GetPlayerClass(client) == class)
 {
  ServerCommand("sm_givenameditem %s %s", userid, weapString);
 }
 return Plugin_Continue;
}

[MikeJS]

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
#include <tf2_stocks>
new Handle:gameConf;
new Handle:giveNamedItem;
new Handle:weaponEquip;
new Handle:g_hEnabled = INVALID_HANDLE;
new bool:g_bEnabled = true;
public OnPluginStart() {
    gameConf = LoadGameConfigFile("sandman.games");
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(gameConf, SDKConf_Virtual, "GiveNamedItem");
    PrepSDKCall_AddParameter(SDKType_String, SDKPass_Pointer);
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);
    PrepSDKCall_AddParameter(SDKType_PlainOldData, SDKPass_Plain);
    PrepSDKCall_SetReturnInfo(SDKType_CBaseEntity, SDKPass_Plain);
    giveNamedItem = EndPrepSDKCall();
    StartPrepSDKCall(SDKCall_Player);
    PrepSDKCall_SetFromConf(gameConf, SDKConf_Virtual, "WeaponEquip");
    PrepSDKCall_AddParameter(SDKType_CBaseEntity, SDKPass_Pointer);
    weaponEquip = EndPrepSDKCall();
    g_hEnabled = CreateConVar("sm_nosandman", "1", "Enable no sandman", FCVAR_PLUGIN|FCVAR_NOTIFY);
    HookConVarChange(g_hEnabled, Cvar_enabled);
}
public OnMapStart() {
    CreateTimer(5.0, WpnCheck);
}
public OnConfigsExecuted() {
    g_bEnabled = GetConVarBool(g_hEnabled);
}
public Cvar_enabled(Handle:convar, const String:oldValue[], const String:newValue[]) {
    g_bEnabled = GetConVarBool(g_hEnabled);
    if(g_bEnabled) {
        WpnCheck(INVALID_HANDLE);
    }
}
public Action:WpnCheck(Handle:timer) {
    new ent;
    decl String:wpn[64];
    for(new i=1;i<=MaxClients;i++) {
        if(IsClientConnected(i) && IsClientInGame(i) && IsPlayerAlive(i)) {
            if((ent = GetPlayerWeaponSlot(i, 2))!=-1) {
                GetEdictClassname(ent, wpn, sizeof(wpn));
                if(StrEqual(wpn, "tf_weapon_bat_wood")) {
                    TF2_RemoveWeaponSlot(i, 2);
                    new entity = SDKCall(giveNamedItem, i, "tf_weapon_bat", 0, 0);
                    SDKCall(weaponEquip, i, entity);
                    PrintToChat(i, "Your sandman has been removed.");
                }
            }
        }
    }
    if(g_bEnabled) {
        CreateTimer(5.0, WpnCheck);
    }
} 


Replaces a player's sandman with a normal bat.

[HL-SDK]

Originally Posted by MikeJS Replaces a player's sandman with a normal bat.

*bow* *bow* *bow*

My hero! Now I see the right way to do it. Thank you, you are credit to team!

[Balisong]

Thanks a lot for creating this plugin guys, and so fast !
I'll try this on my server right away
+ 1