[ShadowRanger]

I'm having an issue with the OnWeaponUse event which I'm trying to use to prevent weapons from being picked up but also not removing the player's current weapon which happens if I don't add the GivePlayerItem at the end and also removing the weapon that gets dropped. The issue is that whenever I try and pick up a weapon, a few seconds after the client/server crashes. I'm not sure what I'm doing wrong.

public Action OnWeaponCanUse(int client, int weapon)
{
	// Exit if a fun round is not in progress
	if (!g_startedFunRound) return Plugin_Continue;

	// Run some other checks
	if (!IsClientInGame(client)) return Plugin_Continue;
	if (!IsPlayerAlive(client)) return Plugin_Stop;

	// Prevent the weapon from being picked up
	if (IsValidEntity(weapon))
	{
		AcceptEntityInput(weapon, "Kill");
	}

	if (!StrEqual(g_curRoundWeapon, "weapon_knife"))
	{
		GivePlayerItem(client, g_curRoundWeapon);
	}

	return Plugin_Handled;
}

[headline]

PHP Code:

public Action OnWeaponCanUse(int client, int weapon)
{
    if (!g_startedFunRound) return Plugin_Continue;

    if (!IsClientInGame(client)) return Plugin_Continue;
    if (!IsPlayerAlive(client)) return Plugin_Stop; // this should return Plugin_Continue

    if (IsValidEntity(weapon)) // This will happen any time the player's weapon is a valid weapon, is this intended behavior???
    {
        AcceptEntityInput(weapon, "Kill"); // If you don't want them to pick the item up, return Plugin_Handled
    }


    if (!StrEqual(g_curRoundWeapon, "weapon_knife")) // Any time this OnCanUse is called you want to give them a weapon? Why here
    {
        GivePlayerItem(client, g_curRoundWeapon);
    }

    return Plugin_Handled; // Why Plugin_Handled here??
} 


I'm not quite sure you understand the differences between Plugin_Handled, Plugin_Continue, and Plugin_Stop. Here you go.

By the way, Plugin_Stop is only used in timer callbacks

[ShadowRanger]

Originally Posted by Headline PHP Code: public Action OnWeaponCanUse(int client, int weapon) {     if (!g_startedFunRound) return Plugin_Continue;     if (!IsClientInGame(client)) return Plugin_Continue;     if (!IsPlayerAlive(client)) return Plugin_Stop; // this should return Plugin_Continue     if (IsValidEntity(weapon)) // This will happen any time the player's weapon is a valid weapon, is this intended behavior???     {         AcceptEntityInput(weapon, "Kill"); // If you don't want them to pick the item up, return Plugin_Handled     }     if (!StrEqual(g_curRoundWeapon, "weapon_knife")) // Any time this OnCanUse is called you want to give them a weapon? Why here     {         GivePlayerItem(client, g_curRoundWeapon);     }     return Plugin_Handled; // Why Plugin_Handled here?? }  I'm not quite sure you understand the differences between Plugin_Handled, Plugin_Continue, and Plugin_Stop. Here you go. By the way, Plugin_Stop is only used in timer callbacks

If I just return Plugin_Handled, and don't do any of the other things such as removing the dropped weapon and giving them a new weapon, whenever they walk over a weapon it creates one over it and drops it and then removes the current weapon from the player. I've got no idea why. I just want it to prevent them from picking it up and leaving them with their current weapon as well as removing the one that's created when they can't pick it up.

[ShadowRanger]

Bump

[MasterMind420]

best way i know how is to use onentitycreated and hook all the entities you'd like to prevent picking up with sdkhook onplayeruse, return plugin_handled in there. if u cant figure it out, let me know and i'll give u an example on how to do it.

[Bacardi]

logic logic

PHP Code:

public Action OnWeaponCanUse(int client, int weapon)
{
    // Exit if a fun round is not in progress
    if (!g_startedFunRound) return Plugin_Continue;

    // Run some other checks
    if (!IsClientInGame(client)) return Plugin_Continue;
    if (!IsPlayerAlive(client)) return Plugin_Continue;



    char Classname[30];
    GetEntityClassname(weapon, Classname, sizeof(Classname));

    if(StrContains(Classname, "knife", false) != -1) return Plugin_Continue; // allow knifes always

    if (StrEqual(g_curRoundWeapon, Classname, false))  return Plugin_Continue; // allow roundweapon


    // Prevent the weapon from being picked up
    if (IsValidEntity(weapon))
    {
        AcceptEntityInput(weapon, "Kill");
    }

    return Plugin_Handled;
} 


[MasterMind420]

Why remove the weapon completely?
Here's the proper way to do it...

char gClassname[64];

public void OnPluginStart()
{
	//This allows you to rehook all entities midgame, if u reload the plugin...
	for (int i = MAXPLAYERS; i <= 2048; i++)
	{
		if (IsValidEntity(i))
			OnEntityCreated(i, gClassname);
	}
}

public void OnEntityCreated(int entity, const char[] classname)
{
	if(!IsValidEntity(entity))
		return;

	char Classname[32];
	GetEntityClassname(entity, Classname, sizeof(Classname));

        if (!g_startedFunRound || StrEqual(Classname, g_curRoundWeapon))
                //false isn't necessary in the StrEqual because it defaults to false
                return;

	if (StrContains(Classname, "knife") > -1)
                return;

        //this will hook every item on the server that's created, except the knife & roundweapon
        //Anything u want to pickup will need to be return'd above
	SDKHook(entity, SDKHook_Use, OnPlayerUse);
}

public Action OnPlayerUse(int entity, int activator, int caller, UseType type, float value)
{
	return Plugin_Handled; //This prevents you from picking up the hooked entity
}

Doing it this way you should have no issues, good luck...

[Mitchell]

//this will hook every item on the server that's created, except the knife & roundweapon //Anything u want to pickup will need to be return'd above

I see you like to live dangerously.. Even if you checked to see if the entity had "weapon_" at the beginning I would advise against hooking ever weapon entity like this. Do what Barcadi said, just hook the player's OnWeaponCanUse and just ignore the pickup. Obviously removing the weapon can be stripped out of the code.

[MasterMind420]

Originally Posted by Mitchell I see you like to live dangerously.. Even if you checked to see if the entity had "weapon_" at the beginning I would advise against hooking ever weapon entity like this. Do what Barcadi said, just hook the player's OnWeaponCanUse and just ignore the pickup. Obviously removing the weapon can be stripped out of the code.

I love living dangerously lol...but besides that i still fail to see how hooking every entity would be an issue if he properly implements blocking items/weapons he wants to pickup from being hooked. I've experimented with every method of blocking weapon pickup in L4D2...This method works flawlessly if implemented correctly...However, depending on what game he's doing this for there may be unforeseen issues that i'm unaware of but in L4D2 it works better than using any of the OnWeaponCanUse hooks trying to block weapon pickup...i've experienced issues with trying to block weapon pickup that way. OnWeaponCanUse also effects the weapons u are already carrying, preventing u from using them if you have blocked them this way. Which for him would be a none issue. He could also use OnPlayerRunCmd to block weapon pickup blocking IN_USE for specific weapons.

[ShadowRanger]

I appreciate all of your help. I tried Bacardi's method and it does work for the most part but for some reason whenever a player walks over the weapon, the gun they have equipped at the time bugs out and the hands disappear from first person and after you switch to the knife it completely removes the gun. This is the reason why I originally had the GivePlayerItem in, as a workaround for this issue. But surely I don't have to do this.

Also, how come you suggested removing the part that removes the weapon Mitchell? The only reason that's in is because I don't want a weapon to be dropped every time a player walks over one which happens without it.

I'll give MasterMind420's method a go today if I can't get the original way of doing it working. Not sure why it's proving so difficult to achieve for me.