[[kirk]./musick`]

I have made a plugin that adds a bounty to the player, and if the user killed has a bounty of over $1000, that money is given to the killer. I need someone to test it real quick, and take a look at the code. It compiled correctly with no errors at all, and with my one player testing (for worldspawn and suicide), it seems to have worked. But since I don't have more than one player, I can't test if the bounty adding even works! If someone can test it for me, and take a look at the code and give me any suggestions that would be awesome!

Thanks,
Kirk

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

new bounty[32], isHeadShot, bcvar, hcvar
    

public plugin_init() {
    register_plugin("Player Bounty", "1.0", "kirkhalo")
    register_event("DeathMsg", "event_death", "a")
    bcvar = register_cvar("amx_bounty", "400")
    hcvar = register_cvar("amx_hsbounty", "800")
    register_clcmd("say /showbounty", "show_bounty")
    register_clcmd("say showbounty", "show_bounty")
}

public client_connect(id){
    bounty[id] = 0 // Set the client's id bounty to 0
}

public event_death(id){
    new killer_name[32], victim_name[32], 
    new bounty_amount = get_pcvar_num(bcvar)
    new bounty_hsamount = get_pcvar_num(hcvar)
    new killer_id = read_data(1) // Killer id
    new victim_id = read_data(2) // Victim id
    isHeadShot = read_data(3) // Is headshot?
    new weapon_name = read_data(4) // Get the weapon name (used for worldspawn)
    get_user_name(killer_id, killer_name, 31) // Get killer name
    get_user_name(victim_id, victim_name, 31) // Get victim name
    if (!isHeadShot){ // If it isn't a headshot
        if ((killer_id==victim_id)||(weapon_name=="worldspawn")) { // Check for suicide or worldspawn death
        return PLUGIN_HANDLED
    }
    if (bounty[killer_id]>=0){
        bounty[killer_id]+=bounty_amount // Add to bounty amount
        // Print message to every client
        client_print(0, print_chat, "[AMXX] Player %s now has a bounty of $%i", killer_name, bounty[killer_id])
    }
} 
    else {
    if (bounty[killer_id]>=0){
        bounty[killer_id]+=bounty_hsamount // Add hs amount to bounty
        // Print message to all players
        client_print(0, print_chat, "[AMXX] Player %s now has a bounty of $%i", killer_name, bounty[killer_id])
    }
}
    if (bounty[victim_id]>1000){ // If someone kills a player with a bounty higher than 0
        give_bounty(killer_id, victim_id) // Give the user money through function
    }
} // End event_death function
    
public client_disconnect(id){
    bounty[id] = 0    // If client disconnects set his id's bounty to 0
}
    
public give_bounty(kID, vID){
    if (is_user_connected(kID)){
        new kName[32], vName[32]
        get_user_name(kID, kName, 31)
        get_user_name(vID, vName, 31)
        new current_money = cs_get_user_money(kID) + bounty[vID]
        cs_set_user_money(kID, current_money)    
        client_print(0, print_chat, "[AMXX] Player %s has recieved $%i for killing %s", kName, bounty[vID], vName)
        bounty[vID] = 0 // Reset bounty of the dead
    }
    return PLUGIN_HANDLED
}

public show_bounty(id){
    if (bounty[id]>0){
    // Display bounty amount to player
    client_print(id, print_chat, "[AMXX] You currently have a %s bounty on your head.", bounty[id]) 
    } 
    else {     
        // user has no bounty currently 
        client_print(id, print_chat, "[AMXX] You currently don't have a bounty.")
    }
    return PLUGIN_HANDLED
} 


[Exolent[jNr]]

quick code correction:

killer_name[] and victim_name[] dont need to be global
since they are only used in the event_death(), use them locally there.

[[kirk]./musick`]

Thanks a lot, noted.

[ConnorMcLeod]

Have a look at this version

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <cstrike>

#define MAX_PLAYERS    32

new g_iBounty[MAX_PLAYERS+1]

new g_pBounty, g_pHsBounty, g_pEnable
    

public plugin_init() {
    register_plugin("Player Bounty", "1.0", "kirkhalo")

    g_pEnable = register_cvar("amx_bounty_enabled", "1")
    g_pBounty = register_cvar("amx_bounty", "400")
    g_pHsBounty = register_cvar("amx_hsbounty", "800")

    register_event("DeathMsg", "eDeathMsg", "a", "1>0")

    register_clcmd("say /showbounty", "show_bounty")
    register_clcmd("say showbounty", "show_bounty")
}

public client_putinserver(id)
{
    g_iBounty[id] = 0
}

public eDeathMsg()
{
    if(!get_pcvar_num(g_pEnable))
        return

    new iKillerId = read_data(1)
    new iVictimId = read_data(2)

    if( iKillerId == iVictimId )
        return

    if( get_user_team(iKillerId) == get_user_team(iVictimId) )
        return

    new iBountyAmount = get_pcvar_num(read_data(3) ? g_pHsBounty : g_pBounty)

    new szKillerName[32]
    get_user_name(iKillerId, szKillerName, 31)

    g_iBounty[iKillerId] += iBountyAmount
    client_print(0, print_chat, "[AMXX] Player %s now has a bounty of $%i", szKillerName, g_iBounty[iKillerId])

    if(g_iBounty[iVictimId] >= 1000 && is_user_connected(iKillerId))
    {
        new szVictimName[32]
        get_user_name(iVictimId, szVictimName, 31)
        cs_set_user_money(iKillerId, cs_get_user_money(iKillerId) + g_iBounty[iVictimId])
        client_print(0, print_chat, "[AMXX] Player %s has recieved $%i for killing %s", szKillerName, g_iBounty[iVictimId], szVictimName)
        g_iBounty[iVictimId] = 0
    }
}

public show_bounty(id){
    if(g_iBounty[id]>0)
    {
        client_print(id, print_chat, "[AMXX] You currently have a $%i bounty on your head.", g_iBounty[id]) 
    } 
    else
    {     
        client_print(id, print_chat, "[AMXX] You currently don't have a bounty.")
    }
    return PLUGIN_HANDLED
} 


[[kirk]./musick`]

Very nice, I had some ideas of publishing this, since there isn't a plugin that is like it. I don't want to use your code, but I'll be sure to make more compact and concise code. Only if you think I should though.

[Arkshine]

You should'nt. Don't rush to release some plugins. You should learn more to be able to support your plugin. For the moment, you can't.

Here what I've done for his request.: http://forums.alliedmods.net/showthr...337#post577337

I don't think it's a good idea to display all players. If there are severals bounty players it will flood chat...

[[kirk]./musick`]

Sounds good, thanks.

Just a quick question, what does the 'MSG_ONE' message look like on the receivers end? Is it in the normal chat area but obviously without a players name or anything?

-Kirk

[Arkshine]

I'm not sure to understand well. ( Sorry I'm french and my english is very poor ).

You're talking about PrintMessage() function ?

If so, using SayText event allows you to display message with color. ( ^4 : green, ^3 : team color, ^1 : normal color (yellow) )

If not, can you rephraze please ?

[pharse]

I think he meant if it is in the normal chat area like
pharse: [AMXX]You currently have...
or without playername:
[AMXX]You currently have...

I think it is the latter.

[[kirk]./musick`]

Yeah I'm asking about this snippet here:

PHP Code:

    PrintMessage( id, const s_Message[] )
    {
        message_begin( MSG_ONE, g_iMsg_SayText, _, id );
        write_byte( id );
        write_string( s_Message );
        message_end();
    } 


What I was asking was where exactly that message would appear? In the normal chat area (bottom left), or somewhere else?