[Flex1z]

Hello, I'm using this plugin but it does not work.
On round 28 nothing shows up and no errors. Can someone pls help

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <sdkhooks>
#include <cstrike>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart() 
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_Post);
    RegConsoleCmd("test_command", Command_Test);
}


public Action Command_Test(int client, int args)
{ 
    DoVoteMenu();
}

public Action Event_RoundStart(Event evEvent, const char[] szName, bool bDontBroadcast)
{
    int CurrentRoundNum = GetTeamScore(CS_TEAM_T) + GetTeamScore(CS_TEAM_CT);
    
    if(CurrentRoundNum % 28 != 0) {
        return;
    }
    
    
    PrintToChatAll("Round %d Test message.", CurrentRoundNum);
}  



public int Handle_VoteMenu(Menu menu, MenuAction action, int param1, int param2)
{
    char buffer[64], display[64];
    menu.GetItem(param1, buffer, sizeof(buffer), _, display, sizeof(display));

    if (action == MenuAction_End)
    {
        delete menu;
    } 
    else if (action == MenuAction_VoteEnd) 
    {
        if (param1 == 0)
        {
            //menu.GetItem(param1);
            ServerCommand("mp_overtime_enable 1");
        }
    }
}

 
void DoVoteMenu()
{
    if (IsVoteInProgress())
    {
        return;
    }
 
    Menu menu = new Menu(Handle_VoteMenu);
    menu.SetTitle("Should there be an overtime?");
    menu.AddItem("yes", "Yes");
    menu.AddItem("no", "No");
    menu.ExitButton = false;
    menu.DisplayVoteToAll(20);
} 


[Rugal]

But why do you need a plugin to run an Overtime ?, most PUG 5x5 plugins already include this in the configuration.

[Flex1z]

I run a community competitive server where I want to give users the option to have overtime or not.
The plugin unfortunately does not work. Do you maybe know why or possibly have a working one?

[Rugal]

Originally Posted by Flex1z I run a community competitive server where I want to give users the option to have overtime or not. The plugin unfortunately does not work. Do you maybe know why or possibly have a working one?

The Warmod BFG plugin already has this feature included, if players want to play OverTime, just use !ot to activate the feature. If
no one types this, the game will end in a draw, as well as the standard competitive valve. And no, I don't know of an overtime plugin, why doesn't it make sense to have one if it already comes with competitive plugins.

[Flex1z]

But that's not the point of the plugin at all. I'm trying to let the players vote for overtime when round 28 starts with the menu. If that works get more then 50% yes to have overtime otherwise a draw. With just typing !OT you instantly active overtime which I'm not trying to achieve.

[SSheriFF]

Originally Posted by Flex1z But that's not the point of the plugin at all. I'm trying to let the players vote for overtime when round 28 starts with the menu. If that works get more then 50% yes to have overtime otherwise a draw. With just typing !OT you instantly active overtime which I'm not trying to achieve.

Try that

PHP Code:

#include <sourcemod>
#include <sdktools>
#include <cstrike>

#pragma semicolon 1
#pragma newdecls required

public void OnPluginStart() 
{
    HookEvent("round_start", Event_RoundStart, EventHookMode_Post);
}

public Action Event_RoundStart(Event evEvent, const char[] szName, bool bDontBroadcast)
{
    int CurrentRoundNum = GetTeamScore(CS_TEAM_T) + GetTeamScore(CS_TEAM_CT);
    
    if(CurrentRoundNum == 28) {
        DoVoteMenu();
    }   
}  

public int Handle_VoteMenu(Menu menu, MenuAction action, int param1, int param2)
{
    if (action == MenuAction_End)
        delete menu;
}

 public void VoteResultCallback(Menu menu, int num_votes, int num_clients, const int[][] client_info, int num_items, const int[][] item_info)
{
    char item[16];
    menu.GetItem(item_info[0][VOTEINFO_ITEM_INDEX], item, sizeof(item)); 
    if (StrEqual(item, "yes", false))
    {
        ServerCommand("mp_overtime_enable 1");
    }
}

void DoVoteMenu()
{
    if (IsVoteInProgress())
    {
        return;
    }
    Menu menu = new Menu(Handle_VoteMenu);
    menu.VoteResultCallback = VoteResultCallback;
    menu.SetTitle("Should there be an overtime?");
    menu.AddItem("yes", "Yes");
    menu.AddItem("no", "No");
    menu.ExitButton = false;
    menu.DisplayVoteToAll(20);
} 


[Flex1z]

Thank you, this works perfectly!
I have one question. Is it possible to let most votes count. So if 3 people do yes and 2 people do no it will go into overtime.

[azalty]

Originally Posted by Flex1z Thank you, this works perfectly! I have one question. Is it possible to let most votes count. So if 3 people do yes and 2 people do no it will go into overtime.

That should already be the case. It might NOT be the case if there is 50% yes and 50% no, not sure if the first menu item takes the priority in this case or if it is the first one to get to 50%.

If no overtime occurs after a tie, just change (at line 32):

if (StrEqual(item, "yes", false))

to

if (StrEqual(item, "yes", false) || (item_info[0][VOTEINFO_ITEM_VOTES] == item_info[1][VOTEINFO_ITEM_VOTES]))

[Flex1z]

Oh thanks! Is there a way to check that specificaly? For example when the voting is done it says like X% voted yes for overtime in chat.

[azalty]

Does it not already says that?

You can try to add:

int percentage = RoundToNearest((float(item_info[0][VOTEINFO_ITEM_VOTES]) / float(num_votes)) * 100);
PrintToChatAll("Vote passed! %i%% voted yes.", percentage);

not tested, but should work