[Chrisber]

Hello,

I try to hook a specific trigger_teleport which works very well when I use my plugin right after the map has been started.

This is my code:

PHP Code:

#include <sourcemod>
#include <sdktools_entoutput>
#include <sdktools_functions>

// public Plugin:myinfo = ...

public OnMapStart()
{
    HookTriggerTeleport();
}

public OnMapEnd()
{
    
}

HookTriggerTeleport()
{
    for (new entity = FindEntityByClassname(-1, "trigger_teleport"); entity != -1; entity = FindEntityByClassname(entity, "trigger_teleport"))
    {
        decl String:targetName[32];
        GetEntPropString(entity, Prop_Data, "m_iName", targetName, sizeof(targetName));
        
        if (StrEqual(targetName, "mytrigger"))
        {
            PrintToServer("Hooked!");
            
            HookSingleEntityOutput(entity, "OnStartTouch", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnEndTouch", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnEndTouchAll", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnTouching", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnNotTouching", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnTrigger", OnEntityOutPut);
            
            break;
        }
    }
}

public OnEntityOutPut(const String:output[], caller, activator, Float:delay)
{
    PrintToServer("%s, %d, %d, %0.2f", output, caller, activator, delay);
} 


For debugging purpose, I print "Hooked!" to the server console if it found the trigger_teleport I want to hook.

The crazy thing is, that it prints "Hooked!", but it does not fire when I touch the entity. Buf if I then reload the plugin using "sm plugins reload <name>", it prints "Hooked!" again and it works. Here's the console output:

Hooked // YIPPIEH!
Initializing Steam libraries for secure Internet server
Looking up breakpad interfaces from steamclient
Calling BreakpadMiniDumpSystemInit
Logging into anonymous gameserver account.
Connection to Steam servers successful.
Public IP is ...
Assigned anonymous gameserver Steam ID [...].
VAC secure mode is activated.
Client "..." connected (...).
>> Here I touched the trigger_teleport, nothing is printed to console
sm plugins reload mypluginname
Hooked! // YIPPIEH AGAIN!
>> Here I touch the trigger_teleport again, and the following output comes (as expected):
OnStartTouch, 191, 1, 0.00
OnEndTouch, 191, 1, 0.00
OnEndTouchAll, 191, 1, 0.00

What can I do to avoid this?
Thanks in advance!

[Leonardo]

Originally Posted by Chrisber What can I do to avoid this?

use SDKHooks?

or use HookEntityOutput instead

[Chrisber]

Originally Posted by Leonardo use SDKHooks?

This is not an option, really.
I also tried this option using OnEntityCreated, but it seems that if the entity is created, that I can't read ANY data out of it. It is empty. I can't resolve the name.

Originally Posted by Leonardo or use HookEntityOutput instead

Too many trigger_teleports in the map with too excessive usage from too many players. I don't want to generate lags.

Edit: I found out that if I clear the Target Destination with DispatchKeyValue, this also only works when reloading the plugin. It seems that something overrides the hooks and the key values.

[FaTony]

Back in the day I've found that HookSingleEntityOutput is rather unreliable. You can store entity index and HookEntityOutput.

[Bacardi]

PHP Code:

#include <sourcemod>
#include <sdktools>

// public Plugin:myinfo = ...

public OnPluginStart()
{
    HookEventEx("teamplay_restart_round", round); // If TF2
    HookEventEx("round_start", round);
}

public round(Handle:event, const String:name[], bool:dontBroadcast)
{
    HookTriggerTeleport();
}

HookTriggerTeleport()
{
    new entity = MaxClients+1;

    while( (entity = FindEntityByClassname(entity, "trigger_teleport")) != -1 )
    {
        decl String:targetName[32];
        GetEntPropString(entity, Prop_Data, "m_iName", targetName, sizeof(targetName));
        
        if (StrEqual(targetName, "mytrigger"))
        {
            PrintToServer("Hooked!");
            
            HookSingleEntityOutput(entity, "OnStartTouch", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnEndTouch", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnEndTouchAll", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnTouching", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnNotTouching", OnEntityOutPut);
            HookSingleEntityOutput(entity, "OnTrigger", OnEntityOutPut);
            
            break;
        }
    }
}

public OnEntityOutPut(const String:output[], caller, activator, Float:delay)
{
    PrintToServer("%s, %d, %d, %0.2f", output, caller, activator, delay);
} 


*edit
https://developer.valvesoftware.com/...es#Mapfilter.h

[Chrisber]

Thanks! :-)