[bblair]

i search this c4 timer

[Wiggen94]

isn't this better?
http://forums.alliedmods.net/showthread.php?p=483666

[ConnorMcLeod]

http://forums.alliedmods.net/showthread.php?p=803602

[bblair]

Thanks

[GmTx]

Try

PHP Code:

/* Plugin generated by AMXX-Studio */

#include <amxmodx>
#include <amxmisc>

#define PLUGIN "Bomb Hud"
#define VERSION "1.0"
#define AUTHOR "GmTx"

new cvar_pointer
new g_c4timer
new bool:b_planted = false;

public plugin_init() {
    register_plugin(PLUGIN, VERSION, AUTHOR)
    
    cvar_pointer = get_cvar_pointer("mp_c4timer")
    
    register_logevent("newRound", 2, "1=Round_Start")
    register_logevent("endRound", 2, "1=Round_End")
    register_logevent("endRound", 2, "1&Restart_Round_")
}

public newRound()
{
    g_c4timer = -1;
    remove_task(652450);
    b_planted = false;
}

public endRound()
{
    g_c4timer = -1;
    remove_task(652450);
}

public bomb_planted()
{
    b_planted = true;
    g_c4timer = get_pcvar_num(pointnum);
    dispTime()
    set_task(1.0, "dispTime", 652450, "", 0, "b");
}

public bomb_defused()
{
    if(b_planted)
    {
        remove_task(652450);
        b_planted = false;
    }
    
}

public bomb_explode()
{
    if(b_planted)
    {
        remove_task(652450);
        b_planted = false;
    }
    
}

public dispTime()
{   
    if(!b_planted)
    {
        remove_task(652450);
        return;
    }
    set_hudmessage(0, 255, 0, -1.0, -1.0)
    show_hudmessage(id, "C4: %d", g_c4timer)
    
    
    --g_c4timer;
} 


[ConnorMcLeod]

@GmTx
Your plugin can't work if you don't include csx.


Try this :

PHP Code:

#include <amxmodx>

#define VERSION "0.0.1"

#define TASKID 134567894

new mp_c4timer
new g_iC4Timer

public plugin_init()
{
    register_plugin("c4 timer", VERSION, "ConnorMcLeod")

    register_event("HLTV", "Event_HLTV_New_Round", "a", "1=0", "2=0")
    register_logevent("LogEvent_PlantedTheBomb", 3, "2=Planted_The_Bomb")
    register_logevent("Logevent_Round_End", 2, "1=Round_End")

    mp_c4timer = get_cvar_pointer("mp_c4timer")
}

public Event_HLTV_New_Round()
{
    remove_task(TASKID)
    g_iC4Timer = get_pcvar_num( mp_c4timer )
}

public LogEvent_PlantedTheBomb()
{
    set_task(1.0, "BombCountDown", TASKID, .flags="b")
}

public BombCountDown()
{
    if( --g_iC4Timer > 0 )
    {
        set_hudmessage(50, 150, 50, 0.10, 0.35, 0, 1.0, 1.0, 0.0, 0.0, -1)
        show_hudmessage(0, "C4: %isec", g_iC4Timer)
    }
}

public Logevent_Round_End()
{
    remove_task(TASKID)
} 


[bblair]

Thanks all

[GmTx]

Yeah i forgot it sorry.But your its better

[Exolent[jNr]]

This should make what you want.
I edited Connor's code for the sprite timer cause I was lazy :]

PHP Code:

/*    Copyright © 2009, ConnorMcLeod

    C4 Sprites Timer is free software;
    you can redistribute it and/or modify it under the terms of the
    GNU General Public License as published by the Free Software Foundation.

    This program is distributed in the hope that it will be useful,
    but WITHOUT ANY WARRANTY; without even the implied warranty of
    MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
    GNU General Public License for more details.

    You should have received a copy of the GNU General Public License
    along with C4 Sprites Timer; if not, write to the
    Free Software Foundation, Inc., 59 Temple Place - Suite 330,
    Boston, MA 02111-1307, USA.
*/

#include <amxmodx>
#include <engine>
#include <fakemeta>
#include <hamsandwich>

#define PLUGIN "C4 Timer"
#define AUTHOR "ConnorMcLeod"
#define VERSION "0.1.0"

const OFFSET_C4_EXPLODE_TIME    = 100

new g_iC4
new HamHook:g_HhGrenadeThink

new g_iTime = -1

new Float:g_flExplodeTime

public plugin_init()
{    
    register_plugin(PLUGIN, VERSION, AUTHOR)

    if( find_ent_by_class(FM_NULLENT, "func_bomb_target") || find_ent_by_class(FM_NULLENT, "info_bomb_target") )
    {
        g_HhGrenadeThink = RegisterHam(Ham_Think, "grenade", "C4_Think", 1)

        register_event("HLTV", "StopHook", "a", "1=0", "2=0")
        register_logevent("StopHook", 2, "1=Round_End")

        register_logevent("StartHook", 3, "2=Planted_The_Bomb")

        StopHook()
    }
}

public StopHook()
{
    g_iC4 = 0
    g_iTime = -1
    DisableHamForward( g_HhGrenadeThink )
}

public StartHook()
{
    new iC4 = FM_NULLENT
    new const grenade[] = "grenade"
    new const env_sprite[] = "env_sprite"
    while( (iC4 = find_ent_by_class(iC4, grenade)) )
    {
        if( get_pdata_int(iC4, 96, 5) & (1<<8) )
        {
            g_iC4 = iC4
            g_flExplodeTime = get_pdata_float(g_iC4, OFFSET_C4_EXPLODE_TIME, 5)
            EnableHamForward( g_HhGrenadeThink )
            return
        }
    }
}

public C4_Think( iC4 )
{
    if( g_iC4 != iC4 )
    {
        return
    }

    static Float:flTime, iTime

    flTime = g_flExplodeTime - get_gametime()
    iTime = floatround(flTime, floatround_ceil)

    if( g_iTime != iTime )
    {
        g_iTime = iTime;
        set_hudmessage( 0, 255, 0, 0.1, 0.2, 0, 0.0, 1.5, 0.0, 0.0, 1 );
        show_hudmessage( 0, "C4: %i", iTime );
    }
}