[Rafa10]

Hello, can anyone tell me how to disable the kick through the menu? So only admins can manage. Thanks for any help.

[freak.exe_uLow]

Originally Posted by Rafa10 Hello, can anyone tell me how to disable the kick through the menu? So only admins can manage. Thanks for any help.

you mean via ESC Menu? change sv_allow_votes "1" in your server.cfg or gamemode file to "0"

[dustinandband]

PHP Code:

#pragma semicolon 1
#pragma newdecls required
 
//Sourcemod Includes
#include <sourcemod>

public Plugin myinfo =
{
    name = "[L4D2] block kick votes",
    author = "",
    description = "",
    version = "1.0.0",
    url = ""
};

public void OnPluginStart()
{
    AddCommandListener(Listener_CallVote, "callvote");
}

public Action Listener_CallVote(int client, const char[] command, int argc)
{
    char sIssue[64];
    GetCmdArg(1, sIssue, sizeof(sIssue));
    
    if (StrEqual(sIssue, "kick", false) && !isValidAdmin(client))
    {
        PrintToChat(client, "[SM] kick votes blocked.");
        return Plugin_Handled;
        
    }
    
    return Plugin_Continue;
}

public bool isValidAdmin(int client)
{
    return 0 < client <= MaxClients && GetUserAdmin(client) != INVALID_ADMIN_ID;
}