[Therirr]

This is really so nice info that you share here. I like it very much.

[ConnorMcLeod]

Well, gonna share latest kz version i'm using.

Say commands : /players /water, to toggle players and water visibility
/invis to open menu with those 2 options in it.

Note that you can allow players to use weapons with this plugin because you don't hear them shooting or walking unless you are dead.
I highly recommand it on kz servers.

Spoiler

PHP Code:

#define SEMICLIP_RENDERING_RADIUS 400.0

// #define CHATCOLOR // if you are runing plugin : http://forums.alliedmods.net/showthread.php?p=851160

// #define KZLEOD // private stuff, don't bother trying to activate.

// /* DON'T EDIT BELOW */

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < hamsandwich >

#if defined CHATCOLOR
#include < chatcolor >
#endif

#if defined KZLEOD
#include <KzLeod/kz_menu>
#endif

#pragma semicolon 1

#define PLUGIN "Kz SemiClip"
new const VERSION[] = "0.3.31";

const Float:SEMICLIP_RADIUS = SEMICLIP_RENDERING_RADIUS;

const groupNone = 0;

enum _:renderGroups ( <<= 1 )
{
    groupRenderVisible = 0b1,        // 0b1
    groupRenderInvisible,            // 0b10
    groupRenderWaterVisPlayers,        // 0b100
    groupRenderWaterInvisPlayers    // 0b1000
}
const groupRenderWater = groupRenderWaterVisPlayers | groupRenderWaterInvisPlayers;

new const CLASS_PLAYER[] = "player";
new const CLASS_FUNC_WATER[] = "func_water";
new const CLASS_FUNC_ILLUSIONARY[] = "func_illusionary";
new const CLASS_FUNC_CONVEYOR[] = "func_conveyor";
new const CLASS_ENV_SPRITE[] = "env_sprite";
new const PATH_MODEL_XSMOKE1[] = "sprites/xsmoke1.spr";

const m_iMenu = 205;

new g_iMaxPlayers;
#define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers )

#define MaskEnt(%0)    ( 1<<(%0 & 31) )

new g_bitIsPlayerInSphere;
#define MarkPlayerInSphere(%0)    g_bitIsPlayerInSphere |= MaskEnt(%0)
#define IsPlayerInSphere(%0)    ( g_bitIsPlayerInSphere & MaskEnt(%0) )

new g_bitIsPlayerAlive;
#define MarkPlayerAlive(%0)    g_bitIsPlayerAlive |= MaskEnt(%0)
#define IsPlayerAlive(%0)    ( g_bitIsPlayerAlive & MaskEnt(%0) )

new g_bitBots;
#define MarkPlayerBot(%0)    g_bitBots |= MaskEnt(%0)
#define ClearPlayerBot(%0)    g_bitBots &= ~MaskEnt(%0)
#define IsUserBot(%0)        ( g_bitBots & MaskEnt(%0) )

new g_bitSeeingPlayers;
#define MarkPlayerSee(%0)        g_bitSeeingPlayers |= MaskEnt(%0)
#define ClearPlayerSee(%0)        g_bitSeeingPlayers &= ~MaskEnt(%0)
#define IsPlayerSeeing(%0)        ( g_bitSeeingPlayers & MaskEnt(%0) )
#define TogglePlayerSeeing(%0)    g_bitSeeingPlayers ^= MaskEnt(%0)

new g_bitHidingWater;
#define MarkPlayerHideWater(%0)        g_bitHidingWater |= MaskEnt(%0)
#define ClearPlayerHideWater(%0)    g_bitHidingWater &= ~MaskEnt(%0)
#define IsPlayerHidingWater(%0)        ( g_bitHidingWater & MaskEnt(%0) )
#define TogglePlayerHideWater(%0)    g_bitHidingWater ^= MaskEnt(%0)

new g_bWaterEnts[64];
#define MarkEntWater(%0)    g_bWaterEnts[%0>>5] |=  MaskEnt(%0)
#define ClearEntWater(%0)    g_bWaterEnts[%0>>5] &= ~MaskEnt(%0)
#define IsEntWater(%0)        ( g_bWaterEnts[%0>>5] &   MaskEnt(%0) )

new g_iPlayers[32], g_iNum;

new g_iLastPlayerIndex;

new HamHook:g_iHhPreThink, HamHook:g_iHhPreThinkPost;
new g_iFhAddToFullPackPost;

new bool:g_bPreThinkHooked;

new bool:g_bReadPackets;
new bool:g_bClientMessages;
new g_iWaterGroup = groupNone;

enum
{
    ITEM_INVIS_PLAYERS,
    ITEM_INVIS_WATER,
    ITEM_INVIS_EXIT
}
new g_iInvisMenu;

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );
    new pCvar = register_cvar("amx_semiclip_version", VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY);
    set_pcvar_string(pCvar, VERSION);

    register_forward(FM_CmdStart, "OnCmdStart", false);

    DisableHamForward( g_iHhPreThink = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink", false) );
    DisableHamForward( g_iHhPreThinkPost = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink_P", true) );

    RegisterHam(Ham_Spawn, CLASS_PLAYER, "OnCBasePlayer_Spawn_P", true);
    RegisterHam(Ham_Killed, CLASS_PLAYER, "OnCBasePlayer_Killed_P", true);

    register_forward(FM_UpdateClientData, "OnUpdateClientData_P", true);

    g_iMaxPlayers = get_maxplayers();

    register_clcmd("say /invis", "ClCmd_Invis");
    register_clcmd("say /players", "ClCmd_Players");

#if defined KZLEOD
    kz_add_menuitem("Invis Menu\R   \d/invis", "ClCmd_Invis", true);
    kz_add_menuitem("Players Invis Toggle\R   \d/players", "ClCmd_Players", true);
#endif

    g_iInvisMenu = menu_create("\yInvisible Menu\R    Status", "HandleMenu_Invis");
    menu_additem(g_iInvisMenu, "Players", .callback = menu_makecallback("HandleMenuBuild_InvisPlayer"));
    menu_setprop(g_iInvisMenu, MPROP_NUMBER_COLOR, "\y");
    menu_setprop(g_iInvisMenu, MPROP_EXIT, MEXIT_NEVER);
    if( CheckAndMarkWater() )
    {
        menu_additem(g_iInvisMenu, "Water", .callback = menu_makecallback("HandleMenuBuild_InvisWater"));
        register_clcmd("say /water", "ClCmd_Water");
#if defined KZLEOD
        kz_add_menuitem("Water Invis Toggle\R   \d/water", "ClCmd_Water", true);
#endif
    }
    else
    {
        menu_additem(g_iInvisMenu, "\dNo Water", "", 1<<31); // menu_addtext bugs menu.
    }
    menu_addblank(g_iInvisMenu, 0);
    menu_additem(g_iInvisMenu, "Exit");
}

bool:CheckAndMarkWater()
{
    new iEnt, bool:bWater;
    
    iEnt = g_iMaxPlayers;
    while( (iEnt = find_ent_by_class(iEnt, CLASS_FUNC_WATER)) )
    {
        set_pev(iEnt, pev_scale, 0.0);
        bWater = true;
        MarkEntWater(iEnt);
    }
    
    iEnt = g_iMaxPlayers;
    while( (iEnt = find_ent_by_class(iEnt, CLASS_FUNC_ILLUSIONARY)) )
    {
        if( entity_get_int(iEnt, EV_INT_skin) == CONTENTS_WATER )
        {
            bWater = true;
            MarkEntWater(iEnt);
        }
    }
    
    iEnt = g_iMaxPlayers;
    while( (iEnt = find_ent_by_class(iEnt, CLASS_FUNC_CONVEYOR)) )
    {
        if( entity_get_int(iEnt, EV_INT_spawnflags) & SF_CONVEYOR_NOTSOLID )
        {
            bWater = true;
            MarkEntWater(iEnt);
        }
    }
    
    iEnt = g_iMaxPlayers;
    while( (iEnt = find_ent_by_model(iEnt, CLASS_ENV_SPRITE, PATH_MODEL_XSMOKE1)) )
    {
        bWater = true;
        MarkEntWater(iEnt);
    }

    return bWater;
}

public client_putinserver(id)
{
    if( is_user_bot(id) )
    {
        MarkPlayerBot(id);
    }
    else
    {
        ClearPlayerBot(id);
        MarkPlayerSee(id);
        ClearPlayerHideWater(id);
    }
}

public OnCmdStart(id)
{
    if( !g_bReadPackets )
    {
        g_bReadPackets = true;
        if( g_iWaterGroup != groupNone )
        {
            SetWaterGroup( groupNone );
        }

        static plr;
        get_players g_iPlayers, g_iNum, "a" ;
        for(--g_iNum; g_iNum>=0; g_iNum--)
        {
            plr = g_iPlayers[ g_iNum ];
            entity_set_int plr, EV_INT_groupinfo, MaskEnt(plr) ;
        }
        g_iLastPlayerIndex = 0;
    }

    if( g_iLastPlayerIndex && is_user_alive(g_iLastPlayerIndex) )
    {
        entity_set_int g_iLastPlayerIndex, EV_INT_groupinfo, MaskEnt(g_iLastPlayerIndex) ;
    }

    if( is_user_alive(id) )
    {
        entity_set_int id, EV_INT_groupinfo, MaskEnt(id) ;
        if( !IsUserBot(id) && IsPlayerSeeing(id) )
        {
            if( !g_bPreThinkHooked )
            {
                EnableHamForward g_iHhPreThink ;
                EnableHamForward g_iHhPreThinkPost ;
                g_bPreThinkHooked = true;
            }
        }
        else if( g_bPreThinkHooked )
        {
            DisableHamForward g_iHhPreThink ;
            DisableHamForward g_iHhPreThinkPost ;
            g_bPreThinkHooked = false;
        }
    }
    else
    {
        entity_set_int id, EV_INT_groupinfo, groupNone ;
        g_iLastPlayerIndex = id;
        if( g_bPreThinkHooked )
        {
            DisableHamForward g_iHhPreThink ;
            DisableHamForward g_iHhPreThinkPost ;
            g_bPreThinkHooked = false;
        }
    }
}

public OnCBasePlayer_PreThink(id)
{
    entity_set_int id, EV_INT_groupinfo, groupNone ;
}

public OnCBasePlayer_PreThink_P(id)
{
    entity_set_int id, EV_INT_groupinfo, MaskEnt(id) ;
}

public OnCBasePlayer_Spawn_P(id)
{
    if( is_user_alive(id) )
    {
        entity_set_int id, EV_INT_groupinfo, MaskEnt(id) ;
    }
}

public OnCBasePlayer_Killed_P(id)
{
    if( !is_user_alive(id) )
    {
        entity_set_int id, EV_INT_groupinfo, groupNone ;
    }
}

public server_frame()
{
    g_iLastPlayerIndex = 0;
    g_bReadPackets = false;
    g_bClientMessages = false;
    if( g_iWaterGroup != groupNone )
    {
        SetWaterGroup( groupNone );
    }
    static id;
    get_players g_iPlayers, g_iNum, "a" ;
    for(--g_iNum; g_iNum>=0; g_iNum--)
    {
        id = g_iPlayers[ g_iNum ];
        entity_set_int id, EV_INT_groupinfo, MaskEnt(id) ;
    }
}

public OnUpdateClientData_P(id, sendweapons, cd)
{
    if( IsUserBot(id) )
    {
        return;
    }

    if( !g_bClientMessages )
    {
        if( g_iWaterGroup != groupRenderWater )
        {
            SetWaterGroup( groupRenderWater );
        }
        g_bClientMessages = true;
        g_bitIsPlayerAlive = 0;
        get_players g_iPlayers, g_iNum, "a" ;
        static player;
        for(--g_iNum; g_iNum>=0; g_iNum--)
        {
            player = g_iPlayers[ g_iNum ];
            MarkPlayerAlive( player );
            entity_set_int player, EV_INT_groupinfo, groupRenderVisible ;
        }
    }

    if( IsPlayerAlive(id) )
    // if( is_user_alive(id) )
    {
        if( g_iLastPlayerIndex )
        {
            entity_set_int g_iLastPlayerIndex, EV_INT_groupinfo, groupRenderVisible ;
            g_iLastPlayerIndex = 0;
        }
        static group;
        if( IsPlayerSeeing(id) )
        {
            group = groupRenderVisible;
            g_bitIsPlayerInSphere = 0;
            g_iNum = find_sphere_class(id, CLASS_PLAYER, SEMICLIP_RADIUS, g_iPlayers, g_iMaxPlayers);
            static player;
            for(--g_iNum; g_iNum>=0; g_iNum--)
            {
                player = g_iPlayers[ g_iNum ];
                if( player != id )
                {
                    MarkPlayerInSphere( player );
                }
            }
            if( g_bitIsPlayerInSphere )
            {
                if( !g_iFhAddToFullPackPost )
                {
                    g_iFhAddToFullPackPost = register_forward(FM_AddToFullPack, "OnAddToFullPack_P", true);
                }
            }
            else if( g_iFhAddToFullPackPost )
            {
                unregister_forward(FM_AddToFullPack, g_iFhAddToFullPackPost, true);
                g_iFhAddToFullPackPost = 0;
            }
            if( !IsPlayerHidingWater(id) )
            {
                group |= groupRenderWaterVisPlayers;
            }
            else if( get_cd(cd, CD_WaterLevel) == 3 )
            {
                set_cd(cd, CD_WaterLevel, 2);
            }
        }
        else
        {
            group = groupRenderInvisible;
            g_iLastPlayerIndex = id;
            if( g_iFhAddToFullPackPost )
            {
                unregister_forward(FM_AddToFullPack, g_iFhAddToFullPackPost, true);
                g_iFhAddToFullPackPost = 0;
            }
            if( !IsPlayerHidingWater(id) )
            {
                group |= groupRenderWaterInvisPlayers;
            }
            else if( get_cd(cd, CD_WaterLevel) == 3 )
            {
                set_cd(cd, CD_WaterLevel, 2);
            }
        }

        
        entity_set_int id, EV_INT_groupinfo, group ;
    }
}

public OnAddToFullPack_P(es, e, ent, id, hostflags, player, pSet)
{
    if( player )
    {
        if( IsPlayerAlive(ent) && IsPlayerInSphere(ent) )
        {
            set_es es, ES_Solid, SOLID_NOT ;
            set_es es, ES_RenderMode, kRenderTransAlpha ;
            set_es es, ES_RenderAmt, floatround(entity_range(id, ent) * 255.0 / SEMICLIP_RADIUS, floatround_floor) ;
        }
    }
    else
    {
        unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;
        g_iFhAddToFullPackPost = 0;
    }
}

public ClCmd_Invis(id)
{
    set_pdata_int(id, m_iMenu, 0);
    menu_display(id, g_iInvisMenu);
}

public ClCmd_Players(id)
{
    TogglePlayerSeeing(id);
#if defined CHATCOLOR
    client_print_color(id, Red, "^4[Invis] ^1Players are now %sisible.", IsPlayerSeeing(id) ? "^4V" :"^3Inv");
#else
    client_print(id, print_chat, "[Invis] Players are now %sisible.", IsPlayerSeeing(id) ? "V" :"Inv");
#endif
}

public ClCmd_Water(id)
{
    TogglePlayerHideWater(id);
#if defined CHATCOLOR
    client_print_color(id, Red, "^4[Invis] ^1Water is now %sisible.", IsPlayerHidingWater(id) ? "^3Inv" : "^4V");
#else
    client_print(id, print_chat, "[Invis] Water is now %sisible.", IsPlayerHidingWater(id) ? "V" :"Inv");
#endif
}

public HandleMenuBuild_InvisPlayer(id, menu, item)
{
    menu_item_setname(menu, item, IsPlayerSeeing(id) ? "Players\R\yVisible" : "Players\R\rInvisible");
}

public HandleMenuBuild_InvisWater(id, menu, item)
{
    menu_item_setname(menu, item, IsPlayerHidingWater(id) ? "Water\R\rInvisible" : "Water\R\yVisible");
}

public HandleMenu_Invis(id, menu, item)
{
    switch( item )
    {
        case ITEM_INVIS_PLAYERS:
        {
            ClCmd_Players(id);
        }
        case ITEM_INVIS_WATER:
        {
            ClCmd_Water(id);
        }
        case ITEM_INVIS_EXIT:
        {
            return;
        }
    }
    ClCmd_Invis(id);
}

SetWaterGroup( iGroup )
{
    static ent;
    ent = g_iMaxPlayers;
    while( (ent = find_ent_by_class(ent, CLASS_FUNC_WATER)) )
    {
        entity_set_int ent, EV_INT_groupinfo, iGroup ;
    }
    ent = g_iMaxPlayers;
    while( (ent = find_ent_by_class(ent, CLASS_FUNC_ILLUSIONARY)) )
    {
        if( IsEntWater(ent) )
        {
            entity_set_int ent, EV_INT_groupinfo, iGroup ;
        }
    }
    
    ent = g_iMaxPlayers;
    while( (ent = find_ent_by_class(ent, CLASS_FUNC_CONVEYOR)) )
    {
        if( IsEntWater(ent) )
        {
            entity_set_int ent, EV_INT_groupinfo, iGroup ;
        }
    }
    
    ent = g_iMaxPlayers;
    while( (ent = find_ent_by_model(ent, CLASS_ENV_SPRITE, PATH_MODEL_XSMOKE1)) )
    {
        entity_set_int ent, EV_INT_groupinfo, iGroup ;
    }

    g_iWaterGroup = iGroup;
} 


Edit 20may2013 : v0.3.3 fixed bugged /invis menu because of bugged menu_addtext native.
21may2013 : v0.3.31 little fix if player spawned furing pfnClientCommand.

[ConnorMcLeod]

Team Semiclip (not tested):

If you use mp_friendlyfire 1, make sure you have enabled following line.

PHP Code:

// #define ENABLE_SHOTS_DAMAGE 


Spoiler

PHP Code:

#define SHOW_NAMES_WHEN_AIM
// #define ENABLE_SHOTS_DAMAGE

#define SEMICLIP_RENDERING_RADIUS 400.0

// #define CHATCOLOR // if you are runing plugin : http://forums.alliedmods.net/showthread.php?p=851160

// /* DON'T EDIT BELOW */

#include < amxmodx >
#include < engine >
#include < fakemeta >
#include < hamsandwich >

#if defined CHATCOLOR
#include < chatcolor >
#endif

#pragma semicolon 1

#define PLUGIN "Team SemiClip"
new const VERSION[] = "0.3.4";

const Float:SEMICLIP_RADIUS = SEMICLIP_RENDERING_RADIUS;

const m_iTeam = 114;

const GROUP_OP_NAND = 1;
#define ENGINE_SETGROUPMASK(%0,%1)    engfunc(EngFunc_SetGroupMask, %0, %1)

const groupNone = 0;

new const CLASS_PLAYER[] = "player";

new g_iMaxPlayers;
#define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers )

#define MaskEnt(%0)    ( 1<<(%0 & 31) )

new g_bitIsPlayerInSphere;
#define MarkPlayerInSphere(%0)    g_bitIsPlayerInSphere |= MaskEnt(%0)
#define IsPlayerInSphere(%0)    ( g_bitIsPlayerInSphere & MaskEnt(%0) )

new g_bitIsPlayerInTeam;
#define MarkPlayerInTeam(%0)    g_bitIsPlayerInTeam |= MaskEnt(%0)
#define IsPlayerInTeam(%0)    ( g_bitIsPlayerInTeam & MaskEnt(%0) )

new g_bitIsPlayerAlive;
#define MarkPlayerAlive(%0)    g_bitIsPlayerAlive |= MaskEnt(%0)
#define IsPlayerAlive(%0)    ( g_bitIsPlayerAlive & MaskEnt(%0) )

new g_bitBots;
#define MarkPlayerBot(%0)    g_bitBots |= MaskEnt(%0)
#define ClearPlayerBot(%0)    g_bitBots &= ~MaskEnt(%0)
#define IsUserBot(%0)        ( g_bitBots & MaskEnt(%0) )

new g_bitSeeingPlayers;
#define MarkPlayerSee(%0)        g_bitSeeingPlayers |= MaskEnt(%0)
#define ClearPlayerSee(%0)        g_bitSeeingPlayers &= ~MaskEnt(%0)
#define IsPlayerSeeing(%0)        ( g_bitSeeingPlayers & MaskEnt(%0) )
#define TogglePlayerSeeing(%0)    g_bitSeeingPlayers ^= MaskEnt(%0)

new g_iPlayers[32], g_iNum;

new g_iLastPlayerIndex;

new g_iFhAddToFullPackPost;

new bool:g_bReadPackets;
new bool:g_bClientMessages;

#if defined SHOW_NAMES_WHEN_AIM
    new HamHook:g_iHhPreThink, HamHook:g_iHhPreThinkPost, bool:g_bPreThinkHooked;
#endif

#if defined ENABLE_SHOTS_DAMAGE
    new HamHook:g_iHhPostThink, HamHook:g_iHhPostThinkPost, bool:g_bPostThinkHooked;
#endif

public plugin_init()
{
    register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );
    new pCvar = register_cvar("team_semiclip_version", VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY);
    set_pcvar_string(pCvar, VERSION);

    register_forward(FM_CmdStart, "OnCmdStart_P", true);

#if defined SHOW_NAMES_WHEN_AIM
    DisableHamForward( g_iHhPreThink = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink", false) );
    DisableHamForward( g_iHhPreThinkPost = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink_P", true) );
#endif
    
#if defined ENABLE_SHOTS_DAMAGE
    DisableHamForward( g_iHhPostThink = RegisterHam(Ham_Player_PostThink, CLASS_PLAYER, "OnCBasePlayer_PostThink", false) );
    DisableHamForward( g_iHhPostThinkPost = RegisterHam(Ham_Player_PostThink, CLASS_PLAYER, "OnCBasePlayer_PostThink_P", true) );
#endif

    RegisterHam(Ham_Spawn, CLASS_PLAYER, "OnCBasePlayer_Spawn_P", true);
    RegisterHam(Ham_Killed, CLASS_PLAYER, "OnCBasePlayer_Killed_P", true);

    register_forward(FM_UpdateClientData, "OnUpdateClientData_P", true);

    g_iMaxPlayers = get_maxplayers();

    register_clcmd("say /invis", "ClCmd_Players");
    register_clcmd("say /players", "ClCmd_Players");
}

public client_putinserver(id)
{
    if( is_user_bot(id) )
    {
        MarkPlayerBot(id);
    }
    else
    {
        ClearPlayerBot(id);
    }
    MarkPlayerSee(id);
}

public OnCmdStart_P(id)
{
    if( !g_bReadPackets )
    {
        g_bReadPackets = true;

        static plr;
        get_players g_iPlayers, g_iNum, "a" ;
        for(--g_iNum; g_iNum>=0; g_iNum--)
        {
            plr = g_iPlayers[ g_iNum ];
            entity_set_int plr, EV_INT_groupinfo, get_pdata_int(plr, m_iTeam) ;
        }
        g_iLastPlayerIndex = 0;
    }

    if( g_iLastPlayerIndex && is_user_alive(g_iLastPlayerIndex) )
    {
        entity_set_int g_iLastPlayerIndex, EV_INT_groupinfo, get_pdata_int(g_iLastPlayerIndex, m_iTeam) ;
    }

    if( is_user_alive(id) )
    {
        static group;
        group = get_pdata_int(id, m_iTeam);
        entity_set_int id, EV_INT_groupinfo, group ;
        ENGINE_SETGROUPMASK(group, GROUP_OP_NAND);
        if( IsPlayerSeeing(id) )
        {
#if defined SHOW_NAMES_WHEN_AIM
            if( !g_bPreThinkHooked )
            {
                EnableHamForward g_iHhPreThink ;
                EnableHamForward g_iHhPreThinkPost ;
                g_bPreThinkHooked = true;
            }
#endif
#if defined ENABLE_SHOTS_DAMAGE
            if( !g_bPostThinkHooked )
            {
                EnableHamForward g_iHhPostThink ;
                EnableHamForward g_iHhPostThinkPost ;
                g_bPostThinkHooked = true;
            }
#endif
        }
        else // empty statement when nothing is defined ?
        {
#if defined SHOW_NAMES_WHEN_AIM
            if( g_bPreThinkHooked )
            {
                DisableHamForward g_iHhPreThink ;
                DisableHamForward g_iHhPreThinkPost ;
                g_bPreThinkHooked = false;
            }
#endif
#if defined ENABLE_SHOTS_DAMAGE
            if( g_bPostThinkHooked )
            {
                DisableHamForward g_iHhPostThink ;
                DisableHamForward g_iHhPostThinkPost ;
                g_bPostThinkHooked = false;
            }
#endif
        }
    }
    else
    {
        entity_set_int id, EV_INT_groupinfo, groupNone ;
        g_iLastPlayerIndex = id;
#if defined SHOW_NAMES_WHEN_AIM
        if( g_bPreThinkHooked )
        {
            DisableHamForward g_iHhPreThink ;
            DisableHamForward g_iHhPreThinkPost ;
            g_bPreThinkHooked = false;
        }
#endif
#if defined ENABLE_SHOTS_DAMAGE
        if( g_bPostThinkHooked )
        {
            DisableHamForward g_iHhPostThink ;
            DisableHamForward g_iHhPostThinkPost ;
            g_bPostThinkHooked = false;
        }
#endif
    }
}

public OnCBasePlayer_PreThink(id)
{
    entity_set_int id, EV_INT_groupinfo, groupNone ;
}

public OnCBasePlayer_PreThink_P(id)
{
    entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ;
}

public OnCBasePlayer_PostThink(id)
{
    entity_set_int id, EV_INT_groupinfo, groupNone ;
}

public OnCBasePlayer_PostThink_P(id)
{
    entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ;
}

public OnCBasePlayer_Spawn_P(id)
{
    if( is_user_alive(id) )
    {
        entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ;
    }
}

public OnCBasePlayer_Killed_P(id)
{
    if( !is_user_alive(id) )
    {
        entity_set_int id, EV_INT_groupinfo, groupNone ;
    }
}

// maybe this could be moved to first UpdateClientData ??
// in any ways, SV_Physics gonna be executed with clipping players
public server_frame()
{
    g_iLastPlayerIndex = 0;
    g_bReadPackets = false;
    g_bClientMessages = false;

    static id;
    get_players g_iPlayers, g_iNum, "a" ;
    for(--g_iNum; g_iNum>=0; g_iNum--)
    {
        id = g_iPlayers[ g_iNum ];
        entity_set_int id, EV_INT_groupinfo, 0 ;
    }
}

public OnUpdateClientData_P(id, sendweapons, cd)
{
    if( IsUserBot(id) )
    {
        return;
    }

    if( !g_bClientMessages )
    {
        g_bClientMessages = true;

        g_bitIsPlayerAlive = 0;
        get_players g_iPlayers, g_iNum, "a" ;
        for(--g_iNum; g_iNum>=0; g_iNum--)
        {
            MarkPlayerAlive( g_iPlayers[ g_iNum ] ); // safe to cache alive players here because nobody can die/spawn during rendering
        }
    }

    if( IsPlayerAlive(id) )
    {
        if( IsPlayerSeeing(id) )
        {
            static player;

            g_bitIsPlayerInTeam = 0;

            get_players g_iPlayers, g_iNum, "ae", get_pdata_int(id, m_iTeam) == 1 ? "TERRORIST" : "CT" ;

            for(--g_iNum; g_iNum>=0; g_iNum--)
            {
                player = g_iPlayers[ g_iNum ];
                if( player != id )
                {
                    MarkPlayerInTeam( player );
                }
            }
            g_iNum = find_sphere_class(id, CLASS_PLAYER, SEMICLIP_RADIUS, g_iPlayers, g_iMaxPlayers);
            
            g_bitIsPlayerInSphere = 0;
            for(--g_iNum; g_iNum>=0; g_iNum--)
            {
                player = g_iPlayers[ g_iNum ];
                if( player != id && IsPlayerInTeam( player ) )
                {
                    MarkPlayerInSphere( player );
                }
            }
            if( g_bitIsPlayerInSphere )
            {
                if( !g_iFhAddToFullPackPost )
                {
                    g_iFhAddToFullPackPost = register_forward(FM_AddToFullPack, "OnAddToFullPack_P", true);
                }
            }
            else if( g_iFhAddToFullPackPost )
            {
                unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;
                g_iFhAddToFullPackPost = 0;
            }
        }
        else if( g_iFhAddToFullPackPost )
        {
            unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;
            g_iFhAddToFullPackPost = 0;
        }
    }
}

public OnAddToFullPack_P(es, e, ent, id, hostflags, player, pSet)
{
    if( player )
    {
        if( IsPlayerAlive(ent) && IsPlayerInSphere(ent) )
        {
            set_es es, ES_Solid, SOLID_NOT ;
            set_es es, ES_RenderMode, kRenderTransAlpha ;
            set_es es, ES_RenderAmt, floatround(entity_range(id, ent) * 255.0 / SEMICLIP_RADIUS, floatround_floor) ;
        }
    }
    else
    {
        unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;
        g_iFhAddToFullPackPost = 0;
    }
}

public ClCmd_Players(id)
{
    TogglePlayerSeeing(id);
#if defined CHATCOLOR
    client_print_color(id, Red, "^4[Invis] ^1Players are now %sisible.", IsPlayerSeeing(id) ? "^4V" :"^3Inv");
#else
    client_print(id, print_chat, "[Invis] Players are now %sisible.", IsPlayerSeeing(id) ? "V" :"Inv");
#endif
} 


[Diegorkable]

Originally Posted by ConnorMcLeod Team Semiclip (not tested): If you use mp_friendlyfire 1, make sure you have enabled following line. PHP Code: // #define ENABLE_SHOTS_DAMAGE  Spoiler PHP Code: #define SHOW_NAMES_WHEN_AIM // #define ENABLE_SHOTS_DAMAGE #define SEMICLIP_RENDERING_RADIUS 400.0 // #define CHATCOLOR // if you are runing plugin : http://forums.alliedmods.net/showthread.php?p=851160 // /* DON'T EDIT BELOW */ #include < amxmodx > #include < engine > #include < fakemeta > #include < hamsandwich > #if defined CHATCOLOR #include < chatcolor > #endif #pragma semicolon 1 #define PLUGIN "Team SemiClip" new const VERSION[] = "0.3.31"; const Float:SEMICLIP_RADIUS = SEMICLIP_RENDERING_RADIUS; const m_iTeam = 114; const GROUP_OP_NAND = 1; #define ENGINE_SETGROUPMASK(%0,%1)    engfunc(EngFunc_SetGroupMask, %0, %1) const groupNone = 0; new const CLASS_PLAYER[] = "player"; new g_iMaxPlayers; #define IsPlayer(%0)    ( 1 <= (%0) <= g_iMaxPlayers ) #define MaskEnt(%0)    ( 1<<(%0 & 31) ) new g_bitIsPlayerInSphere; #define MarkPlayerInSphere(%0)    g_bitIsPlayerInSphere |= MaskEnt(%0) #define IsPlayerInSphere(%0)    ( g_bitIsPlayerInSphere & MaskEnt(%0) ) new g_bitIsPlayerAlive; #define MarkPlayerAlive(%0)    g_bitIsPlayerAlive |= MaskEnt(%0) #define IsPlayerAlive(%0)    ( g_bitIsPlayerAlive & MaskEnt(%0) ) new g_bitBots; #define MarkPlayerBot(%0)    g_bitBots |= MaskEnt(%0) #define ClearPlayerBot(%0)    g_bitBots &= ~MaskEnt(%0) #define IsUserBot(%0)        ( g_bitBots & MaskEnt(%0) ) new g_bitSeeingPlayers; #define MarkPlayerSee(%0)        g_bitSeeingPlayers |= MaskEnt(%0) #define ClearPlayerSee(%0)        g_bitSeeingPlayers &= ~MaskEnt(%0) #define IsPlayerSeeing(%0)        ( g_bitSeeingPlayers & MaskEnt(%0) ) #define TogglePlayerSeeing(%0)    g_bitSeeingPlayers ^= MaskEnt(%0) new g_iPlayers[32], g_iNum; new g_iLastPlayerIndex; new g_iFhAddToFullPackPost; new bool:g_bReadPackets; new bool:g_bClientMessages; #if defined SHOW_NAMES_WHEN_AIM     new HamHook:g_iHhPreThink, HamHook:g_iHhPreThinkPost, bool:g_bPreThinkHooked; #endif #if defined ENABLE_SHOTS_DAMAGE     new HamHook:g_iHhPostThink, HamHook:g_iHhPostThinkPost, bool:g_bPostThinkHooked; #endif public plugin_init() {     register_plugin( PLUGIN, VERSION, "ConnorMcLeod" );     new pCvar = register_cvar("team_semiclip_version", VERSION, FCVAR_SERVER|FCVAR_EXTDLL|FCVAR_SPONLY);     set_pcvar_string(pCvar, VERSION);     register_forward(FM_CmdStart, "OnCmdStart_P", true); #if defined SHOW_NAMES_WHEN_AIM     DisableHamForward( g_iHhPreThink = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink", false) );     DisableHamForward( g_iHhPreThinkPost = RegisterHam(Ham_Player_PreThink, CLASS_PLAYER, "OnCBasePlayer_PreThink_P", true) ); #endif      #if defined ENABLE_SHOTS_DAMAGE     DisableHamForward( g_iHhPostThink = RegisterHam(Ham_Player_PostThink, CLASS_PLAYER, "OnCBasePlayer_PostThink", false) );     DisableHamForward( g_iHhPostThinkPost = RegisterHam(Ham_Player_PostThink, CLASS_PLAYER, "OnCBasePlayer_PostThink_P", true) ); #endif     RegisterHam(Ham_Spawn, CLASS_PLAYER, "OnCBasePlayer_Spawn_P", true);     RegisterHam(Ham_Killed, CLASS_PLAYER, "OnCBasePlayer_Killed_P", true);     register_forward(FM_UpdateClientData, "OnUpdateClientData_P", true);     g_iMaxPlayers = get_maxplayers();     register_clcmd("say /invis", "ClCmd_Players");     register_clcmd("say /players", "ClCmd_Players"); } public client_putinserver(id) {     if( is_user_bot(id) )     {         MarkPlayerBot(id);     }     else     {         ClearPlayerBot(id);     }     MarkPlayerSee(id); } public OnCmdStart_P(id) {     if( !g_bReadPackets )     {         g_bReadPackets = true;         static plr;         get_players g_iPlayers, g_iNum, "a" ;         for(--g_iNum; g_iNum>=0; g_iNum--)         {             plr = g_iPlayers[ g_iNum ];             entity_set_int plr, EV_INT_groupinfo, get_pdata_int(plr, m_iTeam) ;         }         g_iLastPlayerIndex = 0;     }     if( g_iLastPlayerIndex && is_user_alive(g_iLastPlayerIndex) )     {         entity_set_int g_iLastPlayerIndex, EV_INT_groupinfo, get_pdata_int(g_iLastPlayerIndex, m_iTeam) ;     }     if( is_user_alive(id) )     {         static group;         group = get_pdata_int(id, m_iTeam);         entity_set_int id, EV_INT_groupinfo, group ;         ENGINE_SETGROUPMASK(group, GROUP_OP_NAND);         if( IsPlayerSeeing(id) )         { #if defined SHOW_NAMES_WHEN_AIM             if( !g_bPreThinkHooked )             {                 EnableHamForward g_iHhPreThink ;                 EnableHamForward g_iHhPreThinkPost ;                 g_bPreThinkHooked = true;             } #endif #if defined ENABLE_SHOTS_DAMAGE             if( !g_bPostThinkHooked )             {                 EnableHamForward g_iHhPostThink ;                 EnableHamForward g_iHhPostThinkPost ;                 g_bPostThinkHooked = true;             } #endif         }         else // empty statement when nothing is defined ?         { #if defined SHOW_NAMES_WHEN_AIM             if( g_bPreThinkHooked )             {                 DisableHamForward g_iHhPreThink ;                 DisableHamForward g_iHhPreThinkPost ;                 g_bPreThinkHooked = false;             } #endif #if defined ENABLE_SHOTS_DAMAGE             if( g_bPostThinkHooked )             {                 DisableHamForward g_iHhPostThink ;                 DisableHamForward g_iHhPostThinkPost ;                 g_bPostThinkHooked = false;             } #endif         }     }     else     {         entity_set_int id, EV_INT_groupinfo, groupNone ;         g_iLastPlayerIndex = id; #if defined SHOW_NAMES_WHEN_AIM         if( g_bPreThinkHooked )         {             DisableHamForward g_iHhPreThink ;             DisableHamForward g_iHhPreThinkPost ;             g_bPreThinkHooked = false;         } #endif #if defined ENABLE_SHOTS_DAMAGE         if( g_bPostThinkHooked )         {             DisableHamForward g_iHhPostThink ;             DisableHamForward g_iHhPostThinkPost ;             g_bPostThinkHooked = false;         } #endif     } } public OnCBasePlayer_PreThink(id) {     entity_set_int id, EV_INT_groupinfo, groupNone ; } public OnCBasePlayer_PreThink_P(id) {     entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ; } public OnCBasePlayer_PostThink(id) {     entity_set_int id, EV_INT_groupinfo, groupNone ; } public OnCBasePlayer_PostThink_P(id) {     entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ; } public OnCBasePlayer_Spawn_P(id) {     if( is_user_alive(id) )     {         entity_set_int id, EV_INT_groupinfo, get_pdata_int(id, m_iTeam) ;     } } public OnCBasePlayer_Killed_P(id) {     if( !is_user_alive(id) )     {         entity_set_int id, EV_INT_groupinfo, groupNone ;     } } // maybe this could be moved to first UpdateClientData ?? // in any ways, SV_Physics gonna be executed with clipping players public server_frame() {     g_iLastPlayerIndex = 0;     g_bReadPackets = false;     g_bClientMessages = false;     static id;     get_players g_iPlayers, g_iNum, "a" ;     for(--g_iNum; g_iNum>=0; g_iNum--)     {         id = g_iPlayers[ g_iNum ];         entity_set_int id, EV_INT_groupinfo, 0 ;     } } public OnUpdateClientData_P(id, sendweapons, cd) {     if( IsUserBot(id) )     {         return;     }     if( !g_bClientMessages )     {         g_bClientMessages = true;         g_bitIsPlayerAlive = 0;         get_players g_iPlayers, g_iNum, "a" ;         for(--g_iNum; g_iNum>=0; g_iNum--)         {             MarkPlayerAlive( g_iPlayers[ g_iNum ] ); // safe to cache alive players here because nobody can die/spawn during rendering         }     }     if( IsPlayerAlive(id) )     {         if( IsPlayerSeeing(id) )         {             g_bitIsPlayerInSphere = 0;             g_iNum = find_sphere_class(id, CLASS_PLAYER, SEMICLIP_RADIUS, g_iPlayers, g_iMaxPlayers);             static player;             for(--g_iNum; g_iNum>=0; g_iNum--)             {                 player = g_iPlayers[ g_iNum ];                 if( player != id )                 {                     MarkPlayerInSphere( player );                 }             }             if( g_bitIsPlayerInSphere )             {                 if( !g_iFhAddToFullPackPost )                 {                     g_iFhAddToFullPackPost = register_forward(FM_AddToFullPack, "OnAddToFullPack_P", true);                 }             }             else if( g_iFhAddToFullPackPost )             {                 unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;                 g_iFhAddToFullPackPost = 0;             }         }         else if( g_iFhAddToFullPackPost )         {             unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;             g_iFhAddToFullPackPost = 0;         }     } } public OnAddToFullPack_P(es, e, ent, id, hostflags, player, pSet) {     if( player )     {         if( IsPlayerAlive(ent) && IsPlayerInSphere(ent) )         {             set_es es, ES_Solid, SOLID_NOT ;             set_es es, ES_RenderMode, kRenderTransAlpha ;             set_es es, ES_RenderAmt, floatround(entity_range(id, ent) * 255.0 / SEMICLIP_RADIUS, floatround_floor) ;         }     }     else     {         unregister_forward FM_AddToFullPack, g_iFhAddToFullPackPost, true ;         g_iFhAddToFullPackPost = 0;     } } public ClCmd_Players(id) {     TogglePlayerSeeing(id); #if defined CHATCOLOR     client_print_color(id, Red, "^4[Invis] ^1Players are now %sisible.", IsPlayerSeeing(id) ? "^4V" :"^3Inv"); #else     client_print(id, print_chat, "[Invis] Players are now %sisible.", IsPlayerSeeing(id) ? "V" :"Inv"); #endif }

Connor, it has the same bug I mentioned in my thread, your KZ semiclip fixes that, but it's not a team semiclip... :\

[ConnorMcLeod]

Which one ? doors not opening or prediction making player feel a little block before they pass through each other ?
I haven't worked enough on rendering part, so i guess it is about prediction, if it is about doors, i'm affraid there is nothing i can do.

[Diegorkable]

Originally Posted by ConnorMcLeod Which one ? doors not opening or prediction making player feel a little block before they pass through each other ? I haven't worked enough on rendering part, so i guess it is about prediction, if it is about doors, i'm affraid there is nothing i can do.

It's not about the doors, it's about that you can't really walk into each other, you feel this little block, and even if its a little block, you can't stand in each other, when you go through someone you're getting kicked away up or back or idk where, but yeah, this little block, I gave you a link to my thread! you should have got that.

[ConnorMcLeod]

Made an update, try it as it is without editing nothing, i've just tested with podbots and seems to be fine, hadn't checked previous version though.

[Diegorkable]

Connor, just don't even bother man, sorry but I had the unstuck plugin on my server, that when you get stuck you pop out, so, everytime I went through another players it kicked me back, it wasn't your plugin. It works great now, thanks...

[ConnorMcLeod]

If you have time to test with 2 teamates standing on a rotating entity...

[TeddiBer]

hey connor,
I tried to put your kz semi clip in my surf server, but there are 2 problems:
1. you cant kill each other.
2. when you close to a player, he is almost looks invisible.

So i gut that this plugin is only for kz, but maybe you can add it so it will support games like surf ?
the semiclip should be on for every one, without those problems ^.