[^SmileY]

Connect_Rank[EN].sma


I try to fix this Plugin.


It's correct?


Any Sugestions?

[xPaw]

Try this

#include < amxmodx >
#include < geoip >

#define SHOW_RANK

#if defined SHOW_RANK
    #include < csstats >
#endif

new g_iMsgSayText;

public plugin_init( ) {
#if defined SHOW_RANK
    register_plugin( "Connect Announcer [+Rank]", "1.0", "xPaw" );
#else
    register_plugin( "Connect Announcer", "1.0", "xPaw" );
#endif
    
    g_iMsgSayText = get_user_msgid( "SayText" );
}

public client_putinserver( id )
    ShowClientMessage( id, "connected" );

public client_disconnect( id )
    ShowClientMessage( id, "disconnected" );

ShowClientMessage( const id, const szAction[ ] ) {
    new szNick[ 32 ], szIP[ 16 ], szCountry[ 46 ];
    get_user_name( id, szNick, 31 );
    get_user_ip( id, szIP, 15, 1 );
    
    if( szIP[ 0 ] == 'l' && szIP[ 1 ] == 'o' && szIP[ 4 ] == 'b' )
        get_user_ip( 0, szIP, 15, 1 );
    
    geoip_country( szIP, szCountry, 45 );
    
    if( szCountry[ 0 ] == 'e' && szCountry[ 1 ] == 'r' && szCountry[ 3 ] == 'o' )
        szCountry = "Unknown Country";
    
#if defined SHOW_RANK
    new iTrash[ 8 ], iRank = get_user_stats( id, iTrash, iTrash );
    
    GreenPrint( 0, "^1*^3 %s^1 has^4 %s^1 from^4 %s^1. (Rank:^4 %i^1)", szNick, szAction, szCountry, iRank );
#else
    GreenPrint( 0, "^1*^3 %s^1 has^4 %s^1 from^4 %s^1.", szNick, szAction, szCountry );
#endif
}

GreenPrint( id, const Message[ ], any:... ) {
    new szMessage[ 192 ];
    vformat( szMessage, 191, Message, 3 );
    
    message_begin( id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, id );
    write_byte( id ? id : 1 );
    write_string( szMessage );
    message_end( );
}

Without Country:

#include < amxmodx >
#include < geoip >

#define SHOW_RANK

#if defined SHOW_RANK
    #include < csstats >
#endif

new g_iMsgSayText;

public plugin_init( ) {
#if defined SHOW_RANK
    register_plugin( "Connect Announcer [+Rank]", "1.0", "xPaw" );
#else
    register_plugin( "Connect Announcer", "1.0", "xPaw" );
#endif
    
    g_iMsgSayText = get_user_msgid( "SayText" );
}

public client_putinserver( id )
    ShowClientMessage( id, "connected" );

public client_disconnect( id )
    ShowClientMessage( id, "disconnected" );

ShowClientMessage( const id, const szAction[ ] ) {
    new szNick[ 32 ];
    get_user_name( id, szNick, 31 );
    
#if defined SHOW_RANK
    new iTrash[ 8 ], iRank = get_user_stats( id, iTrash, iTrash );
    
    GreenPrint( 0, "^1*^3 %s^1 has^4 %s^1. (Rank:^4 %i^1)", szNick, szAction, iRank );
#else
    GreenPrint( 0, "^1*^3 %s^1 has^4 %s^1.", szNick, szAction);
#endif
}

GreenPrint( id, const Message[ ], any:... ) {
    new szMessage[ 192 ];
    vformat( szMessage, 191, Message, 3 );
    
    message_begin( id ? MSG_ONE_UNRELIABLE : MSG_BROADCAST, g_iMsgSayText, _, id );
    write_byte( id ? id : 1 );
    write_string( szMessage );
    message_end( );
}

[^SmileY]

Cvar to remove counrtry?


Thank's anyway

[xPaw]

Posted code without country

[^SmileY]

n1ce.

Ps. I am beginner