[lucas_7_94]

/* Plugin generated by AMXX-Studio */

/* INI FILE */
/*
"weapon_m4a1" "models/newmodel/m4a1.mdl"
"weapon_ak47" "models/newmodel/ak47.mdl" 
*/

#include <amxmodx>
#include <amxmisc>
#include <hamsandwich>
#include <fakemeta>

new i, g_size

new EntName[ 64 ][ 64 ]
new ModelName[ 64 ][ 64 ]


public plugin_init() {
    
    for( i = 0; i < g_size ; i++ )
        RegisterHam( Ham_Item_Deploy, EntName[ i ] , "fwReplaceModels", 1);
}

public plugin_precache( ) 
{
    load_settings( "models.ini" );
}

load_settings( const File[] )
{
    static szFilename[136];
    static szPath[ 64 ];

    get_configsdir(szPath, 63);
    formatex(szFilename, 63, "%s/%s", szPath, File);
    
    static szData[64]
    static iLen
    static iPos 
    iPos = 0;
    while (read_file( szFilename, iPos++, szData,63,iLen))
    {
        remove_quotes(szData)

        if (iLen == 0 || check_invalid_chars(szData) ) // Saltear linea si se encuentra un ; o # al principio
            continue;
            
        parse( szData, EntName[g_size], charsmax(EntName), ModelName[g_size], charsmax(ModelName) );
        
        precache_model( ModelName[ i ] );
        
        g_size++
    }
}

bool:check_invalid_chars( const string[] = " " )
{
    if( string[0] == '#' || string[0] == ';' || (string[0] == '/' && string[1] == '/' ) )
        return true; // se encontro un string invalido , por lo tanto returna con 1 ( true )
    
    return false; // no se encontro nada , por lo tanto , returnea 0 (falso , no se encontro ningun dato)
    
}

public fwReplaceModel( entity )
{
    if( pev_valid( entity ) != 2 ) return HAM_IGNORED;
    
    new id = get_pdata_cbase( entity, 41, 4 );
    
    static entclass[32];
    pev(entity, pev_classname, entclass, 31);

    
    for( i = 0; i < g_size; i++ )
    {
        if( equal( entclass, EntName[ i ]) )
            set_pev( id, pev_viewmodel2, ModelName[ i ] );
        
    }
    
    return HAM_IGNORED;
}

[Arkshine]

Use the new file natives.
Trie would be more appropriate here.
Don't use static in a function called just one time.
Why 64 ? There are only 30 weapons if I'm right but again a trie would be better.

[Exolent[jNr]]

You can try this one:

[lucas_7_94]

I don't know how to use Tries , is any tutorial here or a explication about that?

[Exolent[jNr]]

Originally Posted by lucas_7_94 I don't know how to use Tries , is any tutorial here or a explication about that?

Tries are basically arrays that are indexed by a string rather than a number.

Example:

// this is not legit AMXX code, just pseudo code

set[0] = 1; // normal array way

set["value"] = 1; // TrieSetCell
set["value"] = "1"; // TrieSetString
set["value"] = {1,2,3}; // TrieSetArray

value = set["value"]; // TrieGetCell/String/Array

if("value" in set) // TrieKeyExists 

Think of Tries as Arrays and keys as indexes.

[lqlqlq]

Exo, give me a example for weapon_models.ini please.

[ConnorMcLeod]

Example is in last link he gave you.

Version updated : https://forums.alliedmods.net/showth...74#post1641974

[Lolz0r]

LOL thanks, but who plugin is better(ConnorMcLeod or Exolent[jNr] or lucas)?

[lucas_7_94]

exolent, arkshine , or connor , or somebody , i made this.

public plugin_init() {
    
    WeaponInfo[ 0 ] = TrieCreate( );
    WeaponInfo[ 1 ] = TrieCreate( );
    
    static what[32]
        
    for( i = 0; i < g_size ; i++ )
    {
        RegisterHam( Ham_Item_Deploy, whathere, "fwReplaceModels", 1);
    }
}

public plugin_precache( ) 
{
    load_settings( "models.ini" );
}

load_settings( const File[] )
{
    new iFile = fopen( File, "rt" ); 
    if( !iFile ) return;
    
    new szBuffer[1024]
    while( !feof( iFile ) ) 
    { 
        fgets( iFile, szBuffer, charsmax( szBuffer ) ); 
        
        remove_quotes( szBuffer )
        
        if( check_invalid_chars(szBuffer) )
            continue
        
        parse( szBuffer, classname, charsmax(classname), model, charsmax(model) );
        
        precache_model( model );
        
        TrieSetCell(WeaponInfo[ 0 ], classname, g_size)
        TrieSetCell(WeaponInfo[ 1 ], model, g_size)
        g_size++
        
        
    } 
}

But , how i can get the value from the trie in the loop ?

[Exolent[jNr]]

Originally Posted by ConnorMcLeod Example is in last link he gave you.

No, it's different than yours.

Originally Posted by lqlqlq Exo, give me a example for weapon_models.ini please.

Mine has the classname with the associated view model:

"weapon_ak47" "models/custom_weapons/v_ak47.mdl"

Originally Posted by lucas_7_94 But , how i can get the value from the trie in the loop ?

You are using the tries wrong.

new Trie:gWeaponModels;

public plugin_precache( ) 
{
    gWeaponModels = TrieCreate( );
    
    load_settings( "models.ini" );
}

load_settings( const File[] )
{
    new iFile = fopen( File, "rt" ); 
    if( !iFile ) return;
    
    new szBuffer[1024]
    while( !feof( iFile ) ) 
    { 
        fgets( iFile, szBuffer, charsmax( szBuffer ) ); 
        
        remove_quotes( szBuffer )
        
        if( check_invalid_chars(szBuffer) )
            continue
        
        parse( szBuffer, classname, charsmax(classname), model, charsmax(model) );
        
        precache_model( model );
        
        if( !TrieKeyExists( gWeaponModels, classname ) ) {
            RegisterHam( Ham_Item_Deploy, classname, "FwdItemDeployPost", 1 );
        }
        
        TrieSetString( gWeaponModels, classname, model );
    } 
}

public FwdItemDeployPost( entity )
{
    new classname[ 32 ], model[ 64 ];
    entity_get_string( entity, EV_SZ_classname, classname, charsmax( classname ) );
    
    if( TrieGetString( gWeaponModels, classname, model, charsmax( model ) )
    {
        const m_pPlayer = 41;
        
        new id = get_pdata_cbase( entity, m_pPlayer, 4 );
        
        entity_set_string( id, EV_SZ_viewmodel, model );
    }
}

Some variables aren't defined in your load_settings() function, though.