[Any] "[SM]" Prefix changer! UPDATE: March 22, 2013 - Page 4

Mitchell · 03-22-2013 , 22:43 Re: [Any] "[SM]" Prefix changer! UPDATE: June 16, 2012

Quote:

Originally Posted by abrandnewday

Ok, so I looked into this. Here's the timer_strip function:

PHP Code:


			
public Action:timer_strip(Handle:timer, Handle:pack)
{
    new playersNum = ReadPackCell(pack);
    new players[playersNum];

    for(new i = 0; i < playersNum; i++)
    {
        players[i] = ReadPackCell(pack);
    }
    new String:buffer[255];
    ReadPackString(pack, buffer, sizeof(buffer));
    new String:QuickFormat[255];
    new ColorChoose = 0;
    if(UseRandomColors == 1) ColorChoose = GetRandomInt(0, CountColors);
    Format(QuickFormat, sizeof(QuickFormat), "%s", TextColors[ColorChoose]);
    ReplaceStringEx(buffer, sizeof(buffer), "[SM]", QuickFormat);
    
    new Handle:bf = StartMessage("SayText2", players, playersNum, USERMSG_RELIABLE|USERMSG_BLOCKHOOKS);
    //BfWriteString(bf, buffer);
    BfWriteByte(bf, -1);
    BfWriteByte(bf, true);
    BfWriteString(bf, buffer);
    EndMessage();
}

The line in question that is causing the error is this one:

PHP Code:


			
new Handle:bf = StartMessage("SayText2", players, playersNum, USERMSG_RELIABLE|USERMSG_BLOCKHOOKS);

With that being said, I tried my hand at fixing this. Try the version I've attached, let me know if there's any more errors.

Here's how I attempted to fix this:

PHP Code:


			
public Action:timer_strip(Handle:timer, Handle:pack)
{
    new playersNum = ReadPackCell(pack);
    new players[playersNum];

    for(new i = 0; i < playersNum; i++)
    {
        players[i] = ReadPackCell(pack);
    }
    new String:buffer[255];
    ReadPackString(pack, buffer, sizeof(buffer));
    new String:QuickFormat[255];
    new ColorChoose = 0;
    if(UseRandomColors == 1) ColorChoose = GetRandomInt(0, CountColors);
    Format(QuickFormat, sizeof(QuickFormat), "%s", TextColors[ColorChoose]);
    ReplaceStringEx(buffer, sizeof(buffer), "[SM]", QuickFormat);
    
    // Here's the new check
    for(new i = 0; i < playersNum; i++)
    {
        if(IsClientInGame(i))
        {
            new Handle:bf = StartMessage("SayText2", players, playersNum, USERMSG_RELIABLE|USERMSG_BLOCKHOOKS);
            //BfWriteString(bf, buffer);
            BfWriteByte(bf, -1);
            BfWriteByte(bf, true);
            BfWriteString(bf, buffer);
            EndMessage();
        }
    }
}

That wont fix anything, that will actually do it worse, like print the message as many as how many people are connected.

404UserNotFound · *Last edited by 404UserNotFound; 03-22-2013 at 23:03.*

Quote:

Originally Posted by Mitchell

That wont fix anything, that will actually do it worse, like print the message as many as how many people are connected.

Lol, oh boy. Nobody use the version I posted!

EDIT: I see you added a "fixed" version. There's just one problem. It won't compile.

Here's what's tripping out:

PHP Code:


			
public Action:timer_strip(Handle:timer, Handle:pack)
{
    new playersNum = ReadPackCell(pack);
    new players[playersNum];

    for(new i = 0; i < playersNum; i++)
    {
        players[i] = ReadPackCell(pack);
        if(!( 1 <= client <= MaxClients ) || !IsClientInGame(players[i]))
        {
            i--;
            playersNum--;
        }
    }
    new String:buffer[255];
    ReadPackString(pack, buffer, sizeof(buffer));
    new String:QuickFormat[255];
    new ColorChoose = 0;
    if(UseRandomColors == 1) ColorChoose = GetRandomInt(0, CountColors);
    Format(QuickFormat, sizeof(QuickFormat), "%s", TextColors[ColorChoose]);
    ReplaceStringEx(buffer, sizeof(buffer), "[SM]", QuickFormat);
    
    new Handle:bf = StartMessage("SayText2", players, playersNum, USERMSG_RELIABLE|USERMSG_BLOCKHOOKS);
    //BfWriteString(bf, buffer);
    BfWriteByte(bf, -1);
    BfWriteByte(bf, true);
    BfWriteString(bf, buffer);
    EndMessage();
}

Specifically:

PHP Code:


			
if(!( 1 <= client <= MaxClients ) || !IsClientInGame(players[i]))

Error in question is "undefined symbol: client"

Bacardi · 03-23-2013 , 04:57 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

Spoiler

island55 · 03-23-2013 , 13:04 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

it doesn't compile anymore on the original post

Bacardi · 03-23-2013 , 14:14 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

Quote:

Originally Posted by island55

it doesn't compile anymore on the original post

use web compiler

http://www.sourcemod.net/compiler.php

Code:

#include <sourcemod>
#pragma semicolon 1

#define MAXTEXTCOLORS 100

// Plugin definitions
#define PLUGIN_VERSION "0.31000001"

public Plugin:myinfo =
{
	name = "Default SM Text Replacer",
	author = "Mitch/Bacardi",
	description = "Replaces the '[SM]' text with more color!",
	version = PLUGIN_VERSION,
	url = ""
};
//static list_colors[6][] = { "FF9999", "99FF99", "9999FF", "FFFF99", "99FFFF", "FF99FF" };
new Handle:cvar_randomcolor = INVALID_HANDLE;
new UseRandomColors = 0;
new CountColors = 0;

new String:TextColors[MAXTEXTCOLORS][256];

public OnPluginStart()
{
	cvar_randomcolor	=	CreateConVar( "sm_textcol_random", "1", "Uses random colors that you defined. 1- random 0-Default" );
	AutoExecConfig(true, "sm_textreplacer");
	HookConVarChange(cvar_randomcolor, Event_CvarChange);
	CreateConVar("sm_textreplacer_version", PLUGIN_VERSION, "text replacer version", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY);
	RegAdminCmd("sm_reloadstc", Command_ReloadConfig, ADMFLAG_CONFIG, "Reloads Text color's config file");
	HookUserMessage(GetUserMessageId("TextMsg"), TextMsg, true);
}
public Action:Command_ReloadConfig(client, args) {
	
	RefreshConfig();
	LogAction(client, -1, "Reloaded [SM] Text replacer config file");
	ReplyToCommand(client, "[STC] Reloaded config file.");
	return Plugin_Handled;
}
public OnConfigsExecuted()
{
	RefreshConfig();
}

public Event_CvarChange(Handle:convar, const String:oldValue[], const String:newValue[])
{
	RefreshConfig();
}

stock RefreshConfig()
{
	UseRandomColors = GetConVarInt(cvar_randomcolor);
	for (new X = 0; X < MAXTEXTCOLORS; X++)
	{
		//Format(TextColors[X], sizeof(TextColors), "");
		TextColors[X] = "";
	}
	decl String:sPaths[PLATFORM_MAX_PATH];
	BuildPath(Path_SM, sPaths, sizeof(sPaths),"configs/sm_textcolors.cfg");
	new Handle:hFile = OpenFile(sPaths, "r");
	new String:sBuffer[256]; 
	//new len;
	CountColors = -1;
	while (ReadFileLine(hFile, sBuffer, sizeof(sBuffer)))
	{
		/*len = strlen(sBuffer);
		if (sBuffer[len-1] == '\n')
			sBuffer[--len] = '\0';*/

		TrimString(sBuffer);

		if(!StrEqual(sBuffer,"",false)){
			
			ReplaceString(sBuffer, sizeof(sBuffer), "*", "\x08");
			ReplaceString(sBuffer, sizeof(sBuffer), "&", "\x07");
			CountColors++;
			Format(TextColors[CountColors], sizeof(TextColors), "%s", sBuffer);
			PrintToChatAll("\x01%s", sBuffer);
		}
	}
	CloseHandle(hFile);
}
public Action:TextMsg(UserMsg:msg_id, Handle:bf, const players[], playersNum, bool:reliable, bool:init)
{
	if(CountColors != -1)
	{
		if(reliable)
		{
			new String:buffer[256];
			BfReadString(bf, buffer, sizeof(buffer));
			if(StrContains(buffer, "\x03[SM]") == 0)
			{
				new Handle:pack;
				CreateDataTimer(0.0, timer_strip, pack);

				WritePackCell(pack, playersNum);
				for(new i = 0; i < playersNum; i++)
				{
					WritePackCell(pack, players[i]);
				}
				WritePackString(pack, buffer);
				ResetPack(pack);
				return Plugin_Handled;
			}
		}
	}
	return Plugin_Continue;
}

public Action:timer_strip(Handle:timer, Handle:pack)
{
	new playersNum = ReadPackCell(pack);
	new players[playersNum];
	new client, count;

	for(new i = 0; i < playersNum; i++)
	{
		client = ReadPackCell(pack);
		if(IsClientInGame(client))
		{
			players[count++] = client;
		}
	}

	if(count < 1) return;
	
	playersNum = count;
	
	new String:buffer[255];
	ReadPackString(pack, buffer, sizeof(buffer));
	new String:QuickFormat[255];
	new ColorChoose = 0;
	if(UseRandomColors == 1) ColorChoose = GetRandomInt(0, CountColors);
	Format(QuickFormat, sizeof(QuickFormat), "%s", TextColors[ColorChoose]);
	ReplaceStringEx(buffer, sizeof(buffer), "[SM]", QuickFormat);
	
	new Handle:bf = StartMessage("SayText2", players, playersNum, USERMSG_RELIABLE|USERMSG_BLOCKHOOKS);
	//BfWriteString(bf, buffer);
	BfWriteByte(bf, -1);
	BfWriteByte(bf, true);
	BfWriteString(bf, buffer);
	EndMessage();
}

maxolahird · 12-12-2013 , 13:19 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

How to make {default} tag in hex? or can i use \x01?

MafiaBoss · 12-13-2013 , 04:38 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

Can someone tell me the config for white text?

maxolahird · 12-13-2013 , 14:30 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

Quote:

Originally Posted by MafiaBoss

Can someone tell me the config for white text?

That's pretty easy.... &FFFFFF

MafiaBoss · *Last edited by MafiaBoss; 12-13-2013 at 20:19.*

Quote:

Originally Posted by maxolahird

That's pretty easy.... &FFFFFF

Well, I don't know hex.... So yea... Thx. What do I type into the config? Just &FFFFFF or *AAAAAAAA[*FFFFFFAASM*AAAAAAAA]&FFFFFF ?

EDIT : Can I have the hex for black instead? Thx!

Dr. McKay · 12-14-2013 , 14:02 Re: [Any] "[SM]" Prefix changer! UPDATE: March 22, 2013

Black is 000000