[wrecked_]

Red,

new tempid = -1

while( ( tempid = find_ent_in_sphere( tempid, origin, 200.0 ) ) )
{
    // ...
}

[RedRobster]

<3

[TheKidz]

didnt worked :T
im kinda tired.. so, its possible ? :c
i will tell exacly what i had i mind:
all players got radius, if X players in the same radius then they will get 10 seconds to spare or they gonna be slaped. the number max of players in radius depends of max players in server. Possible or not ? if its possible i wish u guys tell me what i have to do, i mean helping me T_T

[TheKidz]

bump

[Exolent[jNr]]

I didn't write the whole thing for you, but this should give you a step forward:

#include < amxmodx >
#include < fakemeta >

CheckRadius( Float:flRadius, iMaxInRadius, iSlapPower = 0 )
{
    new iPlayers[ 32 ], iNum;
    get_players( iPlayers, iNum, "a" );
    
    new Float:vecPlayerOrigins[ 32 ][ 3 ];
    new bool:bSlapped[ 33 ];
    
    for( new i = 0; i < iNum; i++ )
    {
        pev( iPlayers[ i ], pev_origin, vecPlayerOrigins[ i ] );
    }
    
    new iPlayersInRadius[ 32 ], iRadiusNum;
    
    new iPlayer;
    
    for( new i = 0, j; i < iNum; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        iPlayersInRadius[ 0 ] = iPlayer;
        iRadiusNum = 1;
        
        for( j = 0; j < iNum; j++ )
        {
            if( j != i )
            {
                if( get_distance_f( vecPlayerOrigins[ i ], vecPlayerOrigins[ j ] ) <= flRadius )
                {
                    iPlayersInRadius[ iRadiusNum++ ] = iPlayers[ j ];
                }
            }
        }
        
        if( iRadiusNum >= iMaxInRadius )
        {
            for( j = 0; j < iRadiusNum; j++ )
            {
                iPlayer = iPlayersInRadius[ j ];
                
                if( !bSlapped[ iPlayer ] )
                {
                    user_slap( iPlayer, iSlapPower );
                    
                    bSlapped[ iPlayer ] = true;
                }
            }
        }
    }
}

[TheKidz]

thats exacly what i had i mind, thank you exolent ! thats why ppl luv you ;D