[Lazyneer]

A friend of mine made 2 Source Python plugins which are critical for the custom gamemode I'm hosting on my server. But because Source Python is annoying to install, I can't make more servers with those 2 plugins. So I would like a Sourcemod plugin of them.

The first plugin switches players on team RED to BLU when they die after the server fired the command "switch_death_on". When the server fires the command "switch_death_off", it stops switching players to team BLU. I would like to keep the commands.

Spoiler

myinfo = {
'name': "Omniwolf's Teamswitch Plugin",
'author': "Omniwolf",
'description': "Switches RED Survivors to BLU",
'version': "1.0"
}
from commands.typed import TypedServerCommand
from events import Event
from events.manager import event_manager
from players.entity import Player

@TypedServerCommand("switch_death_on")
def switch_enable(command_info):
try:
event_manager.register_for_event("player_deat h", player_death)
except ValueError:
print("Already on.")

@TypedServerCommand("switch_death_off")
def switch_disable(command_info):
try:
event_manager.unregister_for_event("player_de ath", player_death)
except ValueError:
print("Already off.")

def player_death(event):
player = Player.from_userid(event["userid"])
if player.get_team() == 2:
player.set_team(3)

The second plugin ends the round when there are no more players in team RED.

Spoiler

import time
myinfo = {
'name': "Omniwolf's Auto Restart Zombies",
'author': "Omniwolf",
'description': "Auto Restarts when RED is empty",
'version': "1.0"
}
from commands.typed import TypedServerCommand
from events.manager import event_manager
from engines.server import engine_server
from events import Event
from filters.players import PlayerIter

def emptyred():
if len(list(PlayerIter('red'))) == 0:
time.sleep(1)
engine_server.server_command('sm_settime 1; sm_hsay Round Over')

@Event('player_death')
def player_death(event):
emptyred()


@Event('player_team')
def on_player_team(game_event):
emptyred()

[nosoop]

Here's more-or-less a direct port from what I could see. Hopefully it works.

#include <sourcemod>
#include <tf2_stocks>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "Omniwolf's Teamswitch Plugin",
    author      = "Omniwolf",
    description = "Switches RED Survivors to BLU",
    version     = "1.0",
    url         = ""
};

int g_bHooked;

public void OnPluginStart() {
    RegServerCmd("switch_death_on", OnSwitchEnable);
    RegServerCmd("switch_death_off", OnSwitchDisable);
}

public Action OnSwitchEnable(int argc) {
    if (!g_bHooked) {
        HookEvent("player_death", OnPlayerDeath, EventHookMode_Post);
        g_bHooked = true;
    } else {
        PrintToServer("Already on.");
    }
}

public Action OnSwitchDisable(int argc) {
    if (g_bHooked) {
        UnhookEvent("player_death", OnPlayerDeath, EventHookMode_Post);
        g_bHooked = false;
    } else {
        PrintToServer("Already off.");
    }
}

public void OnPlayerDeath(Event event, const char[] name, bool dontBroadcast) {
    int client = GetClientOfUserId(event.GetInt("userid"));
    if (client && TF2_GetClientTeam(client) == TFTeam_Red) {
        TF2_ChangeClientTeam(client, TFTeam_Blue);
    }
}

#include <sourcemod>
#include <tf2_stocks>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "Omniwolf's Auto Restart Zombies",
    author      = "Omniwolf",
    description = "Auto Restarts when RED is empty",
    version     = "1.0",
    url         = ""
};

public void OnPluginStart() {
    HookEvent("player_death", OnPlayerDeath, EventHookMode_PostNoCopy);
    HookEvent("player_team", OnPlayerTeam, EventHookMode_PostNoCopy);
}

public void OnPlayerDeath(Event event, const char[] name, bool dontBroadcast) {
    EmptyRed();
}

public void OnPlayerTeam(Event event, const char[] name, bool dontBroadcast) {
    EmptyRed();
}

void EmptyRed() {
    if (GetTeamClientCount(view_as<int>(TFTeam_Red)) == 0) {
        CreateTimer(1.0, OnRedEmpty, _, TIMER_FLAG_NO_MAPCHANGE);
    }
}

public Action OnRedEmpty(Handle timer, any data) {
    ServerCommand("sm_settime 1; sm_hsay Round Over");
    return Plugin_Handled;
}

[Lazyneer]

The team switcher plugin works fine, but the auto restart doesnt work right. It ends the round as soon someone dies, connects or disconnects, whether team RED is empty or not.

[nosoop]

Originally Posted by Lazyneer [...] the auto restart doesnt work right. It ends the round as soon someone dies, connects or disconnects, whether team RED is empty or not.

Copied the code after the edits? It earlier had an incorrect test that checks that the team size was greater than zero instead of equal to it, which would explain why the round ends prematurely. Oops.

If that's not it, it sounds like some weird SourcePython-specific quirk (I know some Python, but I have no idea how SourcePython handles things), or maybe the events aren't being handled in the correct order. The hooked player_team event in the Python code suggests the round would end if any player joins any non-RED team including spectate.

Could check if the round is running (see EmptyRed function below); no idea if that'd help any though.

#include <sourcemod>
#include <tf2_stocks>

#pragma semicolon 1
#pragma newdecls required

public Plugin myinfo = {
    name        = "Omniwolf's Auto Restart Zombies",
    author      = "Omniwolf",
    description = "Auto Restarts when RED is empty",
    version     = "1.0",
    url         = ""
};

public void OnPluginStart() {
    HookEvent("player_death", OnPlayerDeath, EventHookMode_PostNoCopy);
    HookEvent("player_team", OnPlayerTeam, EventHookMode_PostNoCopy);
}

public void OnPlayerDeath(Event event, const char[] name, bool dontBroadcast) {
    EmptyRed();
}

public void OnPlayerTeam(Event event, const char[] name, bool dontBroadcast) {
    EmptyRed();
}

void EmptyRed() {
    if (GameRules_GetRoundState() == RoundState_RoundRunning && GetTeamClientCount(view_as<int>(TFTeam_Red)) == 0) {
        CreateTimer(1.0, OnRedEmpty, _, TIMER_FLAG_NO_MAPCHANGE);
    }
}

public Action OnRedEmpty(Handle timer, any data) {
    ServerCommand("sm_settime 1; sm_hsay Round Over");
    return Plugin_Handled;
}

I'll revisit this a bit later in the day if it remains unfulfilled.

[Lazyneer]

The edited version works like I wanted. Thank you.