[Arkshine]

Here an example with this stock :

Spoiler

stock getSequenceName( const model[], const sequence, sequenceName[], nameLen = sizeof sequenceName )
{
    static sequencesNameCached;
    static sequenceCount;
    static Array:arraySequencesName;
    
    if( !sequencesNameCached )
    {
        new f = fopen( model, "rb" );
        
        if( f )
        {
            const studioHeader_NumSeq = 164;
            const mstudioseqdescSize  = 176;
            const sequenceNameLength  = 32;
            
            new sequenceIndex;
            
            fseek( f, studioHeader_NumSeq, SEEK_SET );
            {
                fread( f, sequenceCount, BLOCK_INT );
                fread( f, sequenceIndex, BLOCK_INT );
            }
            fseek( f, sequenceIndex, SEEK_SET );
            
            arraySequencesName = ArrayCreate( sequenceNameLength, sequenceCount );
            
            for( new i = 0; i < sequenceCount; i++ )
            {
                fread_blocks( f, sequenceName, sequenceNameLength, BLOCK_CHAR );
                fseek( f, mstudioseqdescSize - sequenceNameLength, SEEK_CUR );
                
                ArrayPushString( arraySequencesName, sequenceName );
            }

            fclose( f );
         
            if( !( sequencesNameCached = !!ArraySize( arraySequencesName ) ) )
            {
                ArrayDestroy( arraySequencesName );
                return 0;
            }
        }
    }
    
    if( sequencesNameCached && 0 <= sequence < sequenceCount )
    {
        return formatex( sequenceName, nameLen, "%a", ArrayGetStringHandle( arraySequencesName, sequence ) );
    }
    
    return 0;
}

You can use like that :

#include <amxmodx>

public plugin_init()
{
    new const modelToCheck[] = "models/player/urban/urban.mdl";
    
    new sequenceName[ 32 ];
    getSequenceName( modelToCheck, .sequence = 2, sequenceName );
    
    log_amx( "SequenceName = %s", sequenceName );
    
    // It returns "crouch_idle"
}

Or looping all the sequences, like that :

#include <amxmodx>

public plugin_init()
{
    new const modelToCheck[] = "models/player/urban/urban.mdl";
    
    new sequenceName[ 32 ];
    new i;
    
    while( getSequenceName( modelToCheck, i++, sequenceName ) )
    {
        log_amx( "SequenceName = %d) %s", i - 1, sequenceName );
    }
}

[.Dare Devil.]

Originally Posted by Arkshine Here an example with this stock : Spoiler stock getSequenceName( const model[], const sequence, sequenceName[], nameLen = sizeof sequenceName ) {     static sequencesNameCached;     static sequenceCount;     static Array:arraySequencesName;         if( !sequencesNameCached )     {         new f = fopen( model, "rb" );                 if( f )         {             const studioHeader_NumSeq = 164;             const mstudioseqdescSize  = 176;             const sequenceNameLength  = 32;                         new sequenceIndex;                         fseek( f, studioHeader_NumSeq, SEEK_SET );             {                 fread( f, sequenceCount, BLOCK_INT );                 fread( f, sequenceIndex, BLOCK_INT );             }             fseek( f, sequenceIndex, SEEK_SET );                         arraySequencesName = ArrayCreate( sequenceNameLength, sequenceCount );                         for( new i = 0; i < sequenceCount; i++ )             {                 fread_blocks( f, sequenceName, sequenceNameLength, BLOCK_CHAR );                 fseek( f, mstudioseqdescSize - sequenceNameLength, SEEK_CUR );                                 ArrayPushString( arraySequencesName, sequenceName );             }             fclose( f );                       if( !( sequencesNameCached = !!ArraySize( arraySequencesName ) ) )             {                 ArrayDestroy( arraySequencesName );                 return 0;             }         }     }         if( sequencesNameCached && 0 <= sequence < sequenceCount )     {         return formatex( sequenceName, nameLen, "%a", ArrayGetStringHandle( arraySequencesName, sequence ) );     }         return 0; } You can use like that : #include <amxmodx> public plugin_init() {     new const modelToCheck[] = "models/player/urban/urban.mdl";         new sequenceName[ 32 ];     getSequenceName( modelToCheck, .sequence = 2, sequenceName );         log_amx( "SequenceName = %s", sequenceName );         // It returns "crouch_idle" } Or looping all the sequences, like that : #include <amxmodx> public plugin_init() {     new const modelToCheck[] = "models/player/urban/urban.mdl";         new sequenceName[ 32 ];     new i;         while( getSequenceName( modelToCheck, i++, sequenceName ) )     {         log_amx( "SequenceName = %d) %s", i - 1, sequenceName );     } }

Oh Arkshine, If daredevil says it cant be done, then arkshine pop out somewhere and proves that im wrong again, like always. Thank you !
But seriously, you made a good job.

[Arkshine]

Most of things people think it's impossible, it's actually possible, you just need to find a way.

About parsing file, it's the same for .spr, bsp, wav, etc. ; once you know the structure of the file, it's fairly easy to retrieve informations inside. I think I will do a module for that, it may be useful.

[Arkshine]

Most of things people think it's impossible, it's actually possible, you just need to find a way.

About parsing file, it's the same for .spr, bsp, wav, etc. ; once you know the structure of the file, it's fairly easy to retrieve informations inside. I think I will do a module for that, it may be useful.

[Bos93]

Originally Posted by Arkshine Most of things people think it's impossible, it's actually possible, you just need to find a way.

Arkshine,beautifully stated)