[Arkshine]

Hi.

Some suggestions :

- Please, fix your indentation. Either use tabs either spaces, but not both at the same time. The result is a quite a mess now. ^^
- Try to rename 'pcvar', it doesn't hurt to write a name more descriptive.
- Try to keep always {}

As idea, if interested, here a plugin I'm using since a long time ago, I've just fastly optimized the original plugin. ( I think it was an Amx plugin ). It may give you some idea. You will get progressively green to red color depending the damage.

PHP Code:

    
    #include <amxmodx>
    #include <fakemeta>
    #include <hamsandwich>
    
    const MAX_PLAYERS = 32;

    new Float:gMaxHealth [ MAX_PLAYERS + 1 ];
    new bool:gIsConnected[ MAX_PLAYERS + 1 ];

    public plugin_init()
    {
        register_plugin( "Glow When Damaged", "1.0", "A1win" );

        RegisterHam( Ham_Spawn, "player", "Event_PlayerSpawn", 1 );
        register_event( "Damage", "Event_PlayerTakeDamage", "b", "2!0", "3=0", "4!0" );
    }
    
    public client_putinserver( Client )
    {
        gIsConnected[ Client ] = true;
    }
    
    public client_disconnect( Client )
    {   
        gIsConnected[ Client ] = false;
    }

    public Event_PlayerSpawn( const Client ) 
    {
        if ( is_user_alive( Client ) )
        {
            pev( Client, pev_health, gMaxHealth[ Client ] );
            remove_task( Client ); 
            RemoveGlow ( Client );
        }
    }

    public Event_PlayerTakeDamage( const Client )
    {
        if ( gIsConnected[ Client ] )
        {
            static Float:RenderColor[ 3 ];
            static Float:CurrHealth;
            static Float:r;
            static Float:g;
            static Float:Hl;
            
            pev( Client, pev_health, CurrHealth );
            Hl = gMaxHealth[ Client ] * 0.5;
            
            if( CurrHealth == Hl )
            {
                r = 255.0;
                g = 255.0;
            }
            else if( CurrHealth < Hl )
            {
                r = 255.0;
                g = 5.1 * CurrHealth;
            }
            else if( CurrHealth > Hl && CurrHealth != gMaxHealth[ Client ] )
            {
                r = 255.0 - 5.1 * ( CurrHealth - 50 );
                g = 255.0;
            }
            
            RenderColor[ 0 ] = r;
            RenderColor[ 1 ] = g;
            
            UTIL_SetRendering( Client, kRenderFxGlowShell, RenderColor, kRenderNormal, 10.0 );
            
            remove_task( Client );
            set_task( 1.0, "RemoveGlow", Client );
        }

    }

    public RemoveGlow ( const Client )
    {
        if( gIsConnected[ Client ] )
        {    
            UTIL_SetRendering ( Client, kRenderFxNone, Float:{ 0.0, 0.0, 0.0 }, kRenderNormal, 0.0 );
        }
    }
    
    UTIL_SetRendering ( const Client, const RenderFx, const Float:RenderColor[ 3 ], const Render, const Float:Amount )
    {
        set_pev( Client, pev_renderfx   , RenderFx );
        set_pev( Client, pev_rendercolor, RenderColor );
        set_pev( Client, pev_rendermode , Render );
        set_pev( Client, pev_renderamt  , Amount );
    } 


[Starsailor]

updated v1.3 thanks

[Nextra]

Maybe a cvar to switch between glowing in team colors or based on health would be better. You forgot to ident SetRendering properly ;)

[Starsailor]

Originally Posted by Nextra Maybe a cvar to switch between glowing in team colors or based on health would be better. You forgot to ident SetRendering properly ;)

updated, thanks

[eXoDiA]

GJ Starsailor

[Arkshine]

As feature, you can add that only player which do damage will see the glow. Just looking this plugin http://forums.alliedmods.net/showthread.php?t=87845 ; It would be interesting.

[Starsailor]

mm i dont know

the idea of plugin is that everyone knows who is being attacked

[Arkshine]

Ah yeah. Well it was just an idea. But you're right.

[letgoofmyeggs]

hey, im running this plugin with another plugin that makes everyone always glow their team color from this thread.
http://forums.alliedmods.net/showthread.php?t=74052

there is a little bug. when damage is dealt, the person stops glowing their team color. i was wondering if it would be possible to make it so both plugins function properly.

[Starsailor]

i recommend you use this plugin for this

http://forums.alliedmods.net/showthread.php?p=728858