[bullet28]

No cvars.

[SkiPlix]

Can you add a config to easily change the model of the ammo can, and maybe the position of the model itself?

[bullet28]

Originally Posted by SkiPlix Can you add a config to easily change the model of the ammo can, and maybe the position of the model itself?

I left the names of models on line 16 especially for such cases, you can easily replace it.
Also, if you don't like position try to change values on lines 45-46 and 47-48 in source code.
I'm not going to do position offset as a ConVar because it makes no sense to me.

[Shao]

Another great plugin from you, keep it up!

It pairs will with Gun Control from Atomic Stryker, although if I may recommend. Perhaps it would be a good thing to allow more special ammo mags within this plugin rather than having to be forced using Gun Control, or have a version without it.

[NoroHime]

modify version, make ammo pile can use once time only

PHP Code:

#pragma semicolon 1
#include <sourcemod>
#include <sdkhooks>
#include <sdktools>
#pragma newdecls required

public Plugin myinfo =
{
    name = "Upgrade Packs with Ammo (Once Time)",
    author = "bullet28, NoroHime",
    description = "Creates ammo pile at the place where the upgrade pack was deployed",
    version = "1",
    url = "https://forums.alliedmods.net/showthread.php?p=2691806"
}

#define MODEL_AMMO "models/props_unique/spawn_apartment/coffeeammo.mdl" // another model variants: "models/props/terror/ammo_stack.mdl" "models/props/de_prodigy/ammo_can_02.mdl"

public void OnMapStart() {
    if (!IsModelPrecached(MODEL_AMMO)) {
        PrecacheModel(MODEL_AMMO);
    }
}

public void OnEntityCreated(int entity, const char[] classname) {
    if (StrContains(classname, "upgrade_ammo_") != -1)
        SDKHook(entity, SDKHook_SpawnPost, OnPostUpgradeSpawn);
}

public void OnPostUpgradeSpawn(int entity) {
    if (!IsValidEntity(entity)) return;

    char classname[32];
    GetEdictClassname(entity, classname, sizeof(classname));
    if (StrContains(classname, "upgrade_ammo_") == -1) return;

    int ammoStack = CreateEntityByName("weapon_ammo_spawn");
    if (ammoStack <= 0) return;

    float origin[3];
    GetEntPropVector(entity, Prop_Send, "m_vecOrigin", origin);
    
    origin[0] -= 10.0;
    origin[1] -= 10.0;
    TeleportEntity(entity, origin, NULL_VECTOR, NULL_VECTOR);

    origin[0] += 20.0;
    origin[1] += 20.0;
    TeleportEntity(ammoStack, origin, NULL_VECTOR, NULL_VECTOR);

    SetEntityModel(ammoStack, MODEL_AMMO);
    DispatchSpawn(ammoStack);
    SDKHook(ammoStack, SDKHook_UsePost, OnUsePost);
}

void OnUsePost(int entity, int activator, int caller, UseType type, float value) {
    /*if (GetRandomFloat() > 0.5) //if you want has chance to clear, lower mean high chance
        return;*/
    SDKUnhook(entity, SDKHook_UsePost, OnUsePost);
    SetVariantString("OnUser1 !self:Kill::0:-1");
    AcceptEntityInput(entity, "AddOutput");
    AcceptEntityInput(entity, "FireUser1");
} 


[BioHazardN7]

Originally Posted by NoroHime modify version, make ammo pile can use once time only

It's perfect!

Can you make it so that all players on the server can take ammunition once, including servers with 5+ players? Please!

[Silvers]

Originally Posted by NoroHime modify version, make ammo pile can use once time only

Please don't use StrContains in OnEntityCreated or other functions that are called often, what you want is strncmp to compare that first set of characters. StrContains will check every position of the string, it's not efficient for this purpose. You should really only use StrContains when you need to check for something within a string and you can't guarantee it's position. For the rest use strcmp or strncmp.

There's no need to check the classname in OnPostUpgradeSpawn.

The AcceptEntityInput kill part can be replaced with RemoveEntity() since you're removing it instantly without any delay. And also no need for SDKUnhook since you're removing it.

[BloodyBlade]

Originally Posted by Silvers Please don't use StrContains in OnEntityCreated or other functions that are called often, what you want is strncmp to compare that first set of characters. StrContains will check every position of the string, it's not efficient for this purpose. You should really only use StrContains when you need to check for something within a string and you can't guarantee it's position. For the rest use strcmp or strncmp. There's no need to check the classname in OnPostUpgradeSpawn. The AcceptEntityInput kill part can be replaced with RemoveEntity() since you're removing it instantly without any delay. And also no need for SDKUnhook since you're removing it.

This?

#pragma semicolon 1
#pragma newdecls required
#include <sourcemod>
#include <sdkhooks>
#include <sdktools>

public Plugin myinfo =
{
    name = "Upgrade Packs with Ammo (Once Time)",
    author = "bullet28, NoroHime",
    description = "Creates ammo pile at the place where the upgrade pack was deployed",
    version = "1",
    url = "https://forums.alliedmods.net/showthread.php?p=2691806"
}

#define MODEL_AMMO "models/props_unique/spawn_apartment/coffeeammo.mdl" // another model variants: "models/props/terror/ammo_stack.mdl" "models/props/de_prodigy/ammo_can_02.mdl"

public void OnMapStart()
{
    if (!IsModelPrecached(MODEL_AMMO))
    {
        PrecacheModel(MODEL_AMMO);
    }
}

public void OnEntityCreated(int entity, const char[] classname)
{
    if (strcmp(classname, "upgrade_ammo_") != -1)
    {
        SDKHook(entity, SDKHook_SpawnPost, OnPostUpgradeSpawn);
    }
}

public void OnPostUpgradeSpawn(int entity)
{
    if (IsValidEntity(entity))
    {
        int ammoStack = CreateEntityByName("weapon_ammo_spawn");
        if (ammoStack > 0)
        {
            float origin[3];
            GetEntPropVector(entity, Prop_Send, "m_vecOrigin", origin);
            
            origin[0] -= 10.0;
            origin[1] -= 10.0;
            TeleportEntity(entity, origin, NULL_VECTOR, NULL_VECTOR);
        
            origin[0] += 20.0;
            origin[1] += 20.0;
            TeleportEntity(ammoStack, origin, NULL_VECTOR, NULL_VECTOR);
        
            SetEntityModel(ammoStack, MODEL_AMMO);
            DispatchSpawn(ammoStack);
            SDKHook(ammoStack, SDKHook_UsePost, OnUsePost);
        }
    }
}

void OnUsePost(int entity, int activator, int caller, UseType type, float value)
{
    RemoveEntity(entity);
}