[Bugsy]

No, the above only covers when he spawns and does not move.

This will slay when a player spawns and does not move, or stops moving for 30 seconds anywhere on the map.

PHP Code:


#include <amxmodx> 
#include <fakemeta>
#include <hamsandwich>

new const Version[] = "0.2";

const TaskID = 324123;

new Float:g_fPrevOrigin[ MAX_PLAYERS + 1 ][ 3 ];  
new g_pSlayTime;

public plugin_init()  
{  
    register_plugin( "AFK Slay" , Version , "bugsy" );
    
    register_logevent( "RoundStart" , 2 , "1=Round_Start" );
    register_logevent( "RoundEnd" , 2 , "1=Round_End" );

    g_pSlayTime = register_cvar( "as_slaytime" , "30" );
}  

public client_connect( id )
{
    g_fPrevOrigin[ id ][ 0 ] = 0.0;
}

public RoundStart()
{
    new iPlayers[ 32 ] , iNum , iPlayer;
    
    get_players( iPlayers , iNum , "ae" , "CT" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        pev( iPlayer , pev_origin , g_fPrevOrigin[ iPlayer ] );
    }
    
    set_task( get_pcvar_float( g_pSlayTime ) , "CheckAFK" , TaskID , .flags="b" );
}

public RoundEnd()
{
    remove_task( TaskID );
}

public CheckAFK()  
{  
    new iPlayers[ 32 ] , iNum , iPlayer , Float:fOrigin[ 3 ];
        
    get_players( iPlayers , iNum , "ae" , "CT" );
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        pev( iPlayer , pev_origin , fOrigin );
        
        if ( g_fPrevOrigin[ iPlayer ][ 0 ] && ( get_distance_f( fOrigin , g_fPrevOrigin[ iPlayer ] ) <= 25.0 ) )
        {
            user_kill( iPlayer )
        }    
        
        g_fPrevOrigin[ iPlayer ][ 0 ] = fOrigin[ 0 ];
        g_fPrevOrigin[ iPlayer ][ 1 ] = fOrigin[ 1 ];
        g_fPrevOrigin[ iPlayer ][ 2 ] = fOrigin[ 2 ];
    }
} 


[Cirovic]

I Tested right now, and this don't slay my players..

[Cirovic]

BUgsy this dont slay my players

[Bugsy]

Ok I see the issue.. the problem is with players who go AFK after leaving spawn. I'll need to change the logic a bit to make it work with the correct seconds interval. They will eventually get slayed, but in some cases in double the defined cvar seconds.

[Cirovic]

So what should we do

[Bugsy]

I will fix this for you so that it checks people in real-time, not only in 30 second intervals. This will make it work more accurately and how you want

[Cirovic]

okay bro pls do it today im in trouble

[Bugsy]

You got it, chief

[Bugsy]

Try this

PHP Code:


#include <amxmodx> 
#include <fakemeta>

new const Version[] = "0.3";

const TaskID = 324123;

enum PlayerData
{
    Float:PreviousOrigin[ 3 ],
    LastMoveTime
}

new g_PlayerData[ MAX_PLAYERS + 1 ][ PlayerData ];  
new g_pSlayTime;

public plugin_init()  
{  
    register_plugin( "AFK Slay" , Version , "bugsy" );

    g_pSlayTime = register_cvar( "as_slaytime" , "30" );
    
    set_task( 1.0 , "CheckAFK" , TaskID , .flags="b" );
}  

public client_connect( id )
{
    g_PlayerData[ id ][ LastMoveTime ] = 0;
}

public CheckAFK()  
{  
    new iPlayers[ 32 ] , iNum , iPlayer , Float:fOrigin[ 3 ] , iSysTime;
        
    get_players( iPlayers , iNum , "ae" , "CT" );
    iSysTime = get_systime();
    
    for ( new i = 0 ; i < iNum ; i++ )
    {
        iPlayer = iPlayers[ i ];
        
        pev( iPlayer , pev_origin , fOrigin );
        
        if ( g_PlayerData[ iPlayer ][ LastMoveTime ] && !PlayerMoved( fOrigin , g_PlayerData[ iPlayer ][ PreviousOrigin ] ) )
        {
            if ( ( iSysTime - g_PlayerData[ iPlayer ][ LastMoveTime ] ) >= get_pcvar_num( g_pSlayTime ) ) 
                user_kill( iPlayer )
        }
        else
        {
            g_PlayerData[ iPlayer ][ LastMoveTime ] = iSysTime;
        }
        
        g_PlayerData[ iPlayer ][ PreviousOrigin ][ 0 ] = fOrigin[ 0 ];
        g_PlayerData[ iPlayer ][ PreviousOrigin ][ 1 ] = fOrigin[ 1 ];
        g_PlayerData[ iPlayer ][ PreviousOrigin ][ 2 ] = fOrigin[ 2 ];
    }
}

bool:PlayerMoved( Float:fPos1[] , Float:fPos2[] )
{
    return bool:( ( fPos1[ 0 ] != fPos2[ 0 ] ) || ( fPos1[ 1 ] != fPos2[ 1 ] ) );
} 


[Cirovic]

Plugin do the job, but does not kill the players that map is moving to the dead spot.. so basically it does not kill the afk players xd