[.Dare Devil.]

Originally Posted by jc980 yeah, when i disable custom flashlight it goes back to 30 fps. lol.

Why cs lights lag but css lights not lag ?

[jc980]

Originally Posted by .Dare Devil. Why cs lights lag but css lights not lag ?

yeah, when i disabled ZP plugin my fps goes back to 60 fps. so strange. does mods and simple plugins eats up cpu and fps? depending on their size? ( lines )

[Leon M.]

That's definetely not depending on the plugin size. Just coding skills. A code with more than 1000 lines could use less cpu than a code with just 5 lines. I figured out that by myself several times ;) xD

[ConnorMcLeod]

Try this :

PHP Code:

/*    Formatright © 2010, ConnorMcLeod

    This plugin is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with this plugin; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <fakemeta>

#define VERSION "0.0.1"
#define PLUGIN "FlashLight Fix"

#define MAX_PLAYERS        32

new g_bitPlayerFlashlight
#define MarkPlayerFlashLight(%0)    g_bitPlayerFlashlight |= 1<<(%0&31)
#define ClearPlayerFlashLight(%0)    g_bitPlayerFlashlight &= ~(1<<(%0&31))
#define HasPlayerFlashLightOn(%0)    ( g_bitPlayerFlashlight & 1<<(%0&31) )

new g_iPlayerTarget[MAX_PLAYERS+1] = {FM_NULLENT, FM_NULLENT, ...}

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, "ConnorMcLeod")
    register_forward(FM_AddToFullPack, "AddToFullPack_Post", 1)
    register_forward(FM_PlayerPreThink, "PlayerPreThink")
    register_event("Flashlight", "Event_Flashlight", "b")
}

public Event_Flashlight( id )
{
    if( read_data(1) )
    {
        MarkPlayerFlashLight(id)
    }
    else
    {
        ClearPlayerFlashLight(id)
    }
}

public PlayerPreThink(id)
{
    if( HasPlayerFlashLightOn(id) )
    {
        static dummy
        get_user_aiming(id, g_iPlayerTarget[id], dummy)
    }
    else
    {
        g_iPlayerTarget[id] = FM_NULLENT
    }
}

// int AddToFullPack( struct entity_state_s *state, int e, edict_t *ent, edict_t *host, int hostflags, int player, unsigned char *pSet )
public AddToFullPack_Post(es, e, iEnt, id, hostflags, player)
{
    if( !player || iEnt == id || !get_orig_retval() || !is_user_alive(id) || !is_user_alive(iEnt) )
    {
        return
    }

    if( g_iPlayerTarget[id] == iEnt )
    {
        if( !HasPlayerFlashLightOn(iEnt) )
        {
            set_es(es, ES_Effects, get_es(es, ES_Effects) | EF_DIMLIGHT)
        }
    }
    else if( HasPlayerFlashLightOn(iEnt) )
    {
        set_es(es, ES_Effects, get_es(es, ES_Effects) & ~EF_DIMLIGHT)
    }
} 


[georgik57]

thank you connor
can you make it look the same as the default flashlight?
and remove the light when aiming on a player?
here's a video so you can understand better what i mean: http://www.youtube.com/user/georgik5.../0/WNfsKqMu6C0

[georgik57]

bump
help please
take a look at the video

[schmurgel1983]

PHP Code:

#include <amxmodx>
#include <fakemeta>

new bs_Flashlight
#define add_bitsum(%1,%2) (%1 |= (1<<(%2-1)))
#define del_bitsum(%1,%2) (%1 &= ~(1<<(%2-1)))
#define get_bitsum(%1,%2) (%1 & (1<<(%2-1)))

public plugin_init()
{
    register_plugin("no EF_DIMLIGHT", "1.0", "schmurgel1983")
    
    register_forward(FM_AddToFullPack, "fwd_AddToFullPack_Post", 1)
    
    register_message(get_user_msgid("Flashlight"), "message_flashlight")
}


public fwd_AddToFullPack_Post(es_handle, e, ent, host, flags, player, pSet)
{
    if (!player || host == ent || !get_bitsum(bs_Flashlight, ent))
        return FMRES_IGNORED;
    
    set_es(es_handle, ES_Effects, get_es(es_handle, ES_Effects) & ~EF_DIMLIGHT) 
    
    return FMRES_IGNORED;
}

public message_flashlight(msg_id, msg_dest, msg_entity)
{
    get_msg_arg_int(1) ? add_bitsum(bs_Flashlight, msg_entity) : del_bitsum(bs_Flashlight, msg_entity);
} 


[ConnorMcLeod]

I already do this in the plugin i gave him, but when you aim at a player with your FL on that player light doesn't change, that's why in that case i add the DIMLIGHT effect.

[georgik57]

okay everything solved
schmurgel helped me make it look closer to the default flashlight
please tell if you find any mistakes ^^

PHP Code:

#include <amxmodx>
#include <fakemeta>

new g_bitPlayerFlashlight, g_iMaxPlayers

#define MarkPlayerFlashLight(%0)    g_bitPlayerFlashlight |= 1<<(%0&31)
#define ClearPlayerFlashLight(%0)    g_bitPlayerFlashlight &= ~(1<<(%0&31))
#define HasPlayerFlashLightOn(%0)    (g_bitPlayerFlashlight & 1<<(%0&31))

public plugin_init()
{
    register_plugin("[ZPNM] Default FlashLight Fix", "0.0.2", "ConnorMcLeod, schmurgel1983")
    
    register_forward(FM_PlayerPreThink, "PlayerPreThink")
    
    register_event("Flashlight", "Event_Flashlight", "b")
    
    g_iMaxPlayers = get_maxplayers()
}

public Event_Flashlight(id)
{
    if (read_data(1))
        MarkPlayerFlashLight(id)
    else
        ClearPlayerFlashLight(id)
}

public PlayerPreThink(id)
{
    static aim, dummy
    aim = 0
    get_user_aiming(id, aim, dummy)
    
    if (!HasPlayerFlashLightOn(id)
    || aim < 1 || aim > g_iMaxPlayers
    || HasPlayerFlashLightOn(aim))
        return;
    
    static origin[3]; get_user_origin(id, origin, 3)
    
    message_begin(MSG_ONE_UNRELIABLE, SVC_TEMPENTITY, _, id)
    write_byte(TE_DLIGHT) // TE id
    write_coord(origin[0]) // x
    write_coord(origin[1]) // y
    write_coord(origin[2]) // z
    write_byte(random_num(9, 11)) // radius
    write_byte(57) // r
    write_byte(57) // g
    write_byte(57) // b
    write_byte(1) // life
    write_byte(0) // decay rate
    message_end()
}