[notMe2]

I'm trying to execute the code bellow, but the only the first query executes:

for(int i = 0; i <= MAXPLAYERS; i++)
{
    if(!isValidClient(i))
        continue;

    //query build

    SQL_TQuery(hDb, T_CommomQuery, sQuery, _, DBPrio_Normal); 
}

Any ideas why?

[shavit]

not sure why exactly, but initialize the loop like this:

for(int i = 1; i <= MaxClients; i++)

client indexes start from 1 and looping until MAXPLAYERS is bad because it's a constant value (i think of 55); looping up to MaxClients is better because that's the biggest number that could be an entity index with your maxplayer setting

[notMe2]

Originally Posted by shavit not sure why exactly, but initialize the loop like this: for(int i = 1; i <= MaxClients; i++) client indexes start from 1 and looping until MAXPLAYERS is bad because it's a constant value (i think of 55); looping up to MaxClients is better because that's the biggest number that could be an entity index with your maxplayer setting

Hey shavit, thanks for your tips.

The usual game is only 5 vs. 5, i don't think that the size of loop is the problem. The problem is that only the first query is executed, the other 9 (in case of 5vs5) are ignored.

[Kryptanyte]

I'm not sure if I'm right about this but starting a query inside the for loop will break it (end the for loop) and wait for the query to respond.

You could try using transactions instead of doing each query individually - Transactions take several queries and execute them sequentially then pass results back to callbacks.

See this for more information: https://sm.alliedmods.net/new-api/dbi/Database/Execute

eg:

Transaction th_Queries = null;
th_Queries = SQL_CreateTransaction();
     
for(int i = 1; i < MaxClients; i++)
    SQL_AddQuery(th_Queries, /*Put your query here*/, /*Put your query data (if any) here*/);

SQL_Execute(hDb, th_Queries, SQL_QuerySuccess_Callback, SQL_QueryFailed_Callback);

Also don't think you can do threaded transaction queries so you will need to lock your database I would assume since you have to for regular queries, I'm not very familiar with threaded queries so if someone wants to correct me if I'm wrong please feel free

[Mitchell]

Also if you plan on passing a client id through the transaction make sure you convert it to userid then convert it back to index when the callback is called.
Transactions are the best way to catch all players instead of doing one by one.
I have an example of using two different queries to get player settings etc in my build mod:

Spoiler

public LoadAllPlayerSettings() {
	Transaction transaction = SQL_CreateTransaction();
	int accountID;
	char buffer[256];
	int userID = -1;
	for(int i = 1; i <= MaxClients; i++) {
		if(IsClientInGame(i) && !IsFakeClient(i)) {
			userID = GetClientUserId(i);
			accountID = GetSteamAccountID(i);
			Format(buffer, sizeof(buffer), "SELECT * FROM player_settings WHERE accountid='%i';", accountID);
			SQL_AddQuery(transaction, buffer, userID);
			Format(buffer, sizeof(buffer), "SELECT * FROM save_aliases WHERE accountid='%i';", accountID);
			SQL_AddQuery(transaction, buffer, userID);
		}
	}
	SQL_ExecuteTransaction(g_hDatabase, transaction, SQLT_GetPlayerSettings);
}

public SQLT_GetPlayerSettings(Handle db, any data, int numQueries, Handle[] results, any[] queryData) {
	int client;
	char settingsAttrib[32];
	char settingsValue[32];
	int tempInts[4];
	for(int x=0,y=1;x<numQueries;x+=2,y+=2) {
		client = GetClientOfUserId(queryData[x]);
		if(client <= 0) continue;
		if(SQL_GetRowCount(results[x]) > 0) {
			while(SQL_FetchRow(results[x])) {
				SQL_FetchString(results[x], 1, settingsAttrib, sizeof(settingsAttrib));
				SQL_FetchString(results[x], 2, settingsValue, sizeof(settingsValue));
				SetPlayerSettings(client, settingsAttrib, settingsValue);
			}
		}
		if(SQL_GetRowCount(results[y]) > 0) {
			while(SQL_FetchRow(results[y])) {
				tempInts[0] = SQL_FetchInt(results[y], 1);
				SQL_FetchString(results[y], 2, settingsAttrib, sizeof(settingsAttrib));
				tempInts[1] = SQL_FetchInt(results[y], 3);
				tempInts[2] = SQL_FetchInt(results[y], 4);
				tempInts[3] = SQL_FetchInt(results[y], 5);
				SetSaveSettings(client, tempInts[0], tempInts[1], settingsAttrib, tempInts[2], tempInts[3]);
			}
		}
	}
}

[notMe2]

Thanks guys! both Mitchell and Kryptanyte solutions worked for me