[SoulSharD]

Hello,

I've started on some of my own mapping projects for Source, some of the functionality of these maps require SourceMod to trigger map entities, all of which is already possible to an extent.
SourceMod cannot trigger any non-networkable entities, these would be: logic_relay, logic_timer, etc...

Previously I've been using this plugin to enable use of ent_fire. This works perfectly, but has a few complications. (Resetting cvars, rcon access)

So here I am, sharing two things: a snippet and an example plugin.

PHP Code:

FireEntityInput(const String:strTargetname[], const String:strInput[], const String:strParameter[]="", const Float:flDelay=0.0)
{
    decl String:strBuffer[255];
    Format(strBuffer, sizeof(strBuffer), "OnUser1 %s:%s:%s:%f:1", strTargetname, strInput, strParameter, flDelay);
    
    new entity = CreateEntityByName("info_target"); // Dummy entity. (Pretty sure every Source game has this.)
    if(IsValidEdict(entity))
    {
        DispatchSpawn(entity);
        ActivateEntity(entity);
    
        SetVariantString(strBuffer);
        AcceptEntityInput(entity, "AddOutput");
        AcceptEntityInput(entity, "FireUser1");
        
        CreateTimer(0.0, DeleteEdict, entity); // Remove on next frame.
        return true;
    }
    return false;
}

public Action:DeleteEdict(Handle:timer, any:entity)
{
    if(IsValidEdict(entity)) RemoveEdict(entity);
    return Plugin_Stop;
} 


This function works by creating a dummy entity, and making it fire any input specified. The dummy entity is quickly removed afterwards.
Specifying a classname would trigger all entities with that classname. Non-networkable entities work too!

As for the plugin:
Usage: sm_entfire - Same functionality as ent_fire.

Enjoy!

[DeathChaos25]

Ok, so, in L4D2, music is a client sided only entity, meaning it is not networked, would this in theory mean that if we know when a music starts we can, for example, cancel it?

[SoulSharD]

Originally Posted by DeathChaos25 Ok, so, in L4D2, music is a client sided only entity, meaning it is not networked, would this in theory mean that if we know when a music starts we can, for example, cancel it?

Correct.
Although you'll need to know the name of the entity that's playing the music.

[Dr. Greg House]

Please use:
RequestFrame
EntRefs
Kill, instead of RemoveEdict

Since you're already using outputs, just add the kill input to that.

[Chdata]

PHP Code:

/**
 * Activates an entity (CBaseAnimating::Activate)
 *
 * @param entity        Entity index.
 * @noreturn
 * @error                Invalid entity or lack of mod support.
 */
native ActivateEntity(entity); 


Why do we need the info_target to animate?

Here's 2 old stocks I have and a rewrite of your thing.

PHP Code:

stock KillEntityIn(iEnt, Float:flSeconds)
{
    decl String:szAddOutput[32];
    Format(szAddOutput, sizeof(szAddOutput), "OnUser1 !self,Kill,,%0.2f,1", flSeconds);
    SetVariantString(szAddOutput);
    AcceptEntityInput(iEnt, "AddOutput");
    AcceptEntityInput(iEnt, "FireUser1");
}

/*
    Fire entity input on an entity after a certain delay
*/
stock DelayEntityInput(iEnt, const String:szInput[], const Float:flSeconds, const String:szVariant[] = "")
{
    decl String:szAddOutput[128];
    Format(szAddOutput, sizeof(szAddOutput), "OnUser1 !self,%s,%s,%0.2f,1", szInput, szVariant, flSeconds);
    SetVariantString(szAddOutput);
    AcceptEntityInput(iEnt, "AddOutput");
    AcceptEntityInput(iEnt, "FireUser1");
}

stock FireEntityInput(const String:szTargetname[], const String:szInput[], const String:szParam[]="", const Float:flDelay=0.0)
{
    decl String:szBuffer[255];
    Format(szBuffer, sizeof(szBuffer), "OnUser1 %s:%s:%s:%0.2f:1", szTargetname, szInput, szParam, flDelay);

    static iSaveEnt = EntIndexToEntRef(SpawnEntityByName("info_target"));
    
    new iEnt = EntRefToEntIndex(iSaveEnt); // Dummy entity. (Pretty sure every Source game has this.)
    if (iEnt == -1 || !IsValidEntity(iEnt))
    {
        iSaveEnt = EntIndexToEntRef(SpawnEntityByName("info_target"));

        iEnt = EntRefToEntIndex(iSaveEnt);
        if (iEnt == -1 || !IsValidEntity(iEnt))
        {
            return false; // Failed to recreate dummy entity
        }
    }
    
    SetVariantString(szBuffer);
    AcceptEntityInput(iEnt, "AddOutput");
    AcceptEntityInput(iEnt, "FireUser1");

    //AcceptEntityInput(iEnt, "Kill");
    
    return true;
}

stock SpawnEntityByName(const String:szClassname[], iForceEdictIndex = -1)
{
    new iEnt = CreateEntityByName(szClassname, iForceEdictIndex);
    if (iEnt != -1)
    {
        DispatchSpawn(iEnt);
        // ActivateEntity(iEnt);
    }
    return iEnt;
} 


[SoulSharD]

Pfft, I'm still learning.

[Drixevel]

FireEntityInput(char[] strTargetname, char[] strInput, char[] strParameter = "", float flDelay = 0.0)
{
	char[256] strBuffer;
	Format(strBuffer, sizeof(strBuffer), "OnUser1 %s:%s:%s:%f:1", strTargetname, strInput, strParameter, flDelay);
	
	int entity = CreateEntityByName("info_target"); // Dummy entity. (Pretty sure every Source game has this.)

	if (IsValidEntity(entity))
	{
		DispatchSpawn(entity);
		ActivateEntity(entity);
		
		SetVariantString(strBuffer);
		AcceptEntityInput(entity, "AddOutput");
		AcceptEntityInput(entity, "FireUser1");
		
		RequestFrame(DeleteEntity, EntIndexToEntRef(entity)); // Remove on next frame.
		return true;
	}
	
	return false;
}

public void DeleteEntity(any data)
{
	int entity = EntRefToEntIndex(data);
	
	if (IsValidEntity(entity))
	{
		RemoveEdict(entity);
	}
}