[Hunter-Digital]

Have you tried that example there ?

And you don't need tutorials, just search for plugins that use sokets.

[Bugsy]

Here's a basic sockets example, if you need help just ask.

http://forums.alliedmods.net/showpos...12&postcount=4

[crazy.cipry]

Originally Posted by Bugsy Here's a basic sockets example, if you need help just ask. http://forums.alliedmods.net/showpos...12&postcount=4

I saw that but I want to find out how to store the text which is in the txt file on the host ( and has 3 lines for e.g ),store it in a string, and print it exactly as it was in the file ( with spaces/tabs ).

[Bugsy]

Ok so you want to read 3 lines from the file and print them to the server?

[crazy.cipry]

Originally Posted by Bugsy Ok so you want to read 3 lines from the file and print them to the server?

Yes.

[Bugsy]

This isn't the best way to go about this but it was fast\easy to code. Let me know of any problems.

PHP Code:

#include <amxmodx>
#include <sockets>

#define TASK_RECV    551122
new Float:g_fResponseTime[ 33 ];

new const HOSTSERVER[] = "www.usconstitution.net";
new const FILENAME[] = "/const.txt";
new const TEMP_FILE_NAME[] = "TempFile.txt";
const LINES_TO_READ = 3;

public plugin_init() 
{
    register_plugin( "sockets" , "0.1" , "bugsy" );
    register_concmd( "test" , "TestConnect" );
}

public TestConnect( id )
{    
    new iSocket , iError;
    
    g_fResponseTime[ id ] = get_gametime();
    iSocket = socket_open( HOSTSERVER , 80 , SOCKET_TCP , iError );
    
    if ( !iSocket || iError )
        return PLUGIN_HANDLED;
    
    new szPacket[ 128 ];
    formatex( szPacket , charsmax( szPacket ) , "GET %s HTTP/1.1^r^nHost: %s^r^n^r^n" , FILENAME , HOSTSERVER);
    socket_send( iSocket , szPacket , sizeof( szPacket ) );
    
    new params[ 2 ];
    params[ 0 ] = id;
    params[ 1 ] = iSocket;
    set_task( 0.25 , "ReadData" , TASK_RECV , params , sizeof( params ) , "b" );

    return PLUGIN_HANDLED;
}

public ReadData( params[ 2 ] )
{
    new id = params[ 0 ];
    new iSocket = params[ 1 ];
    
    static szData[ 512 ] , szLine[ 32 ];
    new iDataStart , iLinesRead , iLen;
    
    if ( socket_change( iSocket ) )
    {
        socket_recv( iSocket , szData , charsmax( szData ) );
        g_fResponseTime[ id ] = get_gametime();
        
        iDataStart = strfind( szData , "^r^n^r^n" ) + 4;
        
        if ( iDataStart != 3 )
        {
            remove_task( TASK_RECV );
            
            if ( file_exists( TEMP_FILE_NAME ) )
                delete_file( TEMP_FILE_NAME );
                
            write_file( TEMP_FILE_NAME , szData[ iDataStart ] );
            
            while ( iLinesRead < LINES_TO_READ )
            {
                read_file( TEMP_FILE_NAME , iLinesRead++ , szLine , charsmax( szLine ), iLen );
                client_print( 0 , print_chat , "WebData: %s" , szLine );
            }
        }
    }
    
    if ( ( get_gametime() - g_fResponseTime[ id ] ) >= 5.0 )
        remove_task( TASK_RECV );
} 


[crazy.cipry]

Thank you !
It works, but I don't understand this part from code:

PHP Code:

 iDataStart = strfind( szData , "^r^n^r^n" ) + 4; 


So you search for what in the szData string? And why +4 ? :-??

[Bugsy]

That finds where the data starts (after the http header). At the end of the header there are two carriage returns (4 characters) which strfind locates, you then need to add 4 because you do not want the carriage returns included in your data.

[crazy.cipry]

oh... i understand now :-?
Thanks very much.