[Alucard^]

hi guys, here i trying to add a hud msg speed player in a plugin that i modificated.. the speed is showing, yes.. but.. i think this is not the best way to show the speed.. oh, and.. i want to show the speed without decimals.. any can give me the best way to do this?

see the code:

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>


#define PLUGIN_NAME    "HP Hud Display"
#define PLUGIN_VERSION    "1.0"
#define PLUGIN_AUTHOR    "Alucard"

//credits: Exolent, Emp`

new HUDSYNC;
new hp_color;
new hp_custom;
new hp_effects;


public plugin_init()
{
    register_plugin(PLUGIN_NAME, PLUGIN_VERSION, PLUGIN_AUTHOR);
    
    set_task(1.0,"timer_task",_,"",0,"b");
    HUDSYNC = CreateHudSyncObj();

    hp_color = register_cvar("hp_color", "1", 0, 0.0);
    hp_custom = register_cvar("hp_custom", "255 255 0", 0, 0.0);
    hp_effects = register_cvar("hp_effects", "1", 0, 0.0);

    return PLUGIN_CONTINUE;
}

public timer_task() {

    new hud_red, hud_green, hud_blue;
    switch( get_pcvar_num(hp_color) )
    {
        case 0:
        {
            hud_red = 255;
            hud_green = 255;
            hud_blue = 255;
        }
        case 1:
        {
            new color[16], red[4], green[4], blue[4];
            get_pcvar_string(hp_custom, color, 15);
            parse(color, red, 3, green, 3, blue, 3);
            
            hud_red = str_to_num(red);
            hud_green = str_to_num(green);
            hud_blue = str_to_num(blue);
        }
        case 2:
        {
            hud_red = random(256);
            hud_green = random(256);
            hud_blue = random(256);
        }
    }

    static scoreboard[128];
    for(new i=1;i<=32;i++) {
              
        if(is_user_connected(i) && is_user_alive(i) ) {
                new speedstr[32] = ""

                new Float:speed[3]

                pev(i, pev_velocity, speed);
        
                float_to_str ( 
                floatsqroot(floatadd(floatpower(speed[0], 2.0), floatpower(speed[1], 2.0)))
                , speedstr, 5);

                format(speedstr, 31, speedstr);

                formatex(scoreboard, 127, "HP: %i | AP: %i | SPEED: %s", get_user_health(i), get_user_armor(i), speedstr );
                set_hudmessage(hud_red, hud_green, hud_blue, 0.03, 0.94, get_pcvar_num(hp_effects), 0.0, 2.0, 0.0, 0.2, 2);
                ShowSyncHudMsg( i, HUDSYNC, scoreboard );
                }
      }
} 


thx, and sry for my english

[Sn!ff3r]

Use client prethink ?

[ConnorMcLeod]

Set the task to 0.1

http://forums.alliedmods.net/showpos...9&postcount=28

[Alucard^]

@Sn!ff3r

thx but u can give me an example? cuz i am new in scripting.. or is there a tutorial or something about "prethink"?

@connorr

thx connor, i never think that i need a lot of code to do this o.o..

and mm, i am confused, how can i implement this in my plugin? i only need the current speed

[Sn!ff3r]

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Your speed"
#define VERSION "1.0"
#define AUTHOR "Sn!ff3r"

new g_sync

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    register_forward(FM_PlayerPreThink,"prethink")
    g_sync = CreateHudSyncObj()
}

public prethink(id)
{
    if(!is_user_alive(id))
        return FMRES_IGNORED    
    
    static Float:velocity[3], Float:speed
    
    pev(id, pev_velocity, velocity)
    
    speed = vector_length(velocity)
    
    set_hudmessage(255, 255, 255, -1.0, 0.9, 0, 6.0, -1.0)
    ShowSyncHudMsg(id,g_sync,"Your current speed: %3.0f",speed)
    
    return FMRES_IGNORED
} 


[Alucard^]

thx sniffer

oh and why?:

%3.0f

[Sn!ff3r]

http://forums.alliedmods.net/showpos...57&postcount=8

[MeRcyLeZZ]

I would personally suggest not to send it more often than needed.

PreThink could be called like 100 times a second for some players (maybe more), causing lag (choke) on a slow connection and/or the server to drop clients with the "reliable channel overflowed" error.

[ConnorMcLeod]

Setting hudmessage during startframe was causing lot of choke, i don't know if it's the same with prethink.
MeRcyLeZZ is right, a 0.1 task should be enough (or filter by 0.1s in prethink)