[cogu123]

Buenas, tengo un problema, tengo este plugin para comprar godmode, funciona todo bien vale $16000, pero al comprarlo no se descuenta el dinero te quedas con los $16000.
Ayuda.

PHP Code:

#include <amxmodx>
#include <cstrike>
#include <fun>

new OnOff, precio1
new unavez[33]

public plugin_init() {
    
    register_plugin("PLUGIN", "VERSION", "AUTHOR")
    register_clcmd("say /godmode", "ShopMio")
    register_clcmd("say_team /godmode", "ShopMio")
    
    OnOff = register_cvar("jb_tienda", "1")
    
    register_event("HLTV", "start_round", "a", "1=0", "2=0")
    
    precio1 = register_cvar("jb_pGodMode", "16000")
}
public start_round()
{
    for (new id = 1; id <= get_maxplayers(); id++)
    {
        unavez[id] = 0
    }
}

public client_putinserver(id)
{
    unavez[id] = 0
}

public ShopMio(id)
{
    if(get_pcvar_num(OnOff) == 1)
    {
        if(unavez[id] == 0)
        {
            if(is_user_alive(id))
            {
                new Menu = menu_create("\rGODMODE \y[Owners] :", "Handlehns")
                
                menu_additem(Menu, "\wGodMode \r(10 Segundos) \[$16000]","1", 0)
                
                menu_display(id, Menu, 0)
            }
            else
            {
                client_print(id, print_chat, "[Godmode] Estas Muerto No Puedes Comprar Godmode!")
            }
        }
        else if(unavez[id] >= 1)
            client_print(id, print_chat, "[Godmode] Solo puedes comprar una sola vez Godmode por ronda")
    }
    else if(get_pcvar_num(OnOff) == 0)
    {
        client_print(id, print_chat, "[Godmode] La Tienda Esta Desactivada")
    }
}  
public Handlehns(id, Menu, item)
{
    if (item == MENU_EXIT) menu_destroy(Menu)
    
    new data[6],iAccess,iCallback,iName[64];
    
    new money = cs_get_user_money(id)
    
    menu_item_getinfo(Menu, item, iAccess, data, 5, iName, 63, iCallback)
    
    switch (str_to_num(data))
    {
        case 1: 
        {
            if(money >= get_pcvar_num(precio1))
            {
                set_user_godmode(id, 1)
                client_print(id, print_chat, "[Godmode] Compraste 10 segundos de godmode")
                set_task(10.0,"sacargodmode", id)
                unavez[id]++
            }
            else
                client_print(id, print_chat, "[Godmode] Debes tener $%i para comprar 10 segundos de godmode",get_pcvar_num(precio1))
        }
    }
    return PLUGIN_HANDLED
}  

public sacargodmode(id)
{
    set_user_godmode(id, 0)
    client_print(id, print_chat, "[Godmode] Se te acabo el godmode")
} 


[BlackFur]

PHP Code:

#include <amxmodx> 
#include <cstrike> 
#include <fun> 

new OnOff, precio1 
new unavez[33] 
new imax

public plugin_init() { 
    
    register_plugin("PLUGIN", "VERSION", "AUTHOR") 
    register_clcmd("say /godmode", "ShopMio") 
    register_clcmd("say_team /godmode", "ShopMio") 
    
    OnOff = register_cvar("jb_tienda", "1") 
    
    register_event("HLTV", "start_round", "a", "1=0", "2=0") 
    
    precio1 = register_cvar("jb_pGodMode", "16000") 
    
    imax = get_maxplayers()
} 
public start_round() 
{ 
    for (new id = 1; id <= imax ; id++) 
    { 
        unavez[id] = 0 
    } 
} 

public client_putinserver(id) 
{ 
    unavez[id] = 0
    set_user_godmode(id , 0)
} 

public ShopMio(id) 
{ 
    if(get_pcvar_num(OnOff)) 
    { 
        if(!unavez[id]) 
        { 
            if(is_user_alive(id)) 
            { 
                new Menu = menu_create("\rGODMODE \y[Owners] :", "Handlehns") 
                
                new len[99]
                
                formatex(len , 98 , "\wGodmode \r(10 Segundos) \w[%d]" , get_pcvar_num(precio1))
                
                menu_additem(Menu, len ,"1", 0) 
                
                menu_display(id, Menu, 0) 
            } 
            else 
            { 
                client_print(id, print_chat, "[Godmode] Estas Muerto No Puedes Comprar Godmode!") 
            } 
        } 
        else if(unavez[id]) 
            client_print(id, print_chat, "[Godmode] Solo puedes comprar una sola vez Godmode por ronda") 
    } 
    else
        client_print(id, print_chat, "[Godmode] La Tienda Esta Desactivada") 
}   

public Handlehns(id, Menu, item) 
{ 
    if (item == MENU_EXIT || !is_user_alive(id))
        return PLUGIN_HANDLED
    
    new money = cs_get_user_money(id) 
    new costo = get_pcvar_num(precio1)
    
    if(money >= costo)
    {
        set_user_godmode(id, 1) 
        client_print(id, print_chat, "[Godmode] Compraste 10 segundos de godmode") 
        set_task(10.0,"sacargodmode", id) 
        unavez[id]++
        cs_set_user_money(id , money - costo)
    }
    else
        client_print(id , print_chat , "[Godmode] Necesitas $ %d para comprar esto" , costo)
    
    return PLUGIN_HANDLED 
}   

public sacargodmode(id) 
{ 
    set_user_godmode(id, 0) 
    client_print(id, print_chat, "[Godmode] Se te acabo el godmode") 
} 


[xGreat]

Looool

PHP Code:

new unavez[33]

register_event("HLTV", "start_round", "a", "1=0", "2=0")

public start_round()  
{  
    for (new id = 1; id <= imax ; id++)  
    {  
        unavez[id] = 0  
    }  
} 


Mejor usa :

PHP Code:

RegisterHam(Ham_Spawn, "player", "Spawn", 1)

public Spawn(id)
{
    g_Usado[id] = false
} 


Eso , Saludos xGreat

[BlackFur]

Originally Posted by xGreat Looool PHP Code: new unavez[33] register_event("HLTV", "start_round", "a", "1=0", "2=0") public start_round()   {       for (new id = 1; id <= imax ; id++)       {           unavez[id] = 0       }   }  Mejor usa : PHP Code: RegisterHam(Ham_Spawn, "player", "Spawn", 1) public Spawn(id) {     g_Usado[id] = false }  Eso , Saludos xGreat

Es JailBreak No DeathMatch ¬¬!