[Longcat]

Hello.

There is an interest connected with the tagging system of PAWN.

There is a tagof operator, but I cannot understand how does it work.

tagof s results in the a unique number that represents the tag of the variable, the constant, the function result or the tag label. When used in a default value for a function argument, the expression is evaluation at the point of the function call, instead of in the function denition.

The context is the following: when we use a function like this one:

func({Float, bool, _}: x)
{
    ...
}

we may have a question about an actual tag of x. In the tutor it is claimed that a following construct should be used:

func({Float, bool, _}: x, type_x = tagof x)
{
    ...
}

I checked this with a following combination:

public timed(id)
{    
    new Float: x = 3.0;
    new bool: y = true;
    new z = 4;
    
    func1(x, y);
    func1(y, y);
    func1(z, y);
}

func1({Float, _}: a, type_a = tagof a)
{
    new Float: flt, bool: bl, int;
    
    switch(type_a)
    {
        case tagof(flt):     log_amx "a is float";
        case tagof(bl):        log_amx "a is bool";
        case tagof(int):    log_amx "a is int";
    }
}

The output looks like:

a is int
a is int
a is int

So, what is the right usage of tagof?
Thanks.

[Arkshine]

It's probably kind of bugged, and also tricky.

To fix tagof inside function header, you need to use a macro so compiler computer the actual tag value, something like:

#define do_test(%1) func(.type = tagof %1)

public timed()
{    
    new Float:x = 3.0;
    new bool:y = true;
    new z = 4;

    do_test(x);
    do_test(y);
    do_test(z);
}
func(type)
{
    new Float:a, bool:b, c;

    switch(type)
    {
        case tagof(a): log_amx "a is float";
        case tagof(b): log_amx "a is bool";
        case tagof(c): log_amx "a is int";
    }
    
    #pragma unused a
    #pragma unused b
    #pragma unused c
}

Passing a value, you would need to use the any: magic tag.

#define do_test(%1) func(.value = %1, .type = tagof %1)

func(any:value, type)
{
    new Float:a, bool:b, c;

    switch(type)
    {
        case tagof(a): log_amx "value = %f", value;
        case tagof(b): log_amx "value = %d", value;
        case tagof(c): log_amx "value = %d", value;
    }
    
    #pragma unused a
    #pragma unused b
    #pragma unused c
}

I'm not sure why you would get different value doing if (tagof(Float:)) and if (tagof(a))n because using variable is kind of dumb.

EDIT: About this ^, it would seem that I can fix it easily. In compiler it misses a flag. After the patch, tagof in the header work fine (and against tagof(Float:) too).
EDIT2: https://github.com/alliedmodders/amxmodx/pull/191

[Longcat]

Originally Posted by Arkshine EDIT2: https://github.com/alliedmodders/amxmodx/pull/191

Thank you very much for the response.

But, how can I use the GitHub files to get the compiler patched?

[Arkshine]

You can grab compiler from latest build : http://www.amxmodx.org/snapshots.php

Be aware that it's compiler from 1.8.3-dev.