[Natsheh]

Originally Posted by Cristian505 Yesssssss! Please help me (

Here this is how the main plugin should look like, it will set players zombie class randomly on each spawn.

Spoiler

PHP Code:

#include <amxmodx>
#include <fakemeta_util>
#include <hamsandwich>

#define MAX_ZOMBIE_NAME_CHARS 32

new Array:g_array_zclass_name = Invalid_Array, g_zombie_classes_counter;

#define TASK_HUD 123131

new g_iZOMBIE_CLASS[33] = { -1, -1, ... }, g_forward_zombie_spawn;

public plugin_init()
{
    RegisterHam(Ham_Spawn, "player", "Player_Spawned", 1);
    g_forward_zombie_spawn = CreateMultiForward("us_zombie_spawned", ET_IGNORE, FP_CELL, FP_CELL);
}

public client_disconnect(id)
{
    remove_task(id + TASK_HUD);
}

public plugin_end()
{
    ArrayDestroy(g_array_zclass_name);
}

public plugin_precache()
{
    g_array_zclass_name = ArrayCreate(MAX_ZOMBIE_NAME_CHARS, 1);
}

public Player_Spawned(id)
{
    if(!is_user_alive(id) || !g_zombie_classes_counter) return;

    g_iZOMBIE_CLASS[id] = random(g_zombie_classes_counter);
    
    new dummy
    ExecuteForward(g_forward_zombie_spawn, dummy, id, g_iZOMBIE_CLASS[id]);

    remove_task(TASK_HUD + id);
    set_task(0.1, "hud", TASK_HUD + id);
}

public plugin_natives()
{
    register_native("register_zombie_class", "native_register_zm_class");
}

public hud(task)
{
   new id = task - TASK_HUD

   static szZombieName[MAX_ZOMBIE_NAME_CHARS];
   ArrayGetString(g_array_zclass_name, g_iZOMBIE_CLASS[id], szZombieName, charsmax(szZombieName));
   set_hudmessage(255, 90, 0, 0.02, 0.92, 0, 0.0, 0.3, 0.0, 0.0, 7);
   show_hudmessage(id, "Zombie Class: %s", szZombieName);
 
   set_task(0.1, "hud", TASK_HUD + id);
}

public native_register_zm_class(plugin, argc)
{
    static szZombieName[MAX_ZOMBIE_NAME_CHARS];
    get_string(1, szZombieName, charsmax(szZombieName));

    if(!szZombieName[0])
    {
        server_print("Can not register an empty zombie classname!");
        return -1;
    }

    if(g_iZOMBIE_CLASS[0] == -1)
    {
        arrayset(g_iZOMBIE_CLASS, 0, sizeof g_iZOMBIE_CLASS);
    }

    ArrayPushString(g_array_zclass_name, szZombieName);
    g_zombie_classes_counter++;
    return ( g_zombie_classes_counter-1 ) ;
} 


[Cristian505]

...

[Cristian505]

...

[Cristian505]

...

[Black Rose]

Originally Posted by Cristian505 Hello again! How does this code works? return ( g_zombie_classes_counter-1 ) Why not g_zombie_class_counter - 1? Why - 1? From what i know about amxx every 'new x' starts from 0.

So the first register will push the variable +1, but it will return the index of the last created entry.

What it does (in short):
native_register_zm_class() is called
Array is pushed to index 0.
g_zombie_classes_counter++; ( 0 -> 1, this is just to prepare for the NEXT entry )
return 0, because that's what the calling plugin is interested in. 1 is for the next entry, not actually in use yet. But it still has to be done within the function because there's no secondary function.

If you tried to do the increment after the function is done using set_task() that would really give you trouble as everything is called on plugin_init() (for example) and ALL of the set_task() would be executed afterwards. That means that everything would be given the index 0 and then it would increment the variable +n after EVERY registration is done.
Sometimes code is ugly, especially API code. But it works, without any problem. That's the important thing.

You could however start the index at -1, increment it at the beginning of the function. Everything will use the index selected (in the first case "0") and return just that. And at the next call it will increment to 1 before doing anything else.
Note that the function doesn't actually use the variable so it could be incremented anywhere, but it still would have to start at -1 if you're returning the value after it is being incremented.

new g_zombie_classes_counter = -1;
// ...

public native_register_zm_class(plugin, argc)
{
    g_zombie_classes_counter++;
    static szZombieName[MAX_ZOMBIE_NAME_CHARS];
    get_string(1, szZombieName, charsmax(szZombieName));

    if(!szZombieName[0])
    {
        server_print("Can not register an empty zombie classname!");
        return -1;
    }

    if(g_iZOMBIE_CLASS[0] == -1)
    {
        arrayset(g_iZOMBIE_CLASS, 0, sizeof g_iZOMBIE_CLASS);
    }

    ArrayPushString(g_array_zclass_name, szZombieName);
    return g_zombie_classes_counter;
}

In most languages you could (I think) do:

return g_zombie_classes_counter++;

but in pawn this is broken and will return a memory address or something (I don't actually know but it's not what you would expect).

It's just a matter of personal preference.

[OciXCrom]

In most languages you could (I think) do: return g_zombie_classes_counter++; but in pawn this is broken and will return a memory address or something (I don't actually know but it's not what you would expect). It's just a matter of personal preference.

This works just fine actually, I use it all the time. It will, however, iterate the number after returning it. It's the same as using:

g_zombie_classes_counter++;
return g_zombie_classes_counter - 1;

If you want to iterate it first, you should do:

return ++g_zombie_classes_counter;

Which is the same as doing:

g_zombie_classes_counter++;
return g_zombie_classes_counter;

[Natsheh]

return g_zombie_classes_counter++;

This might look valid but its not, the previous statement means return a value then do the increment but we all know after a return the function code will no longer be executed.

[OciXCrom]

Like I said, it works just fine.

[Black Rose]

My previous experience:
https://forums.alliedmods.net/showthread.php?t=241630

[Cristian505]

...