[Mini_Midget]

I'm trying to elminate the need for set_tasks in my mod and read
http://forums.alliedmods.net/showthread.php?t=43049

And now I ended up with this in my mod.

PHP Code:

plugin_init()
{
//...
new iEnt = fm_create_entity("info_target")
    if (iEnt)
    {
        set_pev(iEnt, pev_classname, "zswarm_lights")
        fm_DispatchSpawn(iEnt)
        set_pev(iEnt, pev_nextthink, 2.0)
        register_forward(FM_Think, "lightning_effects")
    }
}


public lightning_effects(iEnt) 
{
    if(!get_pcvar_num(zomb_switch))
        return set_pev(iEnt, pev_nextthink, 10.0)

    if (get_pcvar_num(zomb_lightning) == 0)
    {    
        engfunc(EngFunc_LightStyle, 0, "m")
        remove_task(12175)
        set_pev(iEnt, pev_nextthink, 10.0)
    }
    else if (get_pcvar_num(zomb_lightning) == 1)
    {
        engfunc(EngFunc_LightStyle, 0, "a")
        set_task(random_float(10.0,17.0),"thunder_clap",12175)
    }
    else if (get_pcvar_num(zomb_lightning) == 2)
    {    
        engfunc(EngFunc_LightStyle, 0, "b")
        remove_task(12175)
        set_pev(iEnt, pev_nextthink, 10.0)
    }
    
    return FMRES_IGNORED
}

public thunder_clap() 
{
    if(!get_pcvar_num(zomb_switch))
        return
    
    engfunc(EngFunc_LightStyle, 0, "p")
    client_cmd(0,"speak %s", ZOMBIE_THUNDER)
    
    //set_task(1.25, "lightning_effects", 12175)
} 


Compiles with no errors and works ingame.
But the problem is that it changes the lights too fast and spams the wave file and just overloads the server.

[hlstriker]

Check to see if the classname is equal to "zswarm_lights" in the lightning_effects function. If it is equal, then do your thunder claps.

The reason it is spamming the server is because all the other entities using the think are activating the thunder.

[Mini_Midget]

Okay

I did what you said and got this now

PHP Code:


public lightning_effects(iEnt) 
{
    if(!get_pcvar_num(zomb_switch))
        return set_pev(iEnt, pev_nextthink, 10.0)

    if (get_pcvar_num(zomb_lightning) == 0)
    {    
        engfunc(EngFunc_LightStyle, 0, "m")
        remove_task(12175)
        //set_pev(iEnt, pev_nextthink, 10.0)
    }
    else if (get_pcvar_num(zomb_lightning) == 1)
    {
        static classname[33]
        pev(iEnt, pev_classname, classname,32)
        
        if (equal ( classname, g_entlight ) )
        {
            engfunc(EngFunc_LightStyle, 0, "a")
            set_task(random_float(10.0,17.0),"thunder_clap",12175)
        }
    }
    else if (get_pcvar_num(zomb_lightning) == 2)
    {    
        engfunc(EngFunc_LightStyle, 0, "b")
        remove_task(12175)
        //set_pev(iEnt, pev_nextthink, 10.0)
    }
    return FMRES_IGNORED
}

public thunder_clap() 
{
    if(!get_pcvar_num(zomb_switch))
        return
    
    engfunc(EngFunc_LightStyle, 0, "p")
    client_cmd(0,"speak %s", ZOMBIE_THUNDER)
    
    //set_task(1.25, "lightning_effects", 12175)
} 


I also made the classname a global just in case if I ever to typos.

This time it doesn't do anything if I set the cvar to 1.
The lighting stays the same as the cvar before it.
But one thing I accomplished with this is that it changes the lighting instantly which was one of my goals...
I change the cvar to 0 and it goes to normal lightning.
Then I try to change it to 1 but it stays the same as normal lighting and I wait for 20 seconds but nothing changed.
Then I changed to cvar 2 and it went to lighting b.
Tried to change it to cvar 1 again but stayed on lighting b.

[hlstriker]

I really didn't understand 100% what your code was trying to do. I assumed it was trying to make a lightning effect with the lights and a thunder clap sound.

If that is what you want then compile the following code to see what it does, then modify your plugin from there.

I had a lot of fun writing this It started as me editing your code to work, but I got carried away, heh.

Note: The way I set it up you can easily add more lightning flash effects.

PHP Code:

#include <amxmodx>
#include <amxmisc>
#include <fakemeta>

#define PLUGIN "Weather Effects"
#define VERSION "1.0"
#define AUTHOR "hlstriker"

#define CLASS_WEATHER_EFFECTS "zswarm_lights"
#define ZOMBIE_THUNDER_1 "ambience/thunder_clap.wav"
#define ZOMBIE_THUNDER_2 "de_torn/torn_thndrstrike.wav"
new lightStyleChar[3][2] = { "a", "b", "m" };
new lightStyleNum;
new lightCounter;
new flashNum;
new bool:isFlashing;

public plugin_init()
{
    register_plugin(PLUGIN, VERSION, AUTHOR);
    
    new iEnt = engfunc(EngFunc_CreateNamedEntity, engfunc(EngFunc_AllocString, "ambient_generic"));
    if(iEnt)
    {
        dllfunc(DLLFunc_Think, iEnt);
        set_pev(iEnt, pev_classname, CLASS_WEATHER_EFFECTS);
        
        set_keyvalue(iEnt, "message", ZOMBIE_THUNDER_1); // WAV name
        set_keyvalue(iEnt, "targetname", "boom"); // Name
        set_keyvalue(iEnt, "pitchstart", "100"); // Start Pitch
        set_keyvalue(iEnt, "pitch", "100"); // Pitch (> 100 = higher)
        set_keyvalue(iEnt, "health", "10"); // Volume (10 = loudest)
        set_keyvalue(iEnt, "spawnflags", "49"); // Play Everywhere, Start Silent, Not Toggled
        
        dllfunc(DLLFunc_Spawn, iEnt);
        set_pev(iEnt, pev_nextthink, get_gametime() + 2.0);
        
        register_forward(FM_Think, "fwd_Think", 1);
    }
}

public plugin_precache()
{
    precache_sound(ZOMBIE_THUNDER_1);
    precache_sound(ZOMBIE_THUNDER_2);
}

public fwd_Think(iEnt)
{
    if(!pev_valid(iEnt))
        return FMRES_IGNORED;
    
    static className[32];
    pev(iEnt, pev_classname, className, 31);
    
    if(equal(className, CLASS_WEATHER_EFFECTS))
    {
        static thinkReturn, randNum;
        if(!isFlashing)
        {
            randNum = random_num(0, 1);
            if(randNum)
                set_pev(iEnt, pev_message, ZOMBIE_THUNDER_1);
            else
                set_pev(iEnt, pev_message, ZOMBIE_THUNDER_2);
            isFlashing = true;
            flashNum = random_num(1, 3);
            dllfunc(DLLFunc_Use, iEnt, 0);
        }
        thinkReturn = lightning();
        
        if(thinkReturn)
            set_pev(iEnt, pev_nextthink, get_gametime() + random_float(2.5, 12.5));
        else
            set_pev(iEnt, pev_nextthink, get_gametime() + 0.1);
    }
    
    return FMRES_HANDLED;
}

stock lightning()
{
    switch(flashNum)
    {
        // Flash 1 time
        case 1:
        {
            lightCounter += 1;
            switch(lightCounter)
            {
                case 1: lightStyleNum = 1;
                case 2: lightStyleNum = 2;
                case 3: lightStyleNum = 1;
                case 4: lightStyleNum = 0;
            }
            engfunc(EngFunc_LightStyle, 0, lightStyleChar[lightStyleNum]);
            
            if(lightCounter == 4)
            {
                lightCounter = 0;
                isFlashing = false;
                return 1;
            }
            else
                return 0;
        }
        // Flash 2 times
        case 2:
        {
            lightCounter += 1;
            switch(lightCounter)
            {
                case 1: lightStyleNum = 1;
                case 2: lightStyleNum = 2;
                case 3: lightStyleNum = 1;
                case 4: lightStyleNum = 2;
                case 5: lightStyleNum = 1;
                case 6: lightStyleNum = 0;
            }
            engfunc(EngFunc_LightStyle, 0, lightStyleChar[lightStyleNum]);
            
            if(lightCounter == 6)
            {
                lightCounter = 0;
                isFlashing = false;
                return 1;
            }
            else
                return 0;
        }
        // Flash 3 times
        case 3:
        {
            lightCounter += 1;
            switch(lightCounter)
            {
                case 1: lightStyleNum = 1;
                case 2: lightStyleNum = 2;
                case 3: lightStyleNum = 1;
                case 4: lightStyleNum = 2;
                case 5: lightStyleNum = 1;
                case 6: lightStyleNum = 2;
                case 7: lightStyleNum = 1;
                case 8: lightStyleNum = 0;
            }
            engfunc(EngFunc_LightStyle, 0, lightStyleChar[lightStyleNum]);
            
            if(lightCounter == 8)
            {
                lightCounter = 0;
                isFlashing = false;
                return 1;
            }
            else
                return 0;
        }
    }
    return 1;
}

stock set_keyvalue(ent, key[], value[])
{
    new classname[32];
    
    pev(ent, pev_classname, classname, 31);
    set_kvd(0, KV_ClassName, classname);
    set_kvd(0, KV_KeyName, key);
    set_kvd(0, KV_Value, value);
    set_kvd(0, KV_fHandled, 0);
    
    dllfunc(DLLFunc_KeyValue, ent, 0);
} 


[Alka]

Huh, this is awsome. Works fine...the effect is cool

[Mini_Midget]

Just tested and WOW factor is like 10/10 for me.
Thats like the real thing!

I would love to use this for my mod as this is a lot more better than my original one! So can I hlstriker?

[hlstriker]

Why couldn't you? I made it for you

EDIT:

Note that you might want to change...
new lightStyleChar[3][2] = { "a", "b", "m" };

to...
new lightStyleChar[3][2] = { "a", "b", "c" };

I like that better so it doesn't make it so bright.

[kp_uparrow]

the problem is set_pev(iEnt, pev_nextthink, 10.0), its gonna think every frame after 10.0, lol hawk

needs to be set_pev(iEnt, pev_nextthink, halflife_time()+10.0)

[hlstriker]

That wasn't the only problem. I think by the code I posted he can figure out what was wrong with his.