[ProIcons]

PHP Code:

msg(word[])
{
    client_print(0, print_chat,"[Network] %s",word);
    return PLUGIN_CONTINUE

} 


PHP Code:

if (equali(players,"2"))
          {
              client_print(0, print_chat,"[Network] Team Alpha: %s ^n[Network] Team Beta %s", player[1], player[2]);
          }
          else if (equali(players,"4"))
          {
              client_print(0, print_chat,"[Network] Team Alpha: %s - %s ^n[Network] Team Beta %s - %s", player[1], player[2], player[3], player[4]);
          } 


Well i want the message function to can get all the values in the format

PHP Code:

msg("Team Alpha: %s - %s ^n[Network] Team Beta %s - %s",value1,value2,value3,value4); 


And generaly all the values that i will set, is it possible?

[hleV]

msg(word[], any:...)
{
        new text[128];
        vformat(text, charsmax(text), word, 2);
 
        client_print(0, print_chat, "[Network] %s", text);
}

[ProIcons]

just any?

any:...

[Exolent[jNr]]

Originally Posted by ProIcons just any? any:...

That means extra arguments are not limited to a specific tag.
If "..." was only put there, compiler wouldn't let Float (for example) to be passed.

Example:

#include < amxmodx >

public plugin_init( )
{
    new Float:flValue;
    test( "%f", flValue );
}

test( format[], ... )
{
    new message[ 192 ]
    vformat( message, 191, format, 2 )
    
    server_print( "%s", message )
}

That would give a tag mismatch error.

#include < amxmodx >

public plugin_init( )
{
    new Float:flValue;
    test( "%f", flValue );
}

test( format[], {Float,_}:... )
{
    new message[ 192 ]
    vformat( message, 191, format, 2 )
    
    server_print( "%s", message )
}

That allows Floats and untagged variables to be passed.

#include < amxmodx >

public plugin_init( )
{
    new Float:flValue;
    test( "%f", flValue );
}

test( format[], any:... )
{
    new message[ 192 ]
    vformat( message, 191, format, 2 )
    
    server_print( "%s", message )
}

That allows variables of all tags to be passed.