[LearninG]

Hi,
why would this have errors ? :

PHP Code:

#include <amxmodx>

enum _:PlayerInfo
{
    Player_Name[32] ,
    Player_Authid[35]
}

new g_PlayerData[ 33 ] [ PlayerInfo ]

public plugin_init()
{
    register_clcmd("say /test" , "test")
}

public test(id)
{
    new eInfo[g_PlayerData] // difference
    get_user_name(id , eInfo[Player_Name] , charsmax(eInfo[Player_Name]))
    get_user_authid(id , eInfo[Player_Authid] , charsmax(eInfo[Player_Authid]))
    
    client_print(id , print_chat , "Your name is : %s" , eInfo[Player_Name])
    client_print(id , print_chat , "Your steamid is : %s" , eInfo[Player_Authid] )
} 


error 008: must be a constant expression; assumed zero error 017: undefined symbol "eInfo" warning 215: expression has no effect error 001: expected token: ";", but found "]" error 029: invalid expression, assumed zero fatal error 107: too many error messages on one line

however this one compiles and works fine in game.

PHP Code:

#include <amxmodx>

enum _:PlayerInfo
{
    Player_Name[32] ,
    Player_Authid[35]
}

new g_PlayerData[ 33 ] [ PlayerInfo ]

public plugin_init()
{
    register_clcmd("say /test" , "test")
}

public test(id)
{
    new eInfo[PlayerInfo] // difference 
    get_user_name(id , eInfo[Player_Name] , charsmax(eInfo[Player_Name]))
    get_user_authid(id , eInfo[Player_Authid] , charsmax(eInfo[Player_Authid]))

    client_print(id , print_chat , "Your name is : %s" , eInfo[Player_Name])
    client_print(id , print_chat , "Your steamid is : %s" , eInfo[Player_Authid] )
} 


warning 203: symbol is never used: "g_PlayerData" Header size: 256 bytes Code size: 404 bytes Data size: 240 bytes Stack/heap size: 16384 bytes Total requirements: 17284 bytes 1 Warning. Done. [Finished in 0.3s]

so if we do not need this here , where we will need it ?

PHP Code:

new g_PlayerData[ 33 ] [ PlayerInfo ] 


[E1_531G]

g_PlayerData is an array, and PlayerInfo is an enum.
You cannot create an array using other array as dimension.

so if we do not need this here , where we will need it ?

you need it here:

get_user_name(id , g_PlayerData[id][Player_Name] , charsmax(g_PlayerData[][Player_Name]))

now you have player's name in this global array, and you can use it anywhere you need it.

[Natsheh]

You are getting those errors because you are trying to declare an array size with a non constant value/uncomplete memory address of the var, declaring an array size should be done with pre defined size so the compiler would know what size it should be assigned for.

Note:
Also declaring global array variables should always be in the first of the script and thier sizes before them

[LearninG]

Originally Posted by E1_531G g_PlayerData is an array, and PlayerInfo is an enum. You cannot create an array using other array as dimension. so if we do not need this here , where we will need it ? you need it here: get_user_name(id , g_PlayerData[id][Player_Name] , charsmax(g_PlayerData[][Player_Name])) now you have player's name in this global array, and you can use it anywhere you need it.

works , thanks.

Originally Posted by Natsheh Note: Also declaring global array variables should always be in the first of the script and thier sizes before them

like this ?

PHP Code:

#define MAX_PLAYERS   32

enum _:PlayerInfo
{
    Player_Name[32] ,
    Player_Authid[35]
}

new g_PlayerData[MAX_PLAYERS + 1] [ PlayerInfo ] 


or

PHP Code:

#define G_PLAYER_DATA_SIZE  33

enum _:PlayerInfo
{
    Player_Name[32] ,
    Player_Authid[35]
}

new g_PlayerData[G_PLAYER_DATA_SIZE] [ PlayerInfo ] 


[Bugsy]

Either technically works but I prefer the first since it indicates what you are holding in the array. MAX_PLAYERS is used across the majority of plugins and everyone knows what it corresponds to. G_PLAYER_DATA_SIZE does not tell the same story.