[Atgood125]

I'm trying to create a level in tf2, and i cant figure out how to get a trigger to do a sourcemod command to the person who activated the trigger. The command is sm_giveitem, and i want it to have it give a certain item to the activator, how can i do so?

[Bacardi]

So should this work only certain players or anyone ?

[Atgood125]

Any player that steps into the trigger.

[Dr. McKay]

You're going to have to use sdkhooks for this.

[Atgood125]

Can you further explain how i would need to use sdkhooks?

[Bacardi]

I have done now without sdkhooks...

Ok, I made test map. Hope you can open that file and compile with Hammer.
You see how I made trigger_multiple
Just move ...steam/steamapps/account/sourcesdk_content/tf/mapsrc/

MAP
So I added trigger_multiple, give it name "map_test_trigger_123".
Set reset delay 10 seconds (so they can't spam it)
Then I added outputs:
OnTrigger
map_test_trigger_123 (trigger own name)
FireUser1


Plugin
Here simple plugin. It slap player 1 dmg when touch trigger. (sm_slap #userid 1)
- Plugin hook event teamplay_round_start to find trigger_multiple again because most entyties reset when game start.
- Find all trigger_multiple from map and check targetname.
- When targetname match, stop looking further triggers and hook trigger output.
- Then when player touch trigger, pam.

test trigger output

PHP Code:

#include<sdktools>

public OnPluginStart()
{
    HookEventEx("teamplay_round_start", round_start, EventHookMode_PostNoCopy); // HookEvent
}

public round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
    new String:buffer[60], ent = -1;
    while((ent = FindEntityByClassname(ent, "trigger_multiple")) != -1) // Find trigger_multiple
    {
        GetEntPropString(ent, Prop_Data, "m_iName", buffer, sizeof(buffer)); // Get targetname
        if(StrEqual(buffer, "map_test_trigger_123", false)) // targetname match
        {
            HookSingleEntityOutput(ent, "OnTrigger", callback, false); // Hook trigger output
            break; // Stop loop
        }        
    }
}

public callback(const String:output[], caller, activator, Float:delay)
{
    // Here do anything what you want
    // Don't use player names to target!

    PrintToServer("output %s, caller %i, activator %i, delay %0.1f", output, caller, activator, delay);

    if(activator > 0 && activator <= MaxClients)
    {
        ServerCommand("sm_slap #%i 1", GetClientUserId(activator));
    }
} 


Hope not too difficult.
Somebody else could do better way

*edit
You better have test server where installed MM:S, SM and map

[Bacardi]

For @Snaggle

How change player gravity when inside trigger and outside trigger...
I test using trigger_multiple outputs
- "OnEndTouch"
- "OnStartTouch"

There could happen when player is inside trigger and round restart (players spawn), gravity not change on player.
So I added more code to trace player when inside trigger and check it when player spawn.

And avoid log spam, I use SM function to straight change plaeyr gravity instead admin command.

code

PHP Code:

#include<sdktools>

public OnPluginStart()
{
    HookEventEx("teamplay_round_start", round_start, EventHookMode_PostNoCopy); // HookEvent
    HookEventEx("player_spawn", player);
}

new bool:lowgrav[MAXPLAYERS+1]; // Trace players gravity

public player(Handle:event, const String:name[], bool:dontBroadcast)
{
    new client = GetClientOfUserId(GetEventInt(event, "userid"));

    if(lowgrav[client]) // Player have visit inside trigger "map_test_trigger_123" before spawn
    {
        SetEntityGravity(client, 1.0); // Set normal gravity regardless server sv_gravity or other plugins
    }
}

public round_start(Handle:event, const String:name[], bool:dontBroadcast)
{
    new String:buffer[60], ent = -1;
    while((ent = FindEntityByClassname(ent, "trigger_multiple")) != -1) // Find trigger_multiple
    {
        GetEntPropString(ent, Prop_Data, "m_iName", buffer, sizeof(buffer)); // Get targetname

        if(StrEqual(buffer, "map_test_trigger_123", false)) // targetname match
        {
            HookSingleEntityOutput(ent, "OnEndTouch", callback, false); // Hook trigger output
            HookSingleEntityOutput(ent, "OnStartTouch", callback, false);
            break; // Stop loop
        }        
    }
}

public callback(const String:output[], caller, activator, Float:delay)
{
    // Here do anything what you want
    // Don't use player names to target!

    //PrintToServer("output %s, caller %i, activator %i, delay %0.1f", output, caller, activator, delay);

    if(activator > 0 && activator <= MaxClients)
    {
        if(StrEqual(output, "OnStartTouch"))
        {
            //ServerCommand("sm_gravity #%i 0.2", GetClientUserId(activator));
            lowgrav[activator] = true;    // Mark player
            SetEntityGravity(activator, 0.2);
            PrintHintText(activator, "Low gravity");
        }
        else if(StrEqual(output, "OnEndTouch"))
        {
            //ServerCommand("sm_gravity #%i 1.0", GetClientUserId(activator));
            lowgrav[activator] = false;    // Remove mark
            SetEntityGravity(activator, 1.0);
            PrintHintText(activator, "Normal gravity");
        }
    }
}