[hl2dmgamer]

The "retry" command fails when targeting a specific player. (done for all players and that is wrong)
Can someone help me edit?
Thank you guys

PHP Code:

#include <sourcemod>
#include <sdktools>
#define PLUGIN_VERSION "1"

public OnPluginStart() {
CreateConVar("sm_retrytest_version", PLUGIN_VERSION, "retrytest Version", FCVAR_PLUGIN|FCVAR_SPONLY|FCVAR_REPLICATED|FCVAR_NOTIFY)
    RegAdminCmd("sm_retrytest", CommandretryClient, ADMFLAG_SLAY, "sm_retrytest <#userid|name>");
}

public Action:CommandretryClient(client, args) {
    ReplyToCommand(client, "retry <#userid|name>");
    return Plugin_Handled
} 


[Bacardi]

https://sm.alliedmods.net/new-api/co...ReplyToCommand

This ReplyToCommand will reply to command user into chat output or console output, where user is executing command.

*edit
https://sm.alliedmods.net/new-api/sd...econnectClient
ReconnectClient

Then look other SM source plugin files, where it use targeting.
example https://forums.alliedmods.net/showpo...55&postcount=2
example 2 https://forums.alliedmods.net/showpo...80&postcount=4

[hl2dmgamer]

Originally Posted by Bacardi https://sm.alliedmods.net/new-api/co...ReplyToCommand This ReplyToCommand will reply to command user into chat output or console output, where user is executing command. *edit https://sm.alliedmods.net/new-api/sd...econnectClient ReconnectClient Then look other SM source plugin files, where it use targeting. example https://forums.alliedmods.net/showpo...55&postcount=2 example 2 https://forums.alliedmods.net/showpo...80&postcount=4

Sorry. I found it only works for admins.
does not work on other players.
How to target individual <#userid|name> ?

Thank you for your help
cheers

[hl2dmgamer]

PHP Code:

#include <sourcemod>
#include <halflife>
#include <sdktools>
#include <sdktools_client>

public OnPluginStart() {
    RegAdminCmd("admin_retry", Command_Retry, 0, "Forces the player to RETRY connection.");
    }
public Action Command_Retry(int client, int args)
{
    if (args < 1)
    {
        PrintToConsole(client, "Usage: admin_retry <#userid|name>");
        return Plugin_Handled;
    }
 
    char name[32];
    int target = -1;
    GetCmdArg(1, name, sizeof(name));
 
    for (int i = 1; i <= MaxClients; i++)
    {
        if (!IsClientConnected(i))
        {
            continue;
        }
 
        char other[32];
        GetClientName(i, other, sizeof(other));
 
        if (StrEqual(name, other))
        {
            target = i;
        }
    }
 
    if (target == -1)
    {
        PrintToConsole(client, "Could not find any player with the name: \"%s\"", name);
        return Plugin_Handled;
    }
 
    if (!CanUserTarget(client, target))
    {
        PrintToConsole(client, "You cannot target this client.");
        return Plugin_Handled;
    }
 
    ReconnectClient(target);
 
    return Plugin_Handled;
} 


made a plugin - it works when "ReconnectClient" slow shows a black loading screen ?, then you enter the game. OK game HL2dm
will go to fix it to fast loading?

[Bacardi]

I show my example, using FindTarget (because you want target one person oly).

PHP Code:

#include <sdktools>

public void OnPluginStart()
{
    // Admin command. Can be override later by using admin_overrides configure
    RegAdminCmd("admin_retry", admin_retry, ADMFLAG_CHANGEMAP, "Reconnect player");

    LoadTranslations("common.phrases"); // You need load translation files when use ProcessTargetString and ReplyToTargetError()
}

public Action admin_retry(int client, int args)
{
    // When using command without arguments, print command tip
    if(args < 1)
    {
        ReplyToCommand(client, "[SM] Command usage: admin_retry @me, admin_retry #userid, admin_retry \"#STEAM_0:1:123\", admin_retry name");

        return Plugin_Handled;
    }

    // Get command first argument
    char pattern[MAX_NAME_LENGTH];
    GetCmdArg(1, pattern, sizeof(pattern));

    // nobots, check immunity
    int target = FindTarget(client, pattern, true, true);

    if(target == -1)
    {
        // FindTarget error, and it will show targeting error in chat or console. (Using translation "common.phrases").
        return Plugin_Handled;
    }

    ShowActivity2(client, "[SM] ", "Reconnect player %N", target);

    //ReconnectClient(target);
    ClientCommand(target, "retry");

    return Plugin_Handled;
} 


I don't know HL2DM game reconnect, how it should work... I have not tested.
:/



*edit
Try ClientCommand "retry". I updated in my code

[hl2dmgamer]

Thank you sir for the code
WOW dear sir you are the best.
It works like a charm, "fast-reconnect".
I would guess so all sourcemod games will probably work.
Boots are immune "Find Target(client, pattern, true, true);"
Perfectly

[Bacardi]

Your welcome