[Runjaun]

When someone get kill by knife . Play a troll sound

[zmd94]

New update based on Flick3rR suggestion!

Feel free to test it again. ;)

PHP Code:

#include <amxmodx>

#define CustomSound "misc/YourSoundName.wav"

public plugin_init()
{
    register_plugin("Custom Sound", "1.0", "zmd94")
    
    register_event("DeathMsg", "event_DeathMsg", "a", "1>0")
}

public plugin_precache() 
{
    precache_sound(CustomSound)
}

public event_DeathMsg()
{
    static iKiller; iKiller = read_data(1)
    static iVictim; iVictim = read_data(2)
    
    if(!is_user_alive(iKiller) && iVictim == iKiller)
        return PLUGIN_CONTINUE
    
    new iWeapon[32]
    read_data( 4, iWeapon, charsmax(iWeapon))
    
    if(equali(iWeapon, "knife"))
    {
        client_cmd(iVictim, "spk %s", CustomSound)
    }
    
    return PLUGIN_CONTINUE
} 


Just change the "YourSoundName.wav" with your sound. Then, put the sound in the misc folder.

;)

[Krtola]

will be tested (I also thinking about this)

[zmd94]

Feel free to inform me the output. ;)

[Runjaun]

When i cut someone .. it is not playing sound .. but people was downloading the sound and didn't play

[zmd94]

Runjaun, do you get any errors?

And what type of sound that you use (.wav/ .mp3)?

[Flick3rR]

Better use DeathMsg and read_data(4, sz, charsmax(sz)), because in that way, the grenade kill will also play the sound if the killer has switched to knife. Also, you better put that *.wav to misc folder (where it should be).

[zmd94]

You are right, Flick3rR. I appreciate your help. ;)

By the way, I have updated the code.

[yokomo]

Hamsandwich method:

PHP Code:

#include <amxmodx>
#include <hamsandwich>

//#define USE_NEW_AMX_183
#define SoundTroll "misc/trollsound.wav"

public plugin_precache()
{
    precache_sound(SoundTroll)
}

public plugin_init()
{
    register_plugin("Knife Kill Vox", "0.0.1", "wbyokomo")
    
    #if defined USE_NEW_AMX_183
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled", 0, true) //CSBot support
    #else
    RegisterHam(Ham_Killed, "player", "OnPlayerKilled")
    #endif
}

public OnPlayerKilled(victim, attacker)
{
    if(!is_user_connected(attacker)) return;
    if(get_user_weapon(attacker) != CSW_KNIFE) return;
    
    client_cmd(victim, "spk %s", SoundTroll)
} 


[zmd94]

By the way, which one is more efficient? Whether to use Ham_Killed or DeathMsg?

;)