 |
|
Veteran Member
Join Date: Jul 2006
Location: France (95)
|

08-15-2012
, 07:31
Re: Jailbreak Server
|
#4
|
Try this :
Spoiler
PHP Code:
#include <amxmodx>
#include <fakemeta_stocks>
#include <hamsandwich>
#define PLUGIN "Only Knife At Spawn"
#define VERSION "0.0.2"
#define XO_CBASEPLAYERITEM 4
#define m_iId 43
#define m_fHasSurvivedLastRound 113
new HamHook:g_iHhAddPlayerItemPre, HamHook:g_iHhCBasePlayerGiveAmmoPre, HamHook:g_iHhCBasePlayerSpawnPost
public plugin_init()
{
register_plugin( PLUGIN, VERSION, "ConnorMcLeod" )
new player[] = "player"
RegisterHam(Ham_Spawn, player, "OnCBasePlayer_Spawn", false)
DisableHamForward( g_iHhAddPlayerItemPre = RegisterHam(Ham_AddPlayerItem, player, "OnCBasePlayer_AddPlayerItem", false) )
DisableHamForward( g_iHhCBasePlayerGiveAmmoPre = RegisterHam(Ham_GiveAmmo, player, "OnCBasePlayer_GiveAmmo", false) )
DisableHamForward( g_iHhCBasePlayerSpawnPost = RegisterHam(Ham_Spawn, player, "OnCBasePlayer_Spawn_Post", true) )
new ent = FM_NULLENT
while( (ent = EF_FindEntityByString(ent, "classname", "game_player_equip")) > 0 )
{
EF_RemoveEntity(ent)
}
}
public OnCBasePlayer_Spawn( id )
{
if( !get_pdata_int(id, m_fHasSurvivedLastRound) )
{
EnableHamForward( g_iHhAddPlayerItemPre )
EnableHamForward( g_iHhCBasePlayerGiveAmmoPre )
EnableHamForward( g_iHhCBasePlayerSpawnPost )
}
}
public OnCBasePlayer_AddPlayerItem(id, iWeapon)
{
if( get_pdata_int(iWeapon, m_iId, XO_CBASEPLAYERITEM) != CSW_KNIFE )
{
set_pev(iWeapon, pev_flags, FL_KILLME)
SetHamReturnInteger(0)
return HAM_SUPERCEDE
}
return HAM_IGNORED
}
public OnCBasePlayer_GiveAmmo()
{
return HAM_SUPERCEDE
}
public OnCBasePlayer_Spawn_Post( id )
{
DisableHamForward( g_iHhAddPlayerItemPre )
DisableHamForward( g_iHhCBasePlayerGiveAmmoPre )
DisableHamForward( g_iHhCBasePlayerSpawnPost )
}
__________________
Last edited by ConnorMcLeod; 08-15-2012 at 07:33.
|
|
|
|