[dirka_dirka]

the code i posted is similar to something used in multiple plugins.. the do { } while loop is the primary difference. the other plugin i can think of off hand is witch crown stats - that plugin, as mentioned above, tracks the number of entries and uses a for loop to get all the info.

if its not printing anything, then perhaps its not reading in the file. where exactly is the file stored? you dont have a path..

how about you replace the FileToKeyValues(hKV, "sm_tlist.ini"); line with..

PHP Code:

decl String:sBannedDB[PLATFORM_MAX_PATH];
BuildPath(Path_SM, sBannedDB, PLATFORM_MAX_PATH, "configs/sm_tlist.ini");
FileToKeyValues(hKV, sBannedDB); 


and make sure the sm_tlist.ini is in sourcemod/configs

[Steell]

Code:

PHP Code:

#pragma semicolon 1
#include <sourcemod>
 
public OnPluginStart()
{
    RegConsoleCmd("tester", Tester);
}
 
public Action:Tester(client,args)
{
    decl String:szAuth[32];
    decl String:szReason[64];
    new Handle:hKV = CreateKeyValues("Tlist");
    FileToKeyValues(hKV, "sm_tlist.ini");
    if (KvGotoFirstSubKey(hKV))
    {
        if (KvGotoFirstSubKey(hKV))
        {
            do
            {
                KvGetSectionName(hKV, szAuth, sizeof(szAuth));
                KvGetString(hKV, "reason", szReason, sizeof(szReason));
                PrintToChatAll("STEAM: %s REASON: %s", szAuth, szReason);
            } while (KvGotoNextKey(hKV));
        }
    } 
    CloseHandle(hKV);
} 


INI

"Tlist"
{
    "Banned"
    {
        "STEAM_0:0:1234"
        {
            "reason"         "free killing"
        }
        "STEAM_0:0:4321"
        {
            "reason"         "gun planting"
        }
    }
}

Your ini should be in the server's root directory. If it's somewhere else, see dirka's post above mine.

[Greyscale]

That do/while loop is unnecessary. There is only 1 key, and if there are multiple then you are just getting the value of "reason" multiple times.

KvGetSectionName(hKV, szAuth, sizeof(szAuth));
KvGetString(hKV, "reason", szReason, sizeof(szReason));
KvGetString(hKV, "nextkey", string, sizeof(string));
KvGetString(hKV, "nextkey2", string2, sizeof(string2));
// etc
PrintToChatAll("STEAM: %s REASON: %s", szAuth, szReason);

Not to mention that's only looking in the first steam id.
Use KvJumpToKey to jump to the steam id you want.

[Steell]

Well this is what my code outputs:

L 08/03/2010 - 17:33:15: [tester.smx] STEAM: STEAM_0:0:1234 REASON: free killing
L 08/03/2010 - 17:33:15: [tester.smx] STEAM: STEAM_0:0:4321 REASON: gun planting

(I changed PrintToChatAll to LogMessage so I can read it from the console).

I interpreted it as he wanted to iterate through the KV file and then print the steam id and reason for each section under "Banned".

Here's the same code with some documentation:

PHP Code:

#pragma semicolon 1
#include <sourcemod>
 
public OnPluginStart()
{
    RegConsoleCmd("tester", Tester);
}
 
public Action:Tester(client,args)
{
    //buffers
    decl String:szAuth[32];
    decl String:szReason[64];
    new Handle:hKV = CreateKeyValues("Tlist");
    FileToKeyValues(hKV, "sm_tlist.ini");
    if (KvGotoFirstSubKey(hKV)) //Take us inside "Banning" section
    {
        if (KvGotoFirstSubKey(hKV)) //Take us inside the first SteamID.
        {
            do
            {
                KvGetSectionName(hKV, szAuth, sizeof(szAuth)); //Get the SteamID
                KvGetString(hKV, "reason", szReason, sizeof(szReason)); //Get the reason for banning.
                PrintToChatAll("STEAM: %s REASON: %s", szAuth, szReason); //Print the message
            } while (KvGotoNextKey(hKV)); //Goto the next SteamID
        }
    } 
    CloseHandle(hKV);
} 


[bestmeth0ds]

Wow guys. Thank your so much for all your help. I will look over this and see what I get. You guys have been a really big help. I had no idea I was getting into something so complicated.

[bestmeth0ds]

I tried and nothing appeared in chat??? Did your method only work with log message?

Edit: Nvm I had to use Drika's code to build the filepath. Which is wierd because I never had to before.

[bestmeth0ds]

Ok now what I would like to do is either on plugin start or on client connect check if a user is on the ban list and and if they connect it shows to them the reason they are banned in chat. So would I want to make some kind of boolean and apply it to the users in sm_tlsit.ini? And I am trying to makeit so you can type sm_tlsit and it writes to sm_tlist.ini .... Also how do I donate?

Edit: Nvm found donate button on front page.... = )

[Monkeys]

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdktools>
static String:sBannedDB[PLATFORM_MAX_PATH];
 
public OnPluginStart()
{
    BuildPath(Path_SM, sBannedDB, PLATFORM_MAX_PATH, "configs/sm_tlist.ini"); //Build the path and store it in the global variable sBannedDB
    RegConsoleCmd("sm_tlist",Command_tlist);
}

public OnClientPutInServer(Client)
{
    decl String:Auth[64];
    GetClientAuthString(Client,Auth,sizeof(Auth));
    ShowBanReasonOfID(Client,Auth);
}

public bool:ShowBanReasonOfID(Client,const String:Auth[])
{
    new bool:Match = false;
    decl String:szAuth[32];
    decl String:szReason[64];
    new Handle:hKV = CreateKeyValues("Tlist");
    FileToKeyValues(hKV, sBannedDB);
    if (KvGotoFirstSubKey(hKV)) //Take us inside "Banning" section
    {
        if (KvGotoFirstSubKey(hKV)) //Take us inside the first SteamID.
        {
            do
            {
                KvGetSectionName(hKV, szAuth, sizeof(szAuth)); //Get the SteamID
                if(StrContains(Auth,szAuth,false) != -1)
                {
                    KvGetString(hKV, "reason", szReason, sizeof(szReason)); //Get the reason for banning.
                    PrintToChatAll("STEAM: %s REASON: %s", szAuth, szReason); //Print the message
                    Match = true;
                }
            } while (KvGotoNextKey(hKV)); //Goto the next SteamID
        }
    } 
    CloseHandle(hKV);
    return Match;
} 

public Action:Command_tlist(Client,Args)
{
    if( Args < 2)
    {
        ReplyToCommand(Client,"Syntax: sm_tlist <steamid> \"<reason>\"");
    }
    decl String:SteamId[68];
    GetCmdArg(1,SteamId,sizeof(SteamId));
    
    new Handle:Regex = CompileRegex("STEAM_[0-9]:[0-9]:[0-9]{4,}");
    if(MatchRegex(Regex,SteamId) != -1)
    {
        decl String:Reason[255];
        GetCmdArg(2,Reason,sizeof(Reason));
        
        new Handle:hKV = CreateKeyValues("Tlist");
        FileToKeyValues(hKV, sBannedDB);
        
        KvJumpToKey(hKV,"Banned",false);
        KvJumpToKey(hKV,SteamId,true);
        KvSetString(hKV,"reason",Reason);
        
        KvRewind(hKV);
        KeyValuesToFile(hKV,sBannedDB);
        CloseHandle(hKV);
    }else{
        ReplyToCommand(Client,"SteamId doesn't match normal SteamId format");
    }
} 


Haven't compiled yet, so I probably forgot some things/made typos.

I haven't autokicked after ShowBanReason yet, I leave that up to you

[Greyscale]

Sorry I guess I read it too quick. I thought your code went a level deeper than it does.

[bestmeth0ds]

Its spitting errors at me around the lines 55 and 56.

Undefined symbol "compileregex"

undefined symbol "matchregex"

symbol is assigned a value that is never used "regex"