[TrullSin]

Hi, can someone make me a plugin that blocks team change when you are alive, you can only change when you are alive and give message in chat if you try to move when alive.

[dustinandband]

What Game is it? Does this work?

PHP Code:

#include <sourcemod>

public Plugin:myinfo =
{
    name = "block team change",
    author = "dustin",
    description = "blocks team change command when players are alive",
    version = "1.0",
    url = "",
};

public OnPluginStart()
{
    AddCommandListener(CommandJoinTeam, "jointeam");
}

public Action CommandJoinTeam(client, const char[] command, args)
{
    if (IsPlayerAlive(client))
    {
        ReplyToCommand(client, "You Can't Use this command while alive.")
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


[Ilusion9]

Originally Posted by dustinandband What Game is it? Does this work? PHP Code: #include <sourcemod> public Plugin:myinfo = {     name = "block team change",     author = "dustin",     description = "blocks team change command when players are alive",     version = "1.0",     url = "", }; public OnPluginStart() {     AddCommandListener(CommandJoinTeam, "jointeam"); } public Action CommandJoinTeam(client, const char[] command, args) {     if (IsPlayerAlive(client))     {         ReplyToCommand(client, "You Can't Use this command while alive.")         return Plugin_Handled;     }          return Plugin_Continue; }

You should check first if the client != 0 and if the client is in game.

[TrullSin]

It is for CS:GO

[Ilusion9]

PHP Code:


#include <sourcemod> 

public Plugin:myinfo = 
{ 
    name = "block team change", 
    author = "dustin", 
    description = "blocks team change command when players are alive", 
    version = "1.0", 
    url = "", 
}; 

public OnPluginStart() 
{ 
    AddCommandListener(CommandJoinTeam, "jointeam"); 
} 

public Action CommandJoinTeam(client, const char[] command, args) 
{ 
    if (client)
    {
        if (IsClientInGame(client))
        {
            if (IsPlayerAlive(client)) 
            { 
                ReplyToCommand(client, "You cannot use this command while alive.") 
                return Plugin_Handled; 
            } 
        }
    }

    return Plugin_Continue; 
} 


[potatoz]

Both of these codes use a messy mix of old and new syntax and has uncompleted code (";") They do however have the basis down, try this;

PHP Code:

#include <sourcemod>
#pragma semicolon 1

#define VERSION "1.0"

public Plugin:myinfo =
{
    name = "block team change",
    author = "potatoz",
    description = "blocks team changes whilst client is alive",
    version = VERSION,
    url = ""
};

public OnPluginStart()
{
    AddCommandListener(Command_JoinTeam, "jointeam");    
}

public Action Command_JoinTeam(int client, char[] command, int args)
{
    if(!client || !IsClientInGame(client) || IsFakeClient(client))
        return Plugin_Continue;
        
    if(IsPlayerAlive(client))
    {
        ReplyToCommand(client, " \x07You may not switch team whilst alive")  
        return Plugin_Handled;  
    }
    
    return Plugin_Continue;
} 


[Ilusion9]

He can fix some ';', and that ',' at the end of the url (i just copied it).
Also why you check if the client is fake? Lets talk about basis.

[xines]

Originally Posted by potatoz Both of these codes use a messy mix of old and new syntax and has uncompleted code (";") They do however have the basis down

ironically that your edit still had missing parts of transitional syntax , so here:

PHP Code:

#include <sourcemod>

#pragma newdecls required //Force (basics) of Transitional Syntax

public Plugin myinfo =
{
    name = "block team change",
    author = "potatoz",
    description = "blocks team changes whilst client is alive",
    version = "1.0",
    url = ""
};

public void OnPluginStart()
{
    AddCommandListener(Command_JoinTeam, "jointeam");
}

public Action Command_JoinTeam(int client, char[] command, int args)
{
    if(1 <= client <= MaxClients && IsClientInGame(client) && IsPlayerAlive(client))
    {
        ReplyToCommand(client, " \x07You may not switch team whilst alive");
        return Plugin_Handled;
    }
    
    return Plugin_Continue;
} 


[Ilusion9]

Originally Posted by xines ironically that your edit still had missing parts of transitional syntax , so here:

what edit?

[xines]

Originally Posted by Ilusion9 what edit?

potatoz "script" is a edit of the first script posted, as it's not entirely equal to either your edit or the first base script post...