[Alka]

Originally Posted by Hunter-Digital Well it seems I can't create spawn points O.o I searched for all codes I could search, nothing worked, they all spawn me at 0 0 0 even tough the entity's position is where it should be...

Spawn points can be created...

[xPaw]

Works fine. feel free to use.

PHP Code:

#include <amxmodx>
#include <engine>
#include <hamsandwich>

public plugin_precache( ) {
    register_plugin( "Swap Spawns", "1.0", "xPaw" );
    
    RegisterHam( Ham_Spawn, "info_player_start", "FwdHamSpawn_CT", 1 );
    RegisterHam( Ham_Spawn, "info_player_deathmatch", "FwdHamSpawn_T", 1 );
    RegisterHam( Ham_Spawn, "func_buyzone", "FwdHamSpawn_BuyZone", 1 );
}

public FwdHamSpawn_BuyZone( iEntity ) {
    switch( entity_get_int( iEntity, EV_INT_team ) ) {
        case 1: entity_set_int( iEntity, EV_INT_team, 2 );
        case 2: entity_set_int( iEntity, EV_INT_team, 1 );
    }
}

public FwdHamSpawn_CT( iEntity ) {
    new szClass[ 32 ];
    entity_get_string( iEntity, EV_SZ_classname, szClass, 16 );
    
    if( szClass[ 5 ] != 'p' || szClass[ 12 ] != 's' )
        return HAM_IGNORED;
    
    if( entity_get_int( iEntity, EV_INT_iuser4 ) == 9999 )
        return HAM_IGNORED;
    
    CreateSpawn( iEntity, 1 );
    
    return HAM_IGNORED;
}

public FwdHamSpawn_T( iEntity ) {
    new szClass[ 32 ];
    entity_get_string( iEntity, EV_SZ_classname, szClass, 16 );
    
    if( szClass[ 5 ] != 'p' || szClass[ 12 ] != 'd' )
        return HAM_IGNORED;
    
    if( entity_get_int( iEntity, EV_INT_iuser4 ) == 9999 )
        return HAM_IGNORED;
    
    CreateSpawn( iEntity, 0 );
    
    return HAM_IGNORED;
}

CreateSpawn( iEntity, iNewTeam = 0 ) {
    new Float:vAngles[ 3 ], Float:vOrigin[ 3 ];
    entity_get_vector( iEntity, EV_VEC_origin, vOrigin );
    entity_get_vector( iEntity, EV_VEC_angles, vAngles );
    
    entity_set_int( iEntity, EV_INT_flags, FL_KILLME );
    call_think( iEntity );
    
    switch( iNewTeam ) {
        case 0: iEntity = create_entity( "info_player_start" );
        case 1: iEntity = create_entity( "info_player_deathmatch" );
    }
    
    if( !is_valid_ent( iEntity ) )
        return 0;
    
    entity_set_vector( iEntity, EV_VEC_origin, vOrigin );
    entity_set_vector( iEntity, EV_VEC_angles, vAngles );
    entity_set_int( iEntity, EV_INT_iuser4, 9999 );
    
    return iEntity;
} 


[tuty]

nice one digi

[Hunter-Digital]

Yes well, I see that you can only create spawns in precache, thanks for the code xPaw but I want to make it per-map not globally
One question, why do you use FL_KILLME and call_think() when you can simply remove it ? Works the same from what I can see...

[ConnorMcLeod]

I mean, instead of remove those ents, just alter their classname, like info_blabla -> _info_blabla, save state in a globale cvar, when when you switch back the state to normal, alter each _info_blabla into info_blabla, restart round and it should be fine.

[Hunter-Digital]

Well I tried that, doesn't seem to work
Anyway, that's something a map should handle if it doesn't have equal spawns :} wouldn't be fair anyway

small update: checks if there are both player start and deathmatch in the map to switch... because if you'd use this in a kz map it would delete all spawns =)

[ot_207]

Good job man! Nice to see originality! ;)

[stupok]

This works, no creating/deleting spawns:

PHP Code:

/* Script generated by Pawn Studio */

#include <amxmodx>
#include <amxmisc>
#include <engine>

#define PLUGIN    "Swap Spawns"
#define AUTHOR    "stupok"
#define VERSION    "1.0"

#define MAX_SPAWNS    32

new g_iSwapped

new g_iSpawnCount_T
new g_iSpawnIndexes_T[MAX_SPAWNS]
new g_iSpawnDisabled_T[MAX_SPAWNS]
new Float:g_flSpawnOrigins_T[MAX_SPAWNS][3]
new Float:g_flSpawnAngles_T[MAX_SPAWNS][3]

new g_iSpawnCount_CT
new g_iSpawnIndexes_CT[MAX_SPAWNS]
new g_iSpawnDisabled_CT[MAX_SPAWNS]
new Float:g_flSpawnOrigins_CT[MAX_SPAWNS][3]
new Float:g_flSpawnAngles_CT[MAX_SPAWNS][3]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    register_concmd( "swapspawns", "SwapSpawns", ADMIN_BAN, "Swaps spawns" )
    
    FindSpawns()
}

public FindSpawns()
{
    new iEnt = -1
    
    while( ( iEnt = find_ent_by_class( iEnt, "info_player_deathmatch" ) ) )
    {
        g_iSpawnIndexes_T[g_iSpawnCount_T] = iEnt
        entity_get_vector( iEnt, EV_VEC_origin, g_flSpawnOrigins_T[g_iSpawnCount_T] )
        entity_get_vector( iEnt, EV_VEC_angles, g_flSpawnAngles_T[g_iSpawnCount_T] )
        
        if( ++g_iSpawnCount_T == MAX_SPAWNS )
            break
    }
    
    iEnt = -1
    
    while( ( iEnt = find_ent_by_class( iEnt, "info_player_start" ) ) )
    {
        g_iSpawnIndexes_CT[g_iSpawnCount_CT] = iEnt
        entity_get_vector( iEnt, EV_VEC_origin, g_flSpawnOrigins_CT[g_iSpawnCount_CT] )
        entity_get_vector( iEnt, EV_VEC_angles, g_flSpawnAngles_CT[g_iSpawnCount_CT] )
        
        if( ++g_iSpawnCount_CT == MAX_SPAWNS )
            break
    }
}

public SwapSpawns( id, level, cid )
{
    if( !cmd_access( id, level, cid, 1 ) )
        return PLUGIN_HANDLED
    
    if( !g_iSwapped )
    {
        // disable extra t spawns
        if( g_iSpawnCount_CT < g_iSpawnCount_T )
        {
            for( new i = g_iSpawnCount_CT; i < g_iSpawnCount_T; i++ )
            {
                g_iSpawnDisabled_T[i] = 1
                entity_set_string( g_iSpawnIndexes_T[i], EV_SZ_classname, "_info_player_deathmatch" )
            }
        }
        // disable extra ct spawns
        else if( g_iSpawnCount_T < g_iSpawnCount_CT )
        {
            for( new i = g_iSpawnCount_T; i < g_iSpawnCount_CT; i++ )
            {
                g_iSpawnDisabled_CT[i] = 1
                entity_set_string( g_iSpawnIndexes_CT[i], EV_SZ_classname, "_info_player_start" )
            }
        }
    }
    else
    {
        new iMax = max( g_iSpawnCount_T, g_iSpawnCount_CT )
        
        for( new i = 0; i < iMax; i++ )
        {
            if( g_iSpawnDisabled_CT[i] )
            {
                g_iSpawnDisabled_CT[i] = 0
                entity_set_string( g_iSpawnIndexes_CT[i], EV_SZ_classname, "info_player_start" )
            }
            if( g_iSpawnDisabled_T[i] )
            {
                g_iSpawnDisabled_T[i] = 0
                entity_set_string( g_iSpawnIndexes_T[i], EV_SZ_classname, "info_player_deathmatch" )
            }
        }
    }
    
    new iMin = min( g_iSpawnCount_T, g_iSpawnCount_CT )
    
    new Float:flTemp[3]
    
    for( new i = 0; i < iMin; i++ )
    {
        flTemp = g_flSpawnOrigins_T[i]
        g_flSpawnOrigins_T[i] = g_flSpawnOrigins_CT[i]
        g_flSpawnOrigins_CT[i] = flTemp
        
        flTemp = g_flSpawnAngles_T[i]
        g_flSpawnAngles_T[i] = g_flSpawnAngles_CT[i]
        g_flSpawnAngles_CT[i] = flTemp
        
        entity_set_origin( g_iSpawnIndexes_T[i], g_flSpawnOrigins_T[i] )
        entity_set_vector( g_iSpawnIndexes_T[i], EV_VEC_angles, g_flSpawnAngles_T[i] )
        entity_set_origin( g_iSpawnIndexes_CT[i], g_flSpawnOrigins_CT[i] )
        entity_set_vector( g_iSpawnIndexes_CT[i], EV_VEC_angles, g_flSpawnAngles_CT[i] )
    }
    
    g_iSwapped = !g_iSwapped
    
    return PLUGIN_HANDLED
} 


[Hunter-Digital]

Hmm, yes indeed it works, I added your code ideea, thanks

New version (1.2) uploaded, it's morning here, I'm a little dizzy and I *may* have done some serious logic errors in there... but the plugin works just fine

[ConnorMcLeod]

Nice.
May be last missing feature is a cvar to turn off logging.