[OneMoreLevel]

Is there a way I can make people get money each time they DMG someone? I want to be able to make it so that people get 2 dollars each HP they kill. Like if they hit 30 DMG against someone, they would get 60 dollars

EDIT: Is there a way to hook round start with hamsandwich too?

[alan_el_more]

Try this

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <hamsandwich>

#define PLUGIN "Money DMG"
#define VERSION "1.0"
#define AUTHOR "alan_el_more"

#define DAMAGE 2
#define MONEY 300

new g_maxplayers
new g_damage_done[33]

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    g_maxplayers = get_maxplayers()
    
    RegisterHam(Ham_TakeDamage, "player", "fw_TakeDamage")
}

public fw_TakeDamage(victim, inflictor, attacker, Float:damage, damage_type)
{
    if((1 <= attacker <= g_maxplayers) && attacker != victim)
    {
        g_damage_done[attacker] += floatround(damage)
        
        while(g_damage_done[attacker] >= DAMAGE)
        {
            cs_set_user_money(attacker, cs_get_user_money(attacker) + MONEY)
            g_damage_done[attacker] -= DAMAGE
        }
    }
} 


[OneMoreLevel]

Thanks Ill test it out, so far it compiles, Ill try to test it on my server real quick.

[Exolent[jNr]]

#include < amxmodx >
#include < amxmisc >
#include < cstrike >
#include < engine >
#include < hamsandwich >

const Float:MONEY_PER_HP = 2.0; // $2 / 1HP

new g_iMaxPlayers;

public plugin_init( ) {
    register_plugin( "Damage for Money", "0.0.1", "Exolent" );
    
    RegisterHam( Ham_TakeDamage, "player", "FwdPlayerDamage", 1 );
    
    g_iMaxPlayers = get_maxplayers( );
}

public FwdPlayerDamage( iVictim, iInflictor, iAttacker, Float:fDamage, iDamageBits ) {
    if( !( 1 <= iAttacker <= g_iMaxPlayers ) ) {
        return;
    }
    
    new Float:fRealDamage = entity_get_float( iVictim, EV_FL_dmg_take );
    if( cs_get_user_team( iVictim ) == cs_get_user_team( iAttacker ) ) {
        fRealDamage *= -1.0;
    }
    
    cs_set_user_money( iAttacker, cs_get_user_money( iAttacker ) + floatround( MONEY_PER_HP * fRealDamage ) );
}

[OneMoreLevel]

Thanks guys

I hope you dont mind me asking another quick thing.

How can I play a sound so that everyone in the server can hear it, not just the surrounding area or the client.