Raised This Month: $ Target: $400
 0% 

always write reason for kick/ban


Post New Thread Reply   
 
Thread Tools Display Modes
Author Message
hoboman
Senior Member
Join Date: Jul 2007
Old 09-16-2007 , 17:55   always write reason for kick/ban
Reply With Quote #1

I am trying to edit the admincmd.sma so when the admins on my server kick or ban someone they always have to provide a reason for kicking or banning.

I just want to add something like...
if ( reason.length() < 5 )
*tell the admin that the reason must be greater than 5 characters*
return PLUGIN_HANDLED

under....
read_argv(2, reason, 31)
//both the kick and ban function has it. i am guessing it is the part that gets the reason string and assigns it to the variable "reason".


but i am not sure of the syntax for this pawn language


kick:
Code:
public cmdKick(id, level, cid)
{
    if (!cmd_access(id, level, cid, 2))
        return PLUGIN_HANDLED

    new arg[32]
    read_argv(1, arg, 31)
    new player = cmd_target(id, arg, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF)
    
    if (!player)
        return PLUGIN_HANDLED
    
    new authid[32], authid2[32], name2[32], name[32], userid2, reason[32]
    
    get_user_authid(id, authid, 31)
    get_user_authid(player, authid2, 31)
    get_user_name(player, name2, 31)
    get_user_name(id, name, 31)
    userid2 = get_user_userid(player)
    read_argv(2, reason, 31)
    remove_quotes(reason)
    
    log_amx("Kick: ^"%s<%d><%s><>^" kick ^"%s<%d><%s><>^" (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, reason)

    show_activity_key("ADMIN_KICK_1", "ADMIN_KICK_2", name, name2);

    if (is_user_bot(player))
        server_cmd("kick #%d", userid2)
    else
    {
        if (reason[0])
            server_cmd("kick #%d ^"%s^"", userid2, reason)
        else
            server_cmd("kick #%d", userid2)
    }
    
    console_print(id, "[AMXX] Client ^"%s^" kicked", name2)
    
    return PLUGIN_HANDLED
}
ban:
Code:
public cmdBan(id, level, cid)
{
    if (!cmd_access(id, level, cid, 3))
        return PLUGIN_HANDLED

    new target[32], minutes[8], reason[64]
    
    read_argv(1, target, 31)
    read_argv(2, minutes, 7)
    read_argv(3, reason, 63)
    
    new player = cmd_target(id, target, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_NO_BOTS | CMDTARGET_ALLOW_SELF)
    
    if (!player)
        return PLUGIN_HANDLED

    new authid[32], name2[32], authid2[32], name[32]
    new userid2 = get_user_userid(player)

    get_user_authid(player, authid2, 31)
    get_user_authid(id, authid, 31)
    get_user_name(player, name2, 31)
    get_user_name(id, name, 31)
    
    log_amx("Ban: ^"%s<%d><%s><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%s^") (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, minutes, reason)
    
    new temp[64], banned[16], nNum = str_to_num(minutes)
    if (nNum)
        format(temp, 63, "%L", player, "FOR_MIN", minutes)
    else
        format(temp, 63, "%L", player, "PERM")

    format(banned, 15, "%L", player, "BANNED")

    if (reason[0])
        server_cmd("kick #%d ^"%s (%s %s)^";wait;banid ^"%s^" ^"%s^";wait;writeid", userid2, reason, banned, temp, minutes, authid2)
    else
        server_cmd("kick #%d ^"%s %s^";wait;banid ^"%s^" ^"%s^";wait;writeid", userid2, banned, temp, minutes, authid2)

    
    // Display the message to all clients

    new msg[256];
    new len;
    new maxpl = get_maxplayers();
    for (new i = 1; i <= maxpl; i++)
    {
        if (is_user_connected(i) && !is_user_bot(i))
        {
            len = formatex(msg, charsmax(msg), "%L", i, "BAN");
            len += formatex(msg[len], charsmax(msg) - len, " %s ", name2);
            if (nNum)
            {
                formatex(msg[len], charsmax(msg) - len, "%L", i, "FOR_MIN", minutes);
            }
            else
            {
                formatex(msg[len], charsmax(msg) - len, "%L", i, "PERM");
            }
            if (strlen(reason) > 0)
            {
                formatex(msg[len], charsmax(msg) - len, " (%L: %s)", i, "REASON", reason);
            }
            show_activity_id(i, id, name, msg);
        }
    }
    
    console_print(id, "[AMXX] %L", id, "CLIENT_BANNED", name2)
    
    return PLUGIN_HANDLED
}

Last edited by hoboman; 09-17-2007 at 01:49.
hoboman is offline
hoboman
Senior Member
Join Date: Jul 2007
Old 09-18-2007 , 22:31   Re: always write reason for kick/ban
Reply With Quote #2

zzzz
*bump*?

i don't think this is a terribly hard question...ppllsss
hoboman is offline
sawce
The null pointer exception error and virtual machine bug
Join Date: Oct 2004
Old 09-18-2007 , 23:20   Re: always write reason for kick/ban
Reply With Quote #3

kick:
Code:
public cmdKick(id, level, cid)
{
    if (!cmd_access(id, level, cid, 2))
        return PLUGIN_HANDLED

    new arg[32]
    read_argv(1, arg, 31)
    new player = cmd_target(id, arg, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_ALLOW_SELF)
    
    if (!player)
        return PLUGIN_HANDLED
    
    new authid[32], authid2[32], name2[32], name[32], userid2, reason[32]
    
    get_user_authid(id, authid, 31)
    get_user_authid(player, authid2, 31)
    get_user_name(player, name2, 31)
    get_user_name(id, name, 31)
    userid2 = get_user_userid(player)
    read_argv(2, reason, 31)
    remove_quotes(reason)

    if (strlen(reason) < 5)
    {
        console_print(id, "[AMXX] Your reason needs to be at least 5 letters long!");
        return PLUGIN_HANDLED;
    }

    log_amx("Kick: ^"%s<%d><%s><>^" kick ^"%s<%d><%s><>^" (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, reason)

    show_activity_key("ADMIN_KICK_1", "ADMIN_KICK_2", name, name2);

    if (is_user_bot(player))
        server_cmd("kick #%d", userid2)
    else
    {
        if (reason[0])
            server_cmd("kick #%d ^"%s^"", userid2, reason)
        else
            server_cmd("kick #%d", userid2)
    }
    
    console_print(id, "[AMXX] Client ^"%s^" kicked", name2)
    
    return PLUGIN_HANDLED
}
ban:
Code:
public cmdBan(id, level, cid)
{
    if (!cmd_access(id, level, cid, 3))
        return PLUGIN_HANDLED

    new target[32], minutes[8], reason[64]
    
    read_argv(1, target, 31)
    read_argv(2, minutes, 7)
    read_argv(3, reason, 63)
    
    if (strlen(reason) < 5)
    {
        console_print(id, "[AMXX] Your reason needs to be at least 5 letters long!");
        return PLUGIN_HANDLED;
    }

    new player = cmd_target(id, target, CMDTARGET_OBEY_IMMUNITY | CMDTARGET_NO_BOTS | CMDTARGET_ALLOW_SELF)
    
    if (!player)
        return PLUGIN_HANDLED

    new authid[32], name2[32], authid2[32], name[32]
    new userid2 = get_user_userid(player)

    get_user_authid(player, authid2, 31)
    get_user_authid(id, authid, 31)
    get_user_name(player, name2, 31)
    get_user_name(id, name, 31)
    
    log_amx("Ban: ^"%s<%d><%s><>^" ban and kick ^"%s<%d><%s><>^" (minutes ^"%s^") (reason ^"%s^")", name, get_user_userid(id), authid, name2, userid2, authid2, minutes, reason)
    
    new temp[64], banned[16], nNum = str_to_num(minutes)
    if (nNum)
        format(temp, 63, "%L", player, "FOR_MIN", minutes)
    else
        format(temp, 63, "%L", player, "PERM")

    format(banned, 15, "%L", player, "BANNED")

    if (reason[0])
        server_cmd("kick #%d ^"%s (%s %s)^";wait;banid ^"%s^" ^"%s^";wait;writeid", userid2, reason, banned, temp, minutes, authid2)
    else
        server_cmd("kick #%d ^"%s %s^";wait;banid ^"%s^" ^"%s^";wait;writeid", userid2, banned, temp, minutes, authid2)

    
    // Display the message to all clients

    new msg[256];
    new len;
    new maxpl = get_maxplayers();
    for (new i = 1; i <= maxpl; i++)
    {
        if (is_user_connected(i) && !is_user_bot(i))
        {
            len = formatex(msg, charsmax(msg), "%L", i, "BAN");
            len += formatex(msg[len], charsmax(msg) - len, " %s ", name2);
            if (nNum)
            {
                formatex(msg[len], charsmax(msg) - len, "%L", i, "FOR_MIN", minutes);
            }
            else
            {
                formatex(msg[len], charsmax(msg) - len, "%L", i, "PERM");
            }
            if (strlen(reason) > 0)
            {
                formatex(msg[len], charsmax(msg) - len, " (%L: %s)", i, "REASON", reason);
            }
            show_activity_id(i, id, name, msg);
        }
    }
    
    console_print(id, "[AMXX] %L", id, "CLIENT_BANNED", name2)
    
    return PLUGIN_HANDLED
}
__________________
fyren sucks
sawce is offline
Reply



Posting Rules
You may not post new threads
You may not post replies
You may not post attachments
You may not edit your posts

BB code is On
Smilies are On
[IMG] code is On
HTML code is Off

Forum Jump


All times are GMT -4. The time now is 16:12.


Powered by vBulletin®
Copyright ©2000 - 2024, vBulletin Solutions, Inc.
Theme made by Freecode