Admin Models (Updated v1.1.1) - Wählen? - Page 8

vato loco [GE-S] · *Last edited by vato loco [GE-S]; 05-16-2010 at 15:22.*

welches menu öffnet sich das admin menu ???

das ist klar weil das nix mit den stammies zu tun hat und dem tag.

du muss deinen admin weg machen in der user.ini um zu testen ob sich stemmie menu nur für leute öffnet die das tag haben
solange du admin hast ist klar das sich das admin menu immer öffnet egal ob du tag hast oder nicht

fresh099 · 05-16-2010 , 15:21 Re: Admin Models (Updated v1.1.1) - Wählen?

Quote:

Originally Posted by vato loco [GE-S]

welches menu öffnet sich das admin menu ???

das ist klar weil das nix mit den stammies zu tun hat und dem tag.

Ne das Stammie-Menü!
Nur sollte das ned so sein, das das menü nur bei Leuten mit dem Clantag kommt und bei sonst keinem ?

versteh das jetz ned o.O xD

vato loco [GE-S] · 05-16-2010 , 15:28 Re: Admin Models (Updated v1.1.1) - Wählen?

zocke gerad WAR ich teste es später mal ich glaub wir reden an einander vorbei

hast du dein admin noch wenn du plugin am testen bist ???

den du darft kein admin haben um zu testen

fresh099 · 05-16-2010 , 15:35 Re: Admin Models (Updated v1.1.1) - Wählen?

Quote:

Originally Posted by vato loco [GE-S]

zocke gerad WAR ich teste es später mal ich glaub wir reden an einander vorbei

hast du dein admin noch wenn du plugin am testen bist ???

den du darft kein admin haben um zu testen

Jo zock dein War ruhig fertig und gewinn

Ich hab mir die Admin rechte genommen keine Angst

Wenn ich als Normaleruse drauf bin, ohne tag, nur mit mein normalen namen "fresH" kommt automatisch das Stammie Menü, und das soll ned sein.

Nur bei Leuten mit ClanTag sollte das Menü kommen und eben bei den Admins aus der User.ini das admin model menü

vato loco [GE-S] · *Last edited by vato loco [GE-S]; 05-17-2010 at 09:50.*

so getestet und funktioniert...

noch was wie du das tag setzten sollst
damit das so ausieht -> MFB-Stammie| vato loco <- cvar so setzten mfb_clantag "MFB-Stammie| " mit einem lehrzeichen am schluss !!!

also abstand zwischen Tag und Nick -> mfb_clantag "MFB-Stammie| "
ohne abstand zwischen Tag und Nick -> mfb_clantag "MFB-Stammie|"

fresh099 · 05-17-2010 , 07:32 Re: Admin Models (Updated v1.1.1) - Wählen?

Also in der amxx.cfg:

Code:

mfb_tagposition", "1"
mfb_clantag "TAG"

die 2 einträge

und hier:

Code:

g_tagposition = register_cvar("mfb_tagposition", "1")
    g_clantag = register_cvar("mfb_clantag", "HIER DAS TAG ????")

oder nimmt das script dann automatisch aus der amxx.cfg den eintrag `?

vato loco [GE-S] · *Last edited by vato loco [GE-S]; 05-27-2010 at 06:19.*

du musst nur das hier in die amxx.cfg tun

Code:

mfb_clantag "MFB-Stammie| "

das ist alles !!!

und sag bescheid ob alles ok ist hehehe

ambesten nimmst du dies hier !!!
habe das von oben im debug mode laufen lassen und war noch ein nativ error aber der ist jetzt weg...
und die cvar für die position vom tag war überflüssig geworden...
also wenn spieler tag vorm namen hat kann er das
stammie menu öffnen mehr kann ich leider nicht für dich tun

PHP Code:


			
#include <amxmodx>
#include <cstrike>
#include <amxmisc>
#include <hamsandwich>

enum {NONE, ADMIN, VIP, PLAYER}
enum {NO_MODEL, ADMIN_TE, ADMIN_CT, STAMMIE_TE, STAMMIE_CT}

new const g_ModelPath[][] = {
    "models/player/mfb_admin_te/mfb_admin_te.mdl",
    "models/player/mfb_admin_ct/mfb_admin_ct.mdl",
    "models/player/mfb_stammie_te/mfb_stammie_te.mdl",
    "models/player/mfb_stammie_ct/mfb_stammie_ct.mdl" 
}

new g_PlayerModel[33]
new g_iPlayerStatus[33]
new bool:g_bFisrstSpawn[33]

new g_clantag

public plugin_init( )
{
    register_plugin( "Admin Models", "1.0", "vato loco [GE-S]" )
    
    register_clcmd( "say /amodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say .amodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say /adminmodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say .adminmodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say_team /amodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say_team .amodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say_team /adminmodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say_team .adminmodels", "chooseModel", ADMIN_BAN )
    register_clcmd( "say /stmodels", "chooseModelStammie"  )
    register_clcmd( "say .stmodels", "chooseModelStammie"  )
    register_clcmd( "say_team /stmodels", "chooseModelStammie" )
    register_clcmd( "say_team .stmodels", "chooseModelStammie"  )
    
    g_clantag = register_cvar("mfb_clantag", "NONE")
    
    RegisterHam(Ham_Spawn, "player", "fwHamPlayerSpawn", 1)
}

public plugin_precache( )
{
    for( new i ; i < sizeof( g_ModelPath ) ; i++ )
    {
        precache_model( g_ModelPath[i] )
    }
}

public client_connecting( id )
{
    g_iPlayerStatus[ id ] = NONE
    g_PlayerModel[ id ] = NO_MODEL
    g_bFisrstSpawn[ id ] = false
}

public client_putinserver( id )
{
    CheckClientStatus( id )
}

public client_disconnect( id )
{
    g_iPlayerStatus[ id ] = NONE
    g_PlayerModel[ id ] = NO_MODEL
    g_bFisrstSpawn[ id ] = false
}

public fwHamPlayerSpawn( id )
{
    if (is_user_alive( id ))
    {
        if(g_bFisrstSpawn[ id ] )
        {
            if( g_iPlayerStatus[ id ] == ADMIN)
                ModelMenu( id )
            
            if( g_iPlayerStatus[ id ] == VIP)
                ModelMenuStammie( id )
        }
        g_bFisrstSpawn[ id ] = false
        
        CheckCvar(id)
        
        if(g_iPlayerStatus[ id ] == ADMIN || g_iPlayerStatus[ id ] == VIP)
        {
            new g_PlayerModelID = g_PlayerModel[id]
            new is_plr_vip = cs_get_user_vip( id )
            switch ( cs_get_user_team( id ) )
            {
                case CS_TEAM_T: 
                {
                    switch(g_PlayerModelID)
                    {
                        case ADMIN_TE: cs_set_user_model( id, "mfb_admin_te" )
                            
                        case ADMIN_CT: 
                        {
                            cs_set_user_model( id, "mfb_admin_te" )
                            g_PlayerModel[id] = ADMIN_TE
                        }
                        
                        case STAMMIE_TE: cs_set_user_model( id, "mfb_stammie_te" )
                            
                        case STAMMIE_CT: 
                        { 
                            cs_set_user_model( id, "mfb_stammie_te" )
                            g_PlayerModel[id] = STAMMIE_TE
                        }
                    }
                }
                case CS_TEAM_CT:
                { 
                    switch(is_plr_vip)
                    {
                        case false:
                        {
                            switch(g_PlayerModelID)
                            {
                                case ADMIN_TE: 
                                {
                                    cs_set_user_model( id, "mfb_admin_ct" )
                                    g_PlayerModel[id] = ADMIN_CT
                                }
                                
                                case ADMIN_CT: cs_set_user_model( id, "mfb_admin_ct" )
                                    
                                case STAMMIE_TE: 
                                {
                                    cs_set_user_model( id, "mfb_stammie_ct" )
                                    g_PlayerModel[id] = STAMMIE_CT
                                }
                                
                                case STAMMIE_CT: cs_set_user_model( id, "mfb_stammie_ct" )
                                    
                            }
                        }
                        case true: cs_set_user_model( id, "vip" )
                            
                    }
                }
            }
        }
    }
    return HAM_IGNORED
}

public chooseModel( id )
{
    if (is_user_alive( id ) && g_iPlayerStatus[ id ] == ADMIN)
        ModelMenu( id )
    return PLUGIN_HANDLED
}

public ModelMenu( id )    
{
    new menu = menu_create( "\yAMXX Admin Model Menu", "menu_handler" )
    
    menu_additem( menu, "MFB Admin Model", "1", 0 )
    menu_additem( menu, "Standart Model", "2", 0 )
    
    menu_display( id, menu, 0 )
    
    return PLUGIN_HANDLED
}

public menu_handler( id, menu, item )
{
    if ( item == MENU_EXIT )
    {
        menu_destroy( menu )
        return PLUGIN_HANDLED
    }
    
    new data[ 6 ], iName[ 64 ]
    new access, callback
    menu_item_getinfo( menu, item, access, data,5, iName, 63, callback )
    
    switch ( str_to_num( data ) )
    {
        case 1:
        {
            switch ( cs_get_user_team( id ) )
            {
                case CS_TEAM_T:
                {
                    if ( is_user_alive( id ) )
                    {
                        cs_set_user_model( id, "mfb_admin_te" )
                        g_PlayerModel[id] = ADMIN_TE
                    }
                }
                case CS_TEAM_CT:
                {
                    if ( is_user_alive( id ) )
                    {
                        cs_set_user_model( id, "mfb_admin_ct" )
                        g_PlayerModel[id] = ADMIN_CT
                    }
                }
            }
        }
        case 2: 
        {
            if(g_PlayerModel[id] == NO_MODEL)
            {
                g_PlayerModel[id] = NO_MODEL
            }
            else
            {
                cs_reset_user_model(id)
                g_PlayerModel[id] = NO_MODEL
            }
        }
    }
    return PLUGIN_HANDLED
}  

public chooseModelStammie( id )
{
    if (is_user_alive( id ) && g_iPlayerStatus[ id ] == VIP)
        ModelMenuStammie( id )
    return PLUGIN_HANDLED
}

public ModelMenuStammie( id )    
{
    new menu = menu_create( "\yAMXX Stammie Model Menu", "menu_handler_stammie" )
    
    menu_additem( menu, "MFB Stammie Model", "1", 0 )
    menu_additem( menu, "Standart Model", "2", 0 )
    
    menu_display( id, menu, 0 )
    
    return PLUGIN_HANDLED
}

public menu_handler_stammie( id, menu, item )
{
    if ( item == MENU_EXIT )
    {
        menu_destroy( menu )
        return PLUGIN_HANDLED
    }
    
    new data[ 6 ], iName[ 64 ]
    new access, callback
    menu_item_getinfo( menu, item, access, data,5, iName, 63, callback )
    
    switch ( str_to_num( data ) )
    {
        case 1:
        {
            switch ( cs_get_user_team( id ) )
            {
                case CS_TEAM_T:
                {
                    if ( is_user_alive( id ) )
                    {
                        cs_set_user_model( id, "mfb_stammie_te" )
                        g_PlayerModel[id] = STAMMIE_TE
                    }
                }
                case CS_TEAM_CT:
                {
                    if ( is_user_alive( id ) )
                    {
                        cs_set_user_model( id, "mfb_stammie_ct" )
                        g_PlayerModel[id] = STAMMIE_CT
                    }
                }
            }
        }
        case 2: 
        {
            if(g_PlayerModel[id] == NO_MODEL)
            {
                g_PlayerModel[id] = NO_MODEL
            }
            else
            {
                cs_reset_user_model(id)
                g_PlayerModel[id] = NO_MODEL
            }
        }
    }
    return PLUGIN_HANDLED
} 

public client_name(id) 
{
    new Name[32]
    get_user_name(id, Name ,31)
    return force_tag(id, Name)
}

public client_infochanged(id)
{
    new Name[32]
    get_user_info(id, "name", Name, 31)
    return force_tag(id, Name)
}

stock force_tag(id, Name[]) 
{
    new ClanTag[24]
    get_pcvar_string(g_clantag, ClanTag, 23)
    
    if(g_iPlayerStatus[ id  ] == PLAYER  && containi(Name, ClanTag) >= 0)
        g_iPlayerStatus[ id  ] = VIP
    
    if(g_iPlayerStatus[ id  ] == VIP  && containi(Name, ClanTag) < 0)
        g_iPlayerStatus[ id  ] = PLAYER
    
    return PLUGIN_CONTINUE
}



public CheckCvar(id)
{
    query_client_cvar(id, "cl_minmodels", "CvarResult")
}

public CvarResult(id, const szCvar[], const szValue[])
{
    if(szValue[0] == '1')
    {
        client_cmd(id, "cl_minmodels 0")
    }
}  

stock CheckClientStatus( id )
{
    if( is_user_admin(id) )
    {
        g_iPlayerStatus[ id  ] = ADMIN
    }
    else 
    {
        g_iPlayerStatus[ id ] = PLAYER 
    }
    g_bFisrstSpawn[ id  ] = true
    set_task(1.0,"client_name", id)
}

fresh099 · 05-17-2010 , 09:51 Re: Admin Models (Updated v1.1.1) - Wählen?

Funktioniert nun alles

Vielen DANK!!!

vato loco [GE-S] · 05-17-2010 , 10:02 Re: Admin Models (Updated v1.1.1) - Wählen?

super

fresh099 · 05-27-2010 , 04:37 Re: Admin Models (Updated v1.1.1) - Wählen?

Leider klappt mit den Teams immer nochwas nicht!
Ich habe es nun getestet mit ein Paar leute und es hatten CT's Models von T und auch umgekehrt

(